クイックスタート: Terraform を使用して Azure API Management インスタンスを作成する

[アーティクル]
10/29/2024

適用対象: Developer | Standard | Premium

この記事では、Terraform を使用して Azure 上に API Management インスタンスを作成する方法について説明します。 API Management インスタンスへの API のインポートなど、一般的な管理タスクに Terraform を使用することもできます。

Azure API Management が組織にもたらす利点は、外部のパートナーや社内の開発者に API を公開することによって、社内に眠っているデータやサービスの可能性を発掘できることです。 API Management は、開発者の取り組み、ビジネスインサイト、分析、セキュリティ、保護を通じて API プログラムの価値を高め、企業にコアコンピテンシーをもたらします。 API Management を使用すると、任意の場所でホストされている既存のバックエンドサービス用に最新の API ゲートウェイを作成して管理できます。

Terraform を使用すると、クラウドインフラストラクチャの定義、プレビュー、およびデプロイを行うことができます。 Terraform を使用する際は、HCL 構文を使って構成ファイルを作成します。 HCL 構文では、Azure などのクラウドプロバイダーと、クラウドインフラストラクチャを構成する要素を指定できます。構成ファイルを作成したら、"実行プラン" を作成します。これにより、インフラストラクチャの変更をデプロイ前にプレビューすることができます。変更を確認したら、実行プランを適用してインフラストラクチャをデプロイします。

この記事では、次のことについて説明します。

random_pet を使用して Azure リソースグループ名のランダムなペット名を作成する
azurerm_resource_group を使用して Azure リソースグループを作成する
random_string を使用して Azure API Management サービス名のランダムな文字列を作成する
azurerm_api_management を使用して Azure API Management サービスを作成する

前提条件

Azure サブスクリプションをお持ちでない場合は、開始する前に無料アカウントを作成してください。
Terraform のインストールと構成
Azure CLI の場合
- Azure Cloud Shell で Bash 環境を使用します。詳細については、「Azure Cloud Shell の Bash のクイックスタート」を参照してください。
- CLI リファレンスコマンドをローカルで実行する場合、Azure CLI をインストールします。 Windows または macOS で実行している場合は、Docker コンテナーで Azure CLI を実行することを検討してください。詳細については、「Docker コンテナーで Azure CLI を実行する方法」を参照してください。
  - ローカルインストールを使用する場合は、az login コマンドを使用して Azure CLI にサインインします。認証プロセスを完了するには、ターミナルに表示される手順に従います。その他のサインインオプションについては、Azure CLI でのサインインに関するページを参照してください。
  - 初回使用時にインストールを求められたら、Azure CLI 拡張機能をインストールします。拡張機能の詳細については、Azure CLI で拡張機能を使用する方法に関するページを参照してください。
  - az version を実行し、インストールされているバージョンおよび依存ライブラリを検索します。最新バージョンにアップグレードするには、az upgrade を実行します。
Azure PowerShell の場合:
- Azure PowerShell をローカルで使用する場合は、次のようにします。
  - Az PowerShell モジュールの最新バージョンをインストールします。
  - Connect-AzAccount コマンドレットを使用して、Azure アカウントに接続します。
- Azure Cloud Shell を使用する場合は、次のようにします。
  - 詳細については、Azure Cloud Shell の概要に関するページを参照してください。

Terraform コードを実装する

注意

この記事のサンプルコードは、Azure Terraform GitHub リポジトリにあります。 Terraform の現在および以前のバージョンのテスト結果を含むログファイルを表示できます。

Terraform を使用して Azure リソースを管理する方法を示すその他の記事とサンプルコードを参照してください

サンプル Terraform コードをテストして実行するディレクトリを作成し、それを現在のディレクトリにします。

main.tf という名前のファイルを作成し、次のコードを挿入します。

resource "random_pet" "rg_name" {
  prefix = var.resource_group_name_prefix
}

resource "azurerm_resource_group" "rg" {
  name     = random_pet.rg_name.id
  location = var.resource_group_location
}

resource "random_string" "azurerm_api_management_name" {
  length  = 13
  lower   = true
  numeric = false
  special = false
  upper   = false
}

resource "azurerm_api_management" "api" {
  name                = "apiservice${random_string.azurerm_api_management_name.result}"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  publisher_email     = var.publisher_email
  publisher_name      = var.publisher_name
  sku_name            = "${var.sku}_${var.sku_count}"
}

outputs.tf という名前のファイルを作成し、次のコードを挿入します。

output "resource_group_name" {
  value = azurerm_resource_group.rg.name
}

output "api_management_service_name" {
  value = azurerm_api_management.api.name
}

providers.tf という名前のファイルを作成し、次のコードを挿入します。

terraform {
  required_version = ">=1.0"
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~>3.0"
    }
    random = {
      source  = "hashicorp/random"
      version = "~>3.0"
    }
  }
}
provider "azurerm" {
  features {}
}

variables.tf という名前のファイルを作成し、次のコードを挿入します。

variable "resource_group_location" {
  type        = string
  default     = "eastus"
  description = "Location for all resources."
}

variable "resource_group_name_prefix" {
  type        = string
  default     = "rg"
  description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
}

variable "publisher_email" {
  default     = "test@contoso.com"
  description = "The email address of the owner of the service"
  type        = string
  validation {
    condition     = length(var.publisher_email) > 0
    error_message = "The publisher_email must contain at least one character."
  }
}

variable "publisher_name" {
  default     = "publisher"
  description = "The name of the owner of the service"
  type        = string
  validation {
    condition     = length(var.publisher_name) > 0
    error_message = "The publisher_name must contain at least one character."
  }
}

variable "sku" {
  description = "The pricing tier of this API Management service"
  default     = "Developer"
  type        = string
  validation {
    condition     = contains(["Developer", "Standard", "Premium"], var.sku)
    error_message = "The sku must be one of the following: Developer, Standard, Premium."
  }
}

variable "sku_count" {
  description = "The instance size of this API Management service."
  default     = 1
  type        = number
  validation {
    condition     = contains([1, 2], var.sku_count)
    error_message = "The sku_count must be one of the following: 1, 2."
  }
}

Terraform を初期化する

terraform init を実行して、Terraform のデプロイを初期化します。このコマンドによって、Azure リソースを管理するために必要な Azure プロバイダーがダウンロードされます。

terraform init -upgrade

重要なポイント:

-upgrade パラメーターは、必要なプロバイダープラグインを、構成のバージョン制約に準拠する最新バージョンにアップグレードします。

Terraform 実行プランを作成する

terraform plan を実行して、実行プランを作成します。

terraform plan -out main.tfplan

重要なポイント:

terraform plan コマンドは、実行プランを作成しますが、実行はしません。代わりに、構成ファイルに指定された構成を作成するために必要なアクションを決定します。このパターンを使用すると、実際のリソースに変更を加える前に、実行プランが自分の想定と一致しているかどうかを確認できます。
省略可能な -out パラメーターを使用すると、プランの出力ファイルを指定できます。 -out パラメーターを使用すると、レビューしたプランが適用内容とまったく同じであることが確実になります。

Terraform 実行プランを適用する

terraform apply を実行して、クラウドインフラストラクチャに実行プランを適用します。

terraform apply main.tfplan

重要なポイント:

terraform apply コマンドの例は、以前に terraform plan -out main.tfplan が実行されたことを前提としています。
-out パラメーターに別のファイル名を指定した場合は、terraform apply の呼び出しで同じファイル名を使用します。
-out パラメーターを使用しなかった場合は、パラメーターを指定せずに terraform apply を呼び出します。

Note

API Management サービスを作成してアクティブにするには、30 から 40 分かかる場合があります。

Azure リソースグループ名を取得します。

resource_group_name=$(terraform output -raw resource_group_name)

サービス名を取得します。

api_management_service_name=$(terraform output -raw api_management_service_name)

az apim show を実行して、新しいサービスに関する情報を表示します。

az apim show --resource-group $resource_group_name \
             --name $api_management_service_name

Azure リソースグループ名を取得します。

$resource_group_name=$(terraform output -raw resource_group_name)

サービス名を取得します。

$api_management_service_name=$(terraform output -raw api_management_service_name)

Get-AzApiManagement を実行して、新しいサービスに関する情報を表示します。

Get-AzApiManagement -ResourceGroupName $resource_group_name `
                    -Name $api_management_service_name

リソースをクリーンアップする

Terraform を使用して作成したリソースが不要になった場合は、次の手順を実行します。

terraform plan を実行して、destroy フラグを指定します。
```
terraform plan -destroy -out main.destroy.tfplan
```
重要なポイント:
- terraform plan コマンドは、実行プランを作成しますが、実行はしません。代わりに、構成ファイルに指定された構成を作成するために必要なアクションを決定します。このパターンを使用すると、実際のリソースに変更を加える前に、実行プランが自分の想定と一致しているかどうかを確認できます。
- 省略可能な -out パラメーターを使用すると、プランの出力ファイルを指定できます。 -out パラメーターを使用すると、レビューしたプランが適用内容とまったく同じであることが確実になります。
terraform apply を実行して、実行プランを適用します。
```
terraform apply main.destroy.tfplan
```

Azure での Terraform のトラブルシューティング

Azure で Terraform を使用する場合の一般的な問題のトラブルシューティング

次のステップ

チュートリアル:最初の API のインポートと発行

次の方法で共有

クイックスタート: Terraform を使用して Azure API Management インスタンスを作成する

前提条件

Terraform コードを実装する

Terraform を初期化する

Terraform 実行プランを作成する

Terraform 実行プランを適用する

結果を確認する

リソースをクリーンアップする

Azure での Terraform のトラブルシューティング

次のステップ

フィードバック

その他のリソース