Configurare Azure Log Analytics per Power BI

Power BI si integra con Log Analytics di Azure per consentire agli amministratori e ai proprietari dell'area di lavoro Premium di configurare una connessione Log Analytics alla sottoscrizione di Power BI. Questo articolo descrive come funziona l'integrazione tra Log Analytics e Power BI e come configurarla per l'ambiente.

Sono disponibili due elementi per ottenere l'uso di Log Analytics di Azure per Power BI:

• Configurare la sottoscrizione di Azure nel portale di Azure.
• Abilitare Log Analytics per Power BI nel portale di amministrazione di Power BI.

Le sezioni seguenti illustrano i passaggi per eseguire entrambe le operazioni.

Prerequisiti

Prima di configurare l'integrazione di Log Analytics da Power BI, è necessario creare un'area di lavoro Log Analytics nel portale di Azure. È anche necessario concedere l'autorizzazione in Azure per il servizio Power BI per scrivere i log. I requisiti esatti sono:

• Accesso collaboratore alla sottoscrizione di Azure.
• Registrare il provider di risorse "microsoft.insights" nella sottoscrizione di Azure in cui verranno raccolti i dati di log di Power BI.
• L'utente che configura l'integrazione di Log Analytics in Power BI deve avere il ruolo Collaboratore Log Analytics per l'area di lavoro Log Analytics. Vedere Domande frequenti per le soluzioni alternative se non è possibile specificare il ruolo Proprietario.

Abilitare il provider di risorse "microsoft.insights"

Per Log Analytics è necessario abilitare il provider di risorse "microsoft.insights" a livello di sottoscrizione di Azure. I passaggi seguenti illustrano il processo.

1. Accedere al portale di Azure e selezionare la sottoscrizione da usare con Log Analytics e che contiene le aree di lavoro Log Analytics. Nella sezione Impostazioni selezionare Provider di risorse come illustrato nell'immagine seguente.

   

2. Cercare microsoft.insights in Provider di risorse. Selezionare quindi Register (Registra).

   

Impostare le autorizzazioni

1. Assicurarsi che l'utente che configura l'integrazione di Log Analytics abbia il ruolo Collaboratore Log Analytics dell'area di lavoro Log Analytics. Quando si seleziona Controllo di accesso (IAM) per la sottoscrizione nel portale di Azure e quindi Assegnazioni di ruolo dalle selezioni principali nel pannello, l'utente corrente visualizzerà una voce: Collaboratore Log Analytics per l'utente che configura Log Analytics:

   

Dopo aver completato questi passaggi, la parte di configurazione di Log Analytics di Azure è stata completata. La sezione successiva illustra come continuare e completare la configurazione nel portale di amministrazione di Power BI.

Consenti registrazione a livello di area di lavoro dal portale di amministrazione

Un amministratore di Power BI deve completare il passaggio seguente per abilitare Log Analytics di Azure per le aree di lavoro di Power BI Premium. Questa impostazione consente agli amministratori dell'area di lavoro di Power BI Premium di inviare i log dell'area di lavoro a Log Analytics di Azure quando sono stati soddisfatti i prerequisiti.

1. Nel portale di amministrazione di Power BI passare a Impostazioni tenant > Impostazioni di controllo e utilizzo ed espandere Connessioni Log Analytics per gli amministratori dell'area di lavoro. Per consentire agli amministratori dell'area di lavoro di abilitare Log Analytics, impostare il dispositivo di scorrimento su Abilitato e specificare i gruppi di sicurezza necessari in Applica a, come illustrato nell'immagine seguente.

   

Configurare la registrazione in un'area di lavoro Premium

1. Nell'area di lavoro Premium gli amministratori dell'area di lavoro possono abilitare Log Analytics. A tale scopo, passare a Impostazioni come illustrato nell'immagine seguente.

   

2. Nel riquadro Impostazioni selezionare Connessioni di Azure, quindi espandere Log Analytics come illustrato nell'immagine seguente.

   

3. Selezionare la sottoscrizione di Azure, il gruppo di risorse e quindi l'area di lavoro Log Analytics configurata nella sezione precedente. Scegli quindi Salva. Al termine, la sezione Log Analytics a livello di tenant espansa dovrebbe essere simile all'immagine seguente.

   

Disconnettere Azure Log Analytics

È possibile disconnettersi da Log Analytics di Azure per interrompere l'invio dei log ad Azure. Per disconnettersi, nella Impostazioni dell'area di lavoro di Power BI passare alle impostazioni di Log Analytics. Selezionare Disconnetti da Azure. Scegliere quindi Salva per disconnettersi.

Scenari di utilizzo

Esistono molti modi in cui Log Analytics di Azure e Power BI possono aiutare a risolvere le sfide reali per l'organizzazione. Considerare quanto segue:

• Identificare i periodi di attività del motore di Analysis Services elevati o insoliti in base alla capacità, all'area di lavoro, al report o all'utente.
• Analizzare le prestazioni e le tendenze delle query, incluse le operazioni DirectQuery esterne.
• Analizzare la durata dell'aggiornamento del modello semantico, le sovrapposizioni e i passaggi di elaborazione.
• Analizzare le operazioni personalizzate inviate usando l'endpoint XMLA Premium.

Inviare commenti e suggerimenti nella Community di Power BI per informazioni su come si usa la registrazione e su come ha aiutato l'organizzazione.

Condizioni e risoluzioni degli errori

La tabella seguente fornisce una raccolta di errori comuni, gli eventi o le configurazioni che li hanno attivati e le risoluzioni suggerite.

Eventi e schema

Dopo aver abilitato Log Analytics di Azure, inizia a registrare le categorie di eventi seguenti. Per altre informazioni su questi eventi, vedere Eventi traccia di Analysis Services.

• AggregateTableRewriteQuery
• Comando
• Deadlock
• DirectQuery
• Rilevazione
• Error
• ProgressReport
• Query
• Inizializzazione sessione
• VertiPaqSEQuery
• Notifica

Nella tabella seguente viene descritto lo schema.

Evento ExecutionMetrics

Per ogni richiesta di Discover, Command e Query, viene generato un evento denominato ExecutionMetrics alla fine della richiesta. Questo evento contiene le metriche di esecuzione per la richiesta, che consentono di diagnosticare e risolvere i problemi in modo più efficace. La traccia ExecutionMetrics è correlata all'evento [Discover|Command|Query]End più vicino.

La query KQL seguente recupera gli eventi ExecutionMetrics per tutte le operazioni di aggiornamento di un modello semantico nell'ultimo giorno:

let commands = PowerBIDatasetsWorkspace
    | where TimeGenerated > ago(1d)
    | where ArtifactId =~ "[Semantic Model Id]"
    | where OperationName in ("CommandEnd")
    | where EventText contains "<Refresh"
    | project TimeGenerated, ArtifactId, CommandOperationName = OperationName, XmlaRequestId, CorrelationId, CommandText = EventText;
let executionMetrics = PowerBIDatasetsWorkspace        
    | where OperationName == "ExecutionMetrics"
    | project TimeGenerated, XmlaRequestId, CorrelationId, EventText;
commands
| join kind=leftouter executionMetrics on XmlaRequestId

La query KQL seguente recupera gli eventi limitati nell'ultimo giorno dall'area di lavoro, dall'elemento e dall'utente:

let executionMetrics = PowerBIDatasetsWorkspace
    | where TimeGenerated > ago(1d)    
    | where OperationName == "ExecutionMetrics"    
    | extend eventTextJson = parse_json(EventText)      
    | extend capacityThrottlingMs=toint(eventTextJson.capacityThrottlingMs)
    | where capacityThrottlingMs > 0;
let commands = PowerBIDatasetsWorkspace    
    | where OperationName in ("CommandEnd", "QueryEnd", "DiscoverEnd")    
    | project
        TimeGenerated,
        ExecutingUser,
        ArtifactId,
        PowerBIWorkspaceId,
        CommandOperationName = OperationName,
        XmlaRequestId,
        CorrelationId,
        CommandText = EventText;
commands
| join kind=inner executionMetrics on XmlaRequestId
| project
    TimeGenerated,
    ArtifactId,
    PowerBIWorkspaceId,
    ExecutingUser,
    CommandOperationName,
    XmlaRequestId,
    EventText,
    CommandText,
    capacityThrottlingMs
| summarize countThrottling = count(), avgThrottlingDuration = avg(capacityThrottlingMs) by PowerBIWorkspaceId, ArtifactId, ExecutingUser, CommandOperationName

Le statistiche vengono presentate come testo JSON nella proprietà EventText, vedere gli esempi seguenti.

{
    "timeStart": "2024-03-20T12:39:59.681Z",
    "timeEnd": "2024-03-20T13:01:14.241Z",
    "durationMs": 1274559,    
    "vertipaqJobCpuTimeMs": 156,
    "mEngineCpuTimeMs": 9617484,
    "totalCpuTimeMs": 9618469,
    "executionDelayMs": 10,
    "approximatePeakMemConsumptionKB": 1683409,
    "mEnginePeakMemoryKB": 1676816,
    "tabularConnectionTimeoutMs": 18000000,    
    "refreshParallelism": 16,
    "vertipaqTotalRows": 114,
    "intendedUsage": 2
}

{
    "timeStart": "2024-05-07T13:42:21.362Z",
    "timeEnd": "2024-05-07T13:43:30.505Z",
    "durationMs": 69143,
    "datasourceConnectionThrottleTimeMs": 0,
    "directQueryConnectionTimeMs": 3,
    "directQueryIterationTimeMs": 1,
    "directQueryTotalTimeMs": 121872,
    "queryProcessingCpuTimeMs": 16,
    "totalCpuTimeMs": 63,
    "executionDelayMs": 0,
    "approximatePeakMemConsumptionKB": 3632,
    "directQueryTimeoutMs": 225000,
    "tabularConnectionTimeoutMs": 225000,
    "queryDialect": 3,
    "queryResultRows": 67,
    "directQueryRequestCount": 2,
    "directQueryTotalRows": 134
}

Nella tabella seguente vengono descritte tutte le proprietà possibili. Non tutte le proprietà vengono generate in ogni evento, perché il contenuto dipenderà dalla richiesta e dal modello semantico.

• Tutte le durate e i tempi di CPU vengono presentati in millisecondi.
• È possibile che vengano rilevate proprietà aggiuntive oltre a quelle descritte nella tabella precedente, da considerare come non documentate e soggette a modifiche.

Esempio di query KQL di Log Analytics

La raccolta di query di esempio seguente può essere utile quando si usa Log Analytics di Azure con Power BI. Possono essere eseguiti direttamente nel portale di Azure o tramite API per eseguire query sui dati più recenti, in genere circa 5-10 minuti.

// log count per day for last 30d
PowerBIDatasetsWorkspace
| where TimeGenerated > ago(30d)
| summarize count() by format_datetime(TimeGenerated, 'yyyy-MM-dd')


// average query duration by day for last 30d
PowerBIDatasetsWorkspace
| where TimeGenerated > ago(30d)
| where OperationName == 'QueryEnd'
| summarize avg(DurationMs) by format_datetime(TimeGenerated, 'yyyy-MM-dd')


//query duration percentiles for a single day in 1 hour bins
PowerBIDatasetsWorkspace
| where TimeGenerated >= todatetime('2021-04-28') and TimeGenerated <= todatetime('2021-04-29')
| where OperationName == 'QueryEnd'
| summarize percentiles(DurationMs, 0.5, 0.9) by bin(TimeGenerated, 1h)


// refresh durations by workspace and semantic model for last 30d
PowerBIDatasetsWorkspace
| where TimeGenerated > ago(30d)
| where OperationName == 'CommandEnd'
| where ExecutingUser contains 'Power BI Service'
| where EventText contains 'refresh'
| project PowerBIWorkspaceName, DatasetName = ArtifactName, DurationMs

// query count, distinctUsers, avgCPU, avgDuration by workspace for last 30d
PowerBIDatasetsWorkspace  
| where TimeGenerated > ago(30d)
| where OperationName == "QueryEnd" 
| summarize QueryCount=count()
    , Users = dcount(ExecutingUser)
    , AvgCPU = avg(CpuTimeMs)
    , AvgDuration = avg(DurationMs)
by PowerBIWorkspaceId

Modello di report di Power BI di esempio

Esplorare e ottenere informazioni dettagliate sui dati Power BI di Log Analytics di Azure usando un modello di report di Power BI open source in GitHub.

Contenuto correlato

Gli articoli seguenti consentono di ottenere altre informazioni su Power BI e sulla relativa integrazione con Log Analytics di Azure.

• Uso di Azure Log Analytics in Power BI
• Azure Log Analytics in Power BI - Domande frequenti
• Che cos'è Power BI Premium?
• Aree di lavoro in Power BI