Clausola Handles (Visual Basic)

Articolo
04/05/2024

Dichiara che una routine gestisce un evento specificato.

Sintassi

proceduredeclaration Handles eventlist

Parti

proceduredeclaration Dichiarazione per la routine Sub che gestirà l'evento.

eventlist Elenco degli eventi che devono essere gestiti da proceduredeclaration, separati da virgole. Gli eventi devono essere generati dalla classe base per la classe corrente o da un oggetto dichiarato usando la parola chiave WithEvents.

Osservazioni:

Usare la parola chiave Handles alla fine di una dichiarazione di routine per fare in modo che la routine gestisca eventi generati da una variabile oggetto dichiarata con la parola chiave WithEvents . La parola chiave Handles può anche essere usata in una classe derivata per gestire eventi da una classe base.

La parola chiave Handles e l'istruzione AddHandler consentono entrambe di specificare che quelle particolari routine gestiscono particolari eventi, ma esistono alcune differenze. Usare la parola chiave Handles quando si definisce una routine, per specificare che questa gestisce un particolare evento. L'istruzione AddHandler connette le routine agli eventi in fase di esecuzione. Per altre informazioni, vedere Istruzione AddHandler.

Per gli eventi personalizzati, l'applicazione richiama la funzione di accesso AddHandler dell'evento quando aggiunge la routine come gestore eventi. Per altre informazioni sugli eventi personalizzati, vedere Istruzione Event.

Esempio 1

Public Class ContainerClass
    ' Module or class level declaration.
    WithEvents Obj As New Class1

    Public Class Class1
        ' Declare an event.
        Public Event Ev_Event()
        Sub CauseSomeEvent()
            ' Raise an event.
            RaiseEvent Ev_Event()
        End Sub
    End Class

    Sub EventHandler() Handles Obj.Ev_Event
        ' Handle the event.
        MsgBox("EventHandler caught event.")
    End Sub

    ' Call the TestEvents procedure from an instance of the ContainerClass 
    ' class to test the Ev_Event event and the event handler.
    Public Sub TestEvents()
        Obj.CauseSomeEvent()
    End Sub
End Class

L'esempio seguente illustra come una classe derivata può usare l'istruzione Handles per gestire un evento da una classe base.

Public Class BaseClass
    ' Declare an event.
    Event Ev1()
End Class
Class DerivedClass
    Inherits BaseClass
    Sub TestEvents() Handles MyBase.Ev1
        ' Add code to handle this event.
    End Sub
End Class

Esempio 2

L'esempio seguente contiene due gestori eventi dei pulsanti per un progetto Applicazione WPF.

Private Sub Button1_Click(sender As System.Object, e As System.Windows.RoutedEventArgs) Handles Button1.Click
    MessageBox.Show(sender.Name & " clicked")
End Sub

Private Sub Button2_Click(sender As System.Object, e As System.Windows.RoutedEventArgs) Handles Button2.Click
    MessageBox.Show(sender.Name & " clicked")
End Sub

Esempio 3

L'esempio che segue equivale a quello precedente. L'oggetto eventlist nella clausola Handles contiene gli eventi per entrambi i pulsanti.

Private Sub Button_Click(sender As System.Object, e As System.Windows.RoutedEventArgs) Handles Button1.Click, Button2.Click
    MessageBox.Show(sender.Name & " clicked")
End Sub

Condividi tramite