Metodo ConfigurationSectionWithCollection.Remove

Rimuove l'elemento specificato da una raccolta in una sezione di configurazione.

Sintassi

ConfigurationSectionWithCollection.Remove collectionName, element;  

ConfigurationSectionWithCollection.Remove collectionName, element  

Parametri

Valore restituito

Questo metodo non restituisce valori.

Esempio

Nell'esempio seguente vengono visualizzati i nomi dei gestori per il sito Web predefinito, rimuove l'elemento del gestore denominato "CGI-exe" se presente e quindi elenca di nuovo i nomi del gestore. Il codice causerà l'aggiunta del codice XML seguente alla <system.webServer> sezione del file Web.config per il sito Web predefinito:

<handlers>

<remove name="CGI-exe" />

</handlers>

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject("winmgmts:root\WebAdministration")  
  
' Get the default Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
  
' Get the handlers section.  
oSite.GetSection "HandlersSection", oHandlersSection  
  
' Display the current handler names.  
Wscript.Echo "---[Current Handler List]---"  
Call DisplayHandlerNames  
  
' Remove the CGI-exe handler by matching its name.  
For Each oHandler In oHandlersSection.Handlers  
     If oHandler.Name = "CGI-exe" Then  
        oHandlersSection.Remove "Handlers", oHandler  
    End If   
Next  
  
' Refresh the oHandlersSection object so that its contents will  
' reflect the updated configuration.  
oHandlersSection.Refresh_      
  
' List the handler names again to show the change.  
Wscript.Echo "---[New Handler List]---"  
Call DisplayHandlerNames  
  
' Provide a subroutine to display handler names.  
Sub DisplayHandlerNames  
    For Each oHandler In oHandlersSection.Handlers  
        WScript.Echo "Handler Name: " & oHandler.Name  
    Next  
    Wscript.Echo  
End Sub  
  

Nota La chiamata al metodo aggiorna l'archivio Remove_ di configurazione sottostante, ma non l'oggetto oHandlersSection in esecuzione in memoria. La chiamata al metodo su oHandlersSection garantisce che i Refresh_ dati siano accurati se è necessario usarlo più avanti nello stesso script.

Requisiti

Vedere anche

Classe ConfigurationSectionWithCollection
Classe HandlerAction
Classe HandlersSection