Classe CachingProfileElement

Articolo
07/19/2023

Configura la memorizzazione nella cache per un'estensione di richiesta specificata.

Sintassi

class CachingProfileElement : CollectionElement

Metodi

Questa classe non contiene metodi.

Proprietà

Nella tabella seguente sono elencate le proprietà esposte dalla CachingProfileElement classe .

Nome	Descrizione
`Duration`	Valore di lettura/scrittura `datetime` che specifica la quantità di tempo in cui una risposta deve rimanere nella cache. Il valore predefinito è 30 secondi. L'intervallo di tempo valido è compreso tra 0 e 365 giorni.
`Extension`	Valore univoco di lettura/scrittura `string` obbligatorio che specifica l'estensione di una richiesta che userà il profilo della cache. L'estensione deve essere nel formato "EXT" o "", dove EXT* è l'estensione. Proprietà chiave. Nota: Non sono consentite voci di estensione sovrapposte. Ogni richiesta viene mappata esattamente a un `CachingProfileElement` oggetto. Se esiste una voce con "*", altri profili di memorizzazione nella cache con estensioni più specifiche sostituiranno il profilo con l'asterisco. L'ordinamento delle voci del profilo non è importante.
`KernelCachePolicy`	Valore di lettura/scrittura `sint32` che configura i criteri di memorizzazione nella cache del kernel. I valori possibili sono elencati più avanti nella sezione Osservazioni.
`Location`	Valore di lettura/scrittura `sint32` che specifica le posizioni possibili per la cache di output. I valori possibili sono elencati più avanti nella sezione Osservazioni.
`Policy`	Valore di lettura/scrittura `sint32` che configura i criteri di memorizzazione nella cache dell'output. I valori possibili sono elencati più avanti nella sezione Osservazioni.
`VaryByHeaders`	Valore di lettura/scrittura `string` contenente un elenco delimitato da virgole di nomi di intestazione che il server userà per variare le risposte memorizzate nella cache all'URL.
`VaryByQueryString`	Valore di lettura/scrittura `string` che contiene un elenco delimitato da virgole di nomi di parametri stringa di query che il server userà per variare le risposte memorizzate nella cache all'URL.

Sottoclassi

Questa classe non contiene sottoclassi.

Commenti

Questa classe corrisponde all'elemento <profiles><system.webServer/caching> nella sezione del file ApplicationHost.config. Le istanze di questa classe sono contenute nella Profiles proprietà array della classe CachingProfileSettings .

Nella tabella seguente sono elencati i valori possibili per la KernelCachePolicy proprietà. Il valore predefinito è 0 (DontCache).

Valore	Parola chiave	Descrizione
0	`DontCache`	La risposta non verrà memorizzata nella cache nel kernel. Tuttavia, la memorizzazione nella cache dell'output può comunque verificarsi. Nota: Questa impostazione esegue l'override di tutte le impostazioni in conflitto nella `Location` proprietà.
1	`CacheUntilChange`	La risposta viene memorizzata nella cache HTTP.SYS fino a quando la voce non viene invalidata o fino alla scadenza dopo il periodo di inattività specificato dalla `Duration` proprietà.
2	`CacheForTimePeriod`	La risposta viene memorizzata nella cache per la quantità di tempo specificata dalla `Duration` proprietà, anche se la voce viene invalidata nel frattempo.
3	`DisableCache`	La cache è disabilitata e non verrà eseguita alcuna memorizzazione nella cache.

Nella tabella seguente sono elencati i valori possibili per la Location proprietà. Il valore predefinito è 3 (Server).

Valore	Parola chiave	Descrizione
0	`Any`	La risposta può essere memorizzata nella cache nel client, nel server Web o nel server proxy.
1	`Client`	La risposta viene memorizzata nella cache solo nel client.
2	`Downstream`	La risposta viene memorizzata nella cache nei server proxy e nel client, ma non nel server Web.
3	`Server`	La risposta viene memorizzata nella cache solo nel server Web.
4	`None`	La risposta non viene memorizzata nella cache ovunque.
5	`ServerAndClient`	La risposta viene memorizzata nella cache sia nel server Web che nel client, ma non nei server proxy. Nota: È possibile usare questa impostazione per evitare la condivisione del contenuto tra più utenti nella cache proxy quando il server ha un comportamento diverso per il contenuto privato.

Nella tabella seguente sono elencati i valori possibili per la Policy proprietà. Il valore predefinito è 0 (DontCache).

Valore	Parola chiave	Descrizione
0	`DontCache`	La risposta non verrà inserita nella cache di output. Tuttavia, la memorizzazione nella cache del kernel può comunque verificarsi.
1	`CacheUntilChange`	La risposta viene memorizzata nella cache fino a quando la voce non viene invalidata o fino alla scadenza dopo il periodo di inattività specificato dalla `Duration` proprietà.
2	`CacheForTimePeriod`	La risposta viene memorizzata nella cache per la quantità di tempo specificata dalla `Duration` proprietà, anche se la voce viene invalidata nel frattempo.
3	`DisableCache`	La cache è disabilitata e non verrà eseguita alcuna memorizzazione nella cache.

Esempio

Nell'esempio seguente vengono visualizzati tutti gli CachingProfileElement oggetti per il sito Web predefinito.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the caching section for the default Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
oSite.GetSection "CachingSection", oSection  

' Display the path and location.  
Wscript.Echo "Path: " & oSection.Path  
Wscript.Echo "Location: " & oSection.Location  
Wscript.Echo

' Display all of the caching profiles for the default Web site.  
For Each oCachingProfileElement In oSection.Profiles.Profiles  
    Wscript.Echo
    WScript.Echo "[ " & oCachingProfileElement.Extension & _  
        " ] Caching Profile"  
    WScript.Echo "-----------------------------------"  
    WScript.Echo "Duration: " & oCachingProfileElement.Duration  
    WScript.Echo "KernelCachePolicy: " & _  
        CachePolicyText(oCachingProfileElement.KernelCachePolicy)  
    WScript.Echo "Location: " & _  
        LocationText(oCachingProfileElement.Location)  
    WScript.Echo "Policy: " & _  
        CachePolicyText(oCachingProfileElement.Policy)  
    WScript.Echo "VaryByHeaders: " & _  
        oCachingProfileElement.VaryByHeaders  
    WScript.Echo "VaryByQueryString: " & _  
        oCachingProfileElement.VaryByQueryString  
    WScript.Echo
Next  

' Provide text for KernelCachePolicy and Policy enumeration values.  
Function CachePolicyText(enumval)  

    Select Case enumval  
        Case 0  
            CachePolicyText="DontCache"  
        Case 1  
            CachePolicyText="CacheUntilChange"  
        Case 2  
            CachePolicyText="CacheForTimePeriod"  
        Case 3  
            CachePolicyText="DisableCache"  
        Case Else  
            CachePolicyText="Undefined enumeration value"  
    End Select  

End Function  

' Provide text for Location enumeration values.  
Function LocationText(enumval)  

    Select Case enumval  
        Case 0  
            LocationText="Any"  
        Case 1  
            LocationText="Client"  
        Case 2  
            GetLocationText="Downstream"  
        Case 3  
            LocationText="Server"  
        Case 4  
            LocationText="None"  
        Case 5  
            LocationText="ServerAndClient"  
        Case Else  
            LocationText="Undefined enumeration value"  
    End Select  

End Function

Gerarchia di ereditarietà

CollectionElement

CachingProfileElement

Requisiti

Tipo	Descrizione
Client	- IIS 7.0 in Windows Vista - IIS 7.5 in Windows 7 - IIS 8.0 in Windows 8 - IIS 10.0 in Windows 10
Server	- IIS 7.0 in Windows Server 2008 - IIS 7.5 in Windows Server 2008 R2 - IIS 8.0 in Windows Server 2012 - IIS 8.5 in Windows Server 2012 R2 - IIS 10.0 in Windows Server 2016
Prodotto	- IIS 7.0, IIS 7.5, IIS 8.0, IIS 8.5, IIS 10.0
File MOF	WebAdministration.mof

Vedere anche

Classe AspCache
Classe CachingProfileSettings
Classe CachingSection
Classe CollectionElement
Classe HttpClientCache

Condividi tramite