Metodo Session.Invoke

Richiama un metodo e restituisce i risultati della chiamata del metodo.

Sintassi

Session.Invoke( _
  ByVal actionUri, _
  ByVal resourceUri, _
  ByVal parameters, _
  [ ByVal flags ] _
)

Parametri

actionUri [in]

URI del metodo da richiamare.

resourceUri [in]

Identificatore della risorsa da recuperare.

Questo parametro può contenere uno dei seguenti elementi:

• URI con o senza selettori. Nell'esempio di Visual Basic Scripting Edition (VBScript) seguente la chiave viene specificata da Win32_Service?Name=winmgmt.

  strResourceUri = "http://schemas.microsoft.com/wbem/wsman/1/" _ 
     & "Win32_Service?Name=winmgmt"
  

• Oggetto ResourceLocator che può contenere selettori, frammenti o opzioni.

• Riferimento all'endpoint di indirizzamento WS, come descritto nello standard WS-Management Protocol. Per altre informazioni sulla specifica pubblica per il protocollo di WS-Management, vedere Pagina Relativa alle specifiche di gestione.

parametri [in]

Rappresentazione XML dell'input per il metodo. Questa stringa deve essere fornita o questo metodo avrà esito negativo.

flag [in, facoltativo]

Riservato. Deve essere 0.

Valore restituito

Rappresentazione XML dell'output del metodo.

Esempio

L'esempio di codice VBScript seguente avvia un processo di Calc.exe. Il parametro strInputParameters contiene i parametri di input in formato XML. L'unico parametro di input richiesto per il metodo Createdella classe Win32_Process WMI è la riga di comando da eseguire.

Set objWsman = CreateObject( "WSMan.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" & _
    "wmi/root/cimv2/Win32_Process"

strInputParameters = "<p:Create_INPUT " & _
    "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/wmi/root/cimv2/Win32_Process"">" & _
    "<p:CommandLine>" & "calc.exe" & _
    "</p:CommandLine>" & _
    "</p:Create_INPUT>"

strOutputParameters = objSession.Invoke( "Create", _
    strResource, strInputParameters )

DisplayOutput( strOutputParameters )

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Nell'esempio di codice VBScript seguente viene chiamato il metodo Session.Invoke per eseguire il metodo StopService di Win32_Service. Il metodo StopService non dispone di parametri di input. Tuttavia, il metodo Invoke richiede una stringa XML nel parametro parametri .

Option Explicit

Dim objWsman
Dim objSession
Dim strResponse
Dim strActionURI
Dim strInputXml
Dim strResourceURI
Dim strMethodName

set objWsman = CreateObject("Wsman.Automation")
set objSession = objWsman.CreateSession
strResourceURI = "http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service?Name=w32time"
strMethodName = "StopService"
strActionURI = strMethodName                                      

strInputXml = "<p:StopService_INPUT " _
    & "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service""/>"

strResponse = objSession.Invoke(strMethodName, strResourceURI, strInputXml)

call DisplayOutput(strResponse)
 
strMethodName = "StartService" 
strActionURI = strResourceURI & "/" & strMethodName  
strInputXml = "<p:StartService_INPUT " _
    & "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service""/>"
strResponse = objSession.Invoke(strMethodName, _
    strResourceURI, strInputXml)

call DisplayOutput(strResponse)

 
'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************

Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" )    
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile )           
End Sub

Requisiti

Vedi anche

sessione