Esercizio - Creare e usare un modulo

• 9 minuti

È stata eseguita l'attività di aggiunta di una rete di distribuzione di contenuti, o rete CDN, al sito Web dell'azienda per il lancio di un peluche di vombato. Tuttavia, altri team dell'azienda hanno detto di non aver bisogno di una rete CDN. In questo esercizio si creeranno moduli per il sito Web e la rete CDN e si aggiungeranno i moduli a un modello.

Durante il processo, si eseguiranno queste operazioni:

In questo esercizio viene usata l'estensione Bicep per Visual Studio Code. Assicurarsi di installare questa estensione in Visual Studio Code.

Creare un file Bicep vuoto

1. Aprire Visual Studio Code.

2. Creare un nuovo file denominato main.bicep.

3. Salvare il file vuoto in modo che Visual Studio Code possa caricare gli strumenti di Bicep.

   È possibile selezionare File>Salva con nome oppure premere CTRL+S in Windows (⌘+S in macOS). Assicurarsi di ricordare dove è stato salvato il file. Ad esempio, è possibile creare una cartella templates in cui salvarlo.

Creare un modulo per l'applicazione

1. Creare una nuova cartella denominata moduli nella stessa cartella in cui è stato creato il file main.bicep. Nella cartella moduli creare un file denominato app.bicep. Salvare il file.

2. Aggiungere nel file app.bicep il contenuto seguente:

   @description('The Azure region into which the resources should be deployed.')
   param location string
   
   @description('The name of the App Service app.')
   param appServiceAppName string
   
   @description('The name of the App Service plan.')
   param appServicePlanName string
   
   @description('The name of the App Service plan SKU.')
   param appServicePlanSkuName string
   
   resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSkuName
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2023-12-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   
   @description('The default host name of the App Service app.')
   output appServiceAppHostName string = appServiceApp.properties.defaultHostName
   

   Questo file distribuisce un piano di Servizio app di Azure e un'app. Si noti che il modulo è abbastanza generico. Non include ipotesi sui nomi delle risorse o sullo SKU del piano di servizio app. In questo modo è facile riutilizzare il modulo per distribuzioni diverse.

3. Salvare le modifiche apportate al file.

Aggiungere il modulo al modello Bicep

Qui si aggiunge il modulo dell'app al modello Bicep come punto di partenza.

1. Aprire il file main.bicep.

2. Aggiungere i parametri e la variabile seguenti al file:

   @description('The Azure region into which the resources should be deployed.')
   param location string = 'westus3'
   
   @description('The name of the App Service app.')
   param appServiceAppName string = 'toy-${uniqueString(resourceGroup().id)}'
   
   @description('The name of the App Service plan SKU.')
   param appServicePlanSkuName string = 'F1'
   
   var appServicePlanName = 'toy-product-launch-plan'
   

   Poiché si tratta del modello che si intende distribuire per i siti Web di giocattoli, è un po' più specifico. Il nome del piano del servizio app è definito come variabile. Il parametro SKU ha un valore predefinito che ha senso per il sito Web di lancio del giocattolo.

   Suggerimento

   Si specifica che il parametro location deve essere impostato su westus3. In genere, si creano risorse nella stessa località del gruppo di risorse usando la proprietà resourceGroup().location. Ma quando si lavora con la sandbox di Microsoft Learn, è necessario usare determinate aree di Azure che non corrispondono alla posizione del gruppo di risorse.

3. Sotto i parametri creare una riga vuota. Digitare ora la prima riga della definizione del modulo dell'app:

   module app 'modules/app.bicep' = {
   

   Quando si digita, si noti che l'estensione Bicep per Visual Studio Code consente di supportare la dichiarazione del modulo. Quando si digita il percorso del modulo e si digita il carattere equals (=), viene visualizzato un menu popup con diverse opzioni.

4. Nel menu popup selezionare Proprietà obbligatorie:

   

5. Completare la dichiarazione del modulo:

   module app 'modules/app.bicep' = {
     name: 'toy-launch-app'
     params: {
       appServiceAppName: appServiceAppName
       appServicePlanName: appServicePlanName
       appServicePlanSkuName: appServicePlanSkuName
       location: location
     }
   }
   

6. Nella parte inferiore del file definire un output:

   @description('The host name to use to access the website.')
   output websiteHostName string = app.outputs.appServiceAppHostName
   

7. Salvare le modifiche apportate al file.

Creare un modulo per la rete di distribuzione di contenuti

1. Nella cartella moduli creare un file denominato cdn.bicep. Salvare il file.

2. Aggiungere il contenuto seguente nel file cdn.bicep:

   @description('The host name (address) of the origin server.')
   param originHostName string
   
   @description('The name of the CDN profile.')
   param profileName string = 'cdn-${uniqueString(resourceGroup().id)}'
   
   @description('The name of the CDN endpoint')
   param endpointName string = 'endpoint-${uniqueString(resourceGroup().id)}'
   
   @description('Indicates whether the CDN endpoint requires HTTPS connections.')
   param httpsOnly bool
   
   var originName = 'my-origin'
   
   resource cdnProfile 'Microsoft.Cdn/profiles@2024-02-01' = {
     name: profileName
     location: 'global'
     sku: {
       name: 'Standard_Microsoft'
     }
   }
   
   resource endpoint 'Microsoft.Cdn/profiles/endpoints@2024-02-01' = {
     parent: cdnProfile
     name: endpointName
     location: 'global'
     properties: {
       originHostHeader: originHostName
       isHttpAllowed: !httpsOnly
       isHttpsAllowed: true
       queryStringCachingBehavior: 'IgnoreQueryString'
       contentTypesToCompress: [
         'text/plain'
         'text/html'
         'text/css'
         'application/x-javascript'
         'text/javascript'
       ]
       isCompressionEnabled: true
       origins: [
         {
           name: originName
           properties: {
             hostName: originHostName
           }
         }
       ]
     }
   }
   
   @description('The host name of the CDN endpoint.')
   output endpointHostName string = endpoint.properties.hostName
   

   Questo file distribuisce due risorse: un profilo e un endpoint della rete CDN.

3. Salvare le modifiche apportate al file.

Aggiungere i moduli al modello Bicep principale

1. Aprire il file main.bicep.

2. Sotto il parametro appServicePlanSkuName aggiungere il parametro seguente:

   @description('Indicates whether a CDN should be deployed.')
   param deployCdn bool = true
   

3. Sotto la definizione del modulo app definire il modulo cdn:

   module cdn 'modules/cdn.bicep' = if (deployCdn) {
     name: 'toy-launch-cdn'
     params: {
       httpsOnly: true
       originHostName: app.outputs.appServiceAppHostName
     }
   }
   

   Si noti che il modulo ha una condizione per cui viene distribuito solo quando il valore del parametro deployCdn è impostato su true. Si noti anche che il parametro originHostName del modulo è impostato sul valore dell'output appServiceAppHostName del modulo app.

4. Aggiornare l'output del nome host in modo da selezionare il nome host corretto. Quando viene distribuita una rete CDN, si vuole che il nome host sia quello dell'endpoint della rete CDN.

   output websiteHostName string = deployCdn ? cdn.outputs.endpointHostName : app.outputs.appServiceAppHostName
   

5. Salvare le modifiche apportate al file.

Distribuire il modello Bicep in Azure

az bicep install && az bicep upgrade

az configure --defaults group="<rgn>[sandbox resource group name]</rgn>"

az deployment group create --template-file main.bicep

Set-AzDefault -ResourceGroupName <rgn>[sandbox resource group name]</rgn>

New-AzResourceGroupDeployment -TemplateFile main.bicep

Esaminare la cronologia di distribuzione

1. Passare al portale di Azure e assicurarsi di trovarsi nella sottoscrizione dell'ambiente sandbox.

   1. Selezionare l'avatar nell'angolo superiore destro della pagina.
   2. Selezionare Cambia directory. Nell'elenco scegliere la directory Microsoft Learn Sandbox.

2. Nel pannello di sinistra selezionare Gruppi di risorse.

3. Selezionare [nome gruppo di risorse sandbox].

4. Nel menu a sinistra selezionare Distribuzioni.

   

   Sono elencate tre distribuzioni.

5. Selezionare la distribuzione principale ed espandere Dettagli della distribuzione.

   Si noti che sono elencati entrambi i moduli e che i relativi tipi sono visualizzati come Microsoft.Resources/deployments. I moduli sono elencati due volte perché all'interno del modello si fa riferimento anche ai relativi output.

   

6. Selezionare le distribuzioni toy-launch-cdn e toy-launch-app ed esaminare le risorse distribuite in ognuna. Si noti che corrispondono alle risorse definite nei rispettivi moduli.

Testare il sito Web

1. Selezionare la distribuzione toy-launch-app.

2. Selezionare Output.

   

3. Selezionare il pulsante di copia per l'output appServiceAppHostName.

4. In una nuova scheda del browser provare a passare all'indirizzo copiato nel passaggio precedente. L'indirizzo deve iniziare con https://.

   

   Viene visualizzata la pagina iniziale del servizio app che mostra che l'app è stata distribuita correttamente.

5. Passare alla distribuzione principale e selezionare Output.

6. Copiare il valore dell'output websiteHostName. Si noti che questo nome host è diverso, perché è un nome host della Rete di distribuzione dei contenuti di Microsoft Azure.

7. In una nuova scheda del browser provare a passare al nome host copiato nel passaggio precedente. Aggiungere https:// all'inizio dell'indirizzo.

   L'attivazione degli endpoint della rete CDN richiede alcuni minuti. Se viene visualizzato un errore Pagina non trovata, attendere alcuni minuti e riprovare a incollare il collegamento. Assicurarsi anche di aver aggiunto https:// all'inizio dell'URL in modo che si usi HTTPS.

   Quando l'endpoint della rete CDN è attivo, verrà visualizzata la stessa pagina iniziale del servizio app. Questa volta, è stata servita tramite il servizio Rete di distribuzione dei contenuti di Microsoft Azure, che consente di migliorare le prestazioni del sito Web.