Articolo
03/31/2012

COALESCE (Transact-SQL)

Restituisce la prima espressione non Null tra i relativi argomenti.

Icona di collegamento a un argomento Convenzioni della sintassi Transact-SQL

Sintassi

COALESCE (expression [ ,...n ] )

Argomenti

expression
Espressione di qualsiasi tipo.

Tipi restituiti

Restituisce il tipo di dati di expression con la precedenza del tipo di dati più alta. Se tutte le espressioni non ammettono valori Null, il risultato non ammetterà valori Null.

Osservazioni

Se tutti gli argomenti sono NULL, COALESCE restituisce NULL.

Nota

Almeno uno dei valori Null deve essere un valore NULL tipizzato.

COALESCE(expression1,...n) equivale all'espressione CASE seguente:

CASE

WHEN (expression1 IS NOT NULL) THEN expression1

WHEN (expression2 IS NOT NULL) THEN expression2

...

ELSE expressionN

END

Le funzioni ISNULL e COALESCE, sebbene equivalenti, possono presentare comportamenti diversi. Un'espressione che include ISNULL con parametri non Null viene considerata NOT NULL, mentre le espressioni che utilizzano COALESCE con parametri non Null vengono considerate NULL. In SQL Server, per indicizzare espressioni che utilizzano COALESCE con parametri non Null è possibile rendere persistente la colonna calcolata utilizzando l'attributo di colonna PERSISTED come illustrato nell'istruzione seguente:

CREATE TABLE #CheckSumTest 
    (
        ID int identity ,
        Num int DEFAULT ( RAND() * 100 ) ,
        RowCheckSum AS COALESCE( CHECKSUM( id , num ) , 0 ) PERSISTED PRIMARY KEY
    );

Esempi

A. Esecuzione di un esempio semplice

Nell'esempio seguente viene illustrato il modo in cui COALESCE seleziona i dati dalla prima colonna in cui è presente un valore non Null.

USE AdventureWorks2008R2;
GO
SELECT Name, Class, Color, ProductNumber,
COALESCE(Class, Color, ProductNumber) AS FirstNotNull
FROM Production.Product ;
GO

B. Esecuzione di un esempio complesso

Nell'esempio seguente viene illustrata una tabella wages che include tre colonne con informazioni sulla retribuzione annua dei dipendenti, ovvero retribuzione oraria, stipendio e commissione. Un dipendente tuttavia riceve un solo tipo di paga. Per determinare l'importo totale pagato a tutti i dipendenti, utilizzare la funzione COALESCE per ottenere solo i valori non Null delle colonne hourly_wage, salary e commission.

SET NOCOUNT ON;
GO
USE tempdb;
IF OBJECT_ID('dbo.wages') IS NOT NULL
    DROP TABLE wages;
GO
CREATE TABLE dbo.wages
(
    emp_id        tinyint   identity,
    hourly_wage   decimal   NULL,
    salary        decimal   NULL,
    commission    decimal   NULL,
    num_sales     tinyint   NULL
);
GO
INSERT dbo.wages (hourly_wage, salary, commission, num_sales)
VALUES
    (10.00, NULL, NULL, NULL),
    (20.00, NULL, NULL, NULL),
    (30.00, NULL, NULL, NULL),
    (40.00, NULL, NULL, NULL),
    (NULL, 10000.00, NULL, NULL),
    (NULL, 20000.00, NULL, NULL),
    (NULL, 30000.00, NULL, NULL),
    (NULL, 40000.00, NULL, NULL),
    (NULL, NULL, 15000, 3),
    (NULL, NULL, 25000, 2),
    (NULL, NULL, 20000, 6),
    (NULL, NULL, 14000, 4);
GO
SET NOCOUNT OFF;
GO
SELECT CAST(COALESCE(hourly_wage * 40 * 52, 
   salary, 
   commission * num_sales) AS money) AS 'Total Salary' 
FROM dbo.wages
ORDER BY 'Total Salary';
GO

Set di risultati:

Total Salary

------------

20800.0000

41600.0000

62400.0000

83200.0000

10000.0000

20000.0000

30000.0000

40000.0000

45000.0000

50000.0000

120000.0000

56000.0000

(12 row(s) affected)

Vedere anche

Riferimento

ISNULL (Transact-SQL)

CASE (Transact-SQL)

Condividi tramite