Testing unità di librerie .NET Core di Visual Basic usando il test dotnet e NUnit

In questa esercitazione viene illustrata un'esperienza interattiva di compilazione passo passo di una soluzione di esempio finalizzata all'apprendimento dei concetti base del testing unità. Se si preferisce seguire l'esercitazione usando una soluzione preesistente, visualizzare o scaricare il codice di esempio prima di iniziare. Per istruzioni sul download, vedere Esempi ed esercitazioni.

Questo articolo è relativo al test di un progetto .NET Core. Se si sta testando un progetto ASP.NET Core, vedere Test di integrazione in ASP.NET Core.

Prerequisiti

• .NET 8 SDK o versioni successive.
• Un editor di testo o editor di codice di propria scelta.

Creazione del progetto di origine

Aprire una finestra della shell. Creare una directory denominata unit-testing-vb-nunit in cui archiviare la soluzione. In questa nuova directory eseguire il comando seguente per creare un nuovo file di soluzione per la libreria di classi e il progetto di test:

dotnet new sln

Creare quindi una directory PrimeService. Di seguito viene mostrata la struttura di file disponibile fino a questo punto:

/unit-testing-vb-nunit
    unit-testing-vb-nunit.sln
    /PrimeService

Impostare PrimeService come directory corrente ed eseguire il comando seguente per creare il progetto di origine:

dotnet new classlib -lang VB

Rinominare Class1.VB in PrimeService.VB. Si crea un'implementazione non corretta della classe PrimeService:

Namespace Prime.Services
    Public Class PrimeService
        Public Function IsPrime(candidate As Integer) As Boolean
            Throw New NotImplementedException("Please create a test first.")
        End Function
    End Class
End Namespace

Tornare alla directory unit-testing-vb-using-mstest. Eseguire il comando seguente per aggiungere il progetto di libreria di classi alla soluzione:

dotnet sln add .\PrimeService\PrimeService.vbproj

Creazione del progetto di test

Creare quindi la directory PrimeService.Tests. Di seguito è illustrata la struttura di directory:

/unit-testing-vb-nunit
    unit-testing-vb-nunit.sln
    /PrimeService
        Source Files
        PrimeService.vbproj
    /PrimeService.Tests

Impostare PrimeService.Tests come directory corrente e creare un nuovo progetto usando il comando seguente:

dotnet new nunit -lang VB

Il comando dotnet new crea un progetto di test che usa NUnit come libreria di test. Il modello generato configura il Test Runner nel file PrimeServiceTests.vbproj:

<ItemGroup>
  <PackageReference Include="nunit" Version="4.3.1" />
  <PackageReference Include="NUnit3TestAdapter" Version="4.6.0" />
  <PackageReference Include="Microsoft.NET.Test.Sdk" Version="17.12.0" />
</ItemGroup>

Per creare ed eseguire unit test, il progetto di test richiede altri pacchetti. dotnet new nel passaggio precedente aggiunge NUnit e l'adattatore di test NUnit. Aggiungere ora la libreria di classi PrimeService come un'altra dipendenza del progetto. Usare il comando dotnet add reference:

dotnet add reference ../PrimeService/PrimeService.vbproj

È possibile visualizzare l'intero file nel repository degli esempi su GitHub.

Il layout della soluzione finale è il seguente:

/unit-testing-vb-nunit
    unit-testing-vb-nunit.sln
    /PrimeService
        Source Files
        PrimeService.vbproj
    /PrimeService.Tests
        Test Source Files
        PrimeService.Tests.vbproj

Eseguire il comando seguente nella directory unit-testing-vb-nunit:

dotnet sln add .\PrimeService.Tests\PrimeService.Tests.vbproj

Creazione del primo test

Scrivere un test che genera errore, fare in modo che venga superato e quindi ripetere il processo. Nella directory PrimeService.Tests rinominare il file UnitTest1.vb in PrimeService_IsPrimeShould.VB e sostituire l'intero contenuto con il codice seguente:

Imports NUnit.Framework

Namespace PrimeService.Tests
    <TestFixture>
    Public Class PrimeService_IsPrimeShould
        Private _primeService As Prime.Services.PrimeService = New Prime.Services.PrimeService()

        <Test>
        Sub IsPrime_InputIs1_ReturnFalse()
            Dim result As Boolean = _primeService.IsPrime(1)

            Assert.That(result, [Is].False, $"1 should not be prime")
        End Sub

    End Class
End Namespace

L'attributo <TestFixture> indica una classe che contiene test. L'attributo <Test> indica un metodo eseguito dal Test Runner. Da unit-testing-vb-nunit eseguire dotnet test per compilare i test e la libreria di classi, quindi eseguire i test. Il Test Runner di NUnit include il punto d'ingresso del programma per l'esecuzione dei test. dotnet test avvia il Test Runner usando il progetto di unit test creato.

Il test ha esito negativo. Non è stata ancora creata l'implementazione. Fare in modo che questo test venga superato scrivendo il codice più semplice e funzionante nella classe PrimeService:

Public Function IsPrime(candidate As Integer) As Boolean
    If candidate = 1 Then
        Return False
    End If
    Throw New NotImplementedException("Please create a test first.")
End Function

Eseguire di nuovo dotnet test nella directory unit-testing-vb-nunit. Il comando dotnet test esegue prima una compilazione del progetto PrimeService e quindi del progetto PrimeService.Tests. Dopo la compilazione di entrambi i progetti, verrà eseguito il test singolo, che viene superato.

Aggiunta di altre funzionalità

Ora che il test è stato superato, è necessario scriverne altri. Esistono alcuni altri casi semplici per i numeri primi: 0, -1. È possibile aggiungerli come nuovi test, con l'attributo <Test>, ma questa operazione risulta rapidamente noiosa. Sono disponibili altri attributi xUnit che consentono di scrivere una suite di test analoghi. Un attributo <TestCase> rappresenta una suite di test che eseguono lo stesso codice, ma hanno argomenti di input diversi. È possibile usare l'attributo <TestCase> per specificare i valori per tali input.

Anziché creare nuovi test, applicare questi due attributi per creare una serie di test che verificano diversi valori minori di due, ovvero il numero primo più basso:

<TestFixture>
Public Class PrimeService_IsPrimeShould
    Private _primeService As Prime.Services.PrimeService = New Prime.Services.PrimeService()

    <TestCase(-1)>
    <TestCase(0)>
    <TestCase(1)>
    Sub IsPrime_ValuesLessThan2_ReturnFalse(value As Integer)
        Dim result As Boolean = _primeService.IsPrime(value)

        Assert.That(result, [Is].False, $"{value} should not be prime")
    End Sub

    <TestCase(2)>
    <TestCase(3)>
    <TestCase(5)>
    <TestCase(7)>
    Public Sub IsPrime_PrimesLessThan10_ReturnTrue(value As Integer)
        Dim result As Boolean = _primeService.IsPrime(value)

        Assert.That(result, [Is].True, $"{value} should be prime")
    End Sub

    <TestCase(4)>
    <TestCase(6)>
    <TestCase(8)>
    <TestCase(9)>
    Public Sub IsPrime_NonPrimesLessThan10_ReturnFalse(value As Integer)
        Dim result As Boolean = _primeService.IsPrime(value)

        Assert.That(result, [Is].False, $"{value} should not be prime")
    End Sub
End Class

Eseguire dotnet test. Due test hanno esito negativo. Per fare in modo che tutti i test vengano superati, modificare la clausola if all'inizio del metodo Main nel file PrimeServices.cs:

if candidate < 2

Continuare a eseguire l'iterazione aggiungendo altri test, altre teorie e altro codice nella libreria principale. Si ottiene la versione completa dei test e l'implementazione completa della libreria.

È stata compilata una piccola libreria e un set di unit test per tale libreria. La soluzione è stata strutturata in modo che l'aggiunta di nuovi pacchetti e test faccia parte del normale flusso di lavoro. La maggior parte del tempo e dell'impegno è dedicata alla soluzione degli obiettivi dell'applicazione.