Bicep アクセサー演算子

アクセサー演算子は、子リソース、オブジェクトのプロパティ、配列の要素にアクセスするために使われます。 また、プロパティ アクセサーを使用していくつかの関数を使用することもできます。

インデックス アクセサー

array[integerIndex]

object['stringIndex']

インデックス アクセサーを使用して、配列から要素を取得するか、オブジェクトからプロパティを取得します。

配列の場合は、インデックスを整数として指定します。 整数は、取得する要素の 0 から始まる位置と一致します。

オブジェクトの場合は、インデックスを文字列として指定します。 文字列は、取得するオブジェクトの名前と一致します。

次の例では、配列内の要素を取得します。

var arrayVar = [
  'Coho'
  'Contoso'
  'Fabrikam'
]

output accessorResult string = arrayVar[1]

例の出力を次に示します。

次の例では、オブジェクトのプロパティを取得します。

var environmentSettings = {
  dev: {
    name: 'Development'
  }
  prod: {
    name: 'Production'
  }
}

output accessorResult string = environmentSettings['dev'].name

例の出力を次に示します。

関数アクセサー

resourceName.functionName()

getSecret と list*の 2 つの関数は、アクセサー演算子による関数の呼び出しに対応しています。 これら 2 つの関数は、アクセサー演算子をサポートする唯一の関数です。

例

次の例では、既存のキー コンテナーを参照し、getSecret を使用してモジュールにシークレットを渡します。

resource kv 'Microsoft.KeyVault/vaults@2023-07-01' existing = {
  name: kvName
  scope: resourceGroup(subscriptionId, kvResourceGroup )
}

module sql './sql.bicep' = {
  name: 'deploySQL'
  params: {
    sqlServerName: sqlServerName
    adminLogin: adminLogin
    adminPassword: kv.getSecret('vmAdminPassword')
  }
}

入れ子になったリソース アクセサー

parentResource::nestedResource

入れ子になったリソースとは、別のリソース内で宣言されているリソースです。 入れ子になったリソース アクセサー :: を使用して、親リソースの外部から入れ子になったリソースにアクセスします。

親リソース内では、シンボリック名だけを使用して、入れ子になったリソースを参照します。 入れ子になったリソース アクセサーは、親リソースの外部から、入れ子になったリソースを参照する場合にのみ使用する必要があります。

例

次の例は、親リソース内から、および親リソースの外部から、入れ子になったリソースを参照する方法を示しています。

resource demoParent 'demo.Rp/parentType@2024-01-01' = {
  name: 'demoParent'
  location: 'West US'

  // Declare a nested resource within 'demoParent'
  resource demoNested 'childType' = {
    name: 'demoNested'
    properties: {
      displayName: 'The nested instance.'
    }
  }

  // Declare another nested resource
  resource demoSibling 'childType' = {
    name: 'demoSibling'
    properties: {
      // Use symbolic name to reference because this line is within demoParent
      displayName: 'Sibling of ${demoNested.properties.displayName}'
    }
  }
}

// Use nested accessor to reference because this line is outside of demoParent
output displayName string = demoParent::demoNested.properties.displayName

プロパティ アクセサー

objectName.propertyName

プロパティ アクセサーは、オブジェクトのプロパティにアクセスするために使用します。 プロパティ アクセサーは、オブジェクトであるパラメーターや変数など、任意のオブジェクトで使用できます。 オブジェクトではない式に対してプロパティ アクセスを使用すると、エラーが発生します。

例

次の例は、オブジェクト変数と、プロパティにアクセスする方法を示しています。

var x = {
  y: {
    z: 'Hello'
    a: true
  }
  q: 42
}

output outputZ string = x.y.z
output outputQ int = x.q

例の出力を次に示します。

通常、Bicep ファイルにデプロイされたリソースでは、プロパティ アクセサーを使用します。 次の例では、パブリック IP アドレスを作成し、プロパティ アクセサーを使用して、デプロイされたリソースから値を返します。

resource publicIp 'Microsoft.Network/publicIPAddresses@2023-11-01' = {
  name: publicIpResourceName
  location: location
  properties: {
    publicIPAllocationMethod: dynamicAllocation ? 'Dynamic' : 'Static'
    dnsSettings: {
      domainNameLabel: publicIpDnsLabel
    }
  }
}

// Use property accessor to get value
output ipFqdn string = publicIp.properties.dnsSettings.fqdn

次のステップ

• この例を実行するには、Azure CLI または Azure PowerShell を使用して、Bicep ファイルをデプロイします。
• Bicep ファイルの作成方法については、「クイックスタート: Visual Studio Code を使用して Bicep ファイルを作成する」を参照してください。
• Bicep の型のエラーを解決する方法については、「Bicep の any 関数」を参照してください。