Metodo ConfigurationSectionWithCollection.Get

Articolo
07/19/2023

Recupera il membro specificato di una raccolta da una sezione di configurazione.

Sintassi

ConfigurationSectionWithCollection.Get   
   CollectionName,   
   ElementIdentifier,   
   CollectionElement;

ConfigurationSectionWithCollection.Get   
CollectionName,   
ElementIdentifier,   
CollectionElement

Parametri

Nome	Descrizione
`CollectionName`	Valore `string` che contiene il nome della raccolta che verrà recuperata, ad esempio "Modules". Il nome della raccolta può rappresentare una raccolta annidata e può usare gli indici. L'indice può essere un indice integer in base zero o una stringa ,ad esempio [9] o "KeyProperty='Value'". Per altre informazioni, vedere la sezione Osservazioni. Nota:`CollectionName` è il nome della sezione come si trova nel file di configurazione, non il nome della classe WMI corrispondente ,ad esempio "Modules", non "ModulesSection".
`ElementIdentifier`	Valore `string` che specifica una proprietà chiave e un valore dell'elemento della raccolta da recuperare. La stringa deve essere nel formato "KeyProperty1='Value1',KeyProperty2='Value2',..." (ad esempio, "Name='RoleManager'").
`CollectionElement`	Variabile dell'oggetto CollectionElement in cui verrà inserito l'elemento della raccolta recuperata , ad esempio `oModule`.

Valore restituito

void.

Commenti

Questo metodo è utile quando si desidera recuperare un solo membro di una raccolta.

Negli esempi seguenti vengono illustrate le varianti di sintassi per il CollectionName parametro .

La sintassi seguente mostra un CollectionName parametro che usa un indice "KeyProperty='Value" basato su stringa e specifica una raccolta nidificata:

traceFailedRequests[path='Rule_2'].TraceAreas.TraceAreas

È possibile specificare lo stesso valore con un indice in base zero:

traceFailedRequests[1].TraceAreas.TraceAreas

Se il ElementIdentifier parametro è "provider='ASP'" e la CollectionElement variabile di output è oTraceAreaElement, la chiamata completa al Get metodo potrebbe essere simile alla sintassi seguente:

oSection.Get _

"traceFailedRequests[path='Rule_2'].TraceAreas.TraceAreas", _

"provider='ASP'", oTraceAreaElement

La sintassi seguente mostra la chiamata completa con un indice in base zero:

oSection.Get _

"traceFailedRequests[1].TraceAreas.TraceAreas", _

"provider='ASP'", oTraceAreaElement

Esempio

Nell'esempio seguente viene recuperato il nome e il RoleManager tipo del modulo dalla <modules> sezione del file ApplicationHost.config.

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' First, get the <modules> section by using the inherited   
' WMI Get method on the WMI class name of the section  
' (that is, "ModulesSection").  
Set oSection = oWebAdmin.Get( _  
    "ModulesSection.Path='MACHINE/WEBROOT/APPHOST/'," & _  
    "Location=''")  
  
' Display the path.   
WScript.Echo "Path: " & oSection.Path_.RelPath  
  
' Retrieve the RoleManager member of the collection.  
' This is the ConfigurationSectionWithCollection.Get method,  
' so use the collection name found in the configuration file  
' (that is, "Modules").  
oSection.Get "Modules", "Name='RoleManager'", oModule  
  
' Display the module name and type.  
WScript.Echo "Module Name: " & oModule.Name  
WScript.Echo "Module Type: " & oModule.Type  
  
' Output:  
' Path: ModulesSection.Location="",Path="MACHINE/WEBROOT/APPHOST/"  
' Module Name: RoleManager  
' Module Type: System.Web.Security.RoleManagerModule

Requisiti

Tipo	Descrizione
Client	- IIS 7.0 in Windows Vista - IIS 7.5 in Windows 7 - IIS 8.0 in Windows 8 - IIS 10.0 in Windows 10
Server	- IIS 7.0 in Windows Server 2008 - IIS 7.5 in Windows Server 2008 R2 - IIS 8.0 in Windows Server 2012 - IIS 8.5 in Windows Server 2012 R2 - IIS 10.0 in Windows Server 2016
Prodotto	- IIS 7.0, IIS 7.5, IIS 8.0, IIS 8.5, IIS 10.0
File MOF	WebAdministration.mof

Vedere anche

Classe CollectionElement
Classe ConfigurationSectionWithCollection
Classe ModuleAction
Classe ModulesSection
Classe TraceAreaElement
Classe TraceFailedRequestsSection
Classe TraceUrl
Classe TraceUrlAreaSettings

Condividi tramite