クエリからの取り込み (.set、.append、.set-or-append、.set-or-replace)

適用対象: ✅Microsoft Fabric✅Azure データ エクスプローラー

これらのコマンドは、クエリまたは管理コマンドを実行し、クエリの結果をテーブルに取り込みます。 これらのコマンドの違いは、既存または存在しないテーブルとデータを扱う方法です。

クエリ コマンドからの取り込みを取り消すには、cancel operation を参照してください。

アクセス許可

テーブルに対して異なるアクションを実行するには、特定のアクセス許可が必要です。

• .append コマンドを使用して既存のテーブルに行を追加するには、最小限の Table Ingestor アクセス許可が必要です。
• さまざまな .set コマンドを使用して新しいテーブルを作成するには、最小限のデータベース ユーザーアクセス許可が必要です。
• .set-or-replace コマンドを使用して既存のテーブル内の行を置き換えるには、最小限のテーブル管理者アクセス許可が必要です。

アクセス許可の詳細については、「 Kusto ロールベースのアクセス制御を参照してください。

構文

(.set | .append | .set-or-append | .set-or-replace) [async] tableName [with (propertyName = propertyValue [, ...])] <| queryOrCommand

構文規則について詳しく知る。

パラメーター

パフォーマンスに関するヒント

• クエリによって生成されるデータの量が大きく、1 GB を超え、シリアル化を必要としない場合は、 distributed プロパティを true に設定します。 その後、複数のノードが並列で出力を生成できます。 クエリ結果が小さい場合は、このフラグを使用しないでください。これは、多数の小さなデータ シャードを不必要に生成する可能性があるためです。
• データ インジェストは、クエリの実行など、データベース上の同時アクティビティに影響する可能性がある、リソースを集中的に使用する操作です。 同時に実行するインジェスト コマンドが多くなりすぎないようにします。
• インジェスト操作ごとにインジェストのデータを 1 GB 未満に制限します。 必要に応じて、複数のインジェスト コマンドを使用します。

サポートされるインジェストのプロパティ

スキーマに関する考慮事項

• .set-or-replace は、 extend_schema または recreate_schema インジェストプロパティのいずれかが trueに設定されていない限り、スキーマを保持します。
• .set-or-appendextend_schema インジェスト プロパティが true に設定されていない限り、.append コマンドはスキーマを保持します。
• 結果セット スキーマとターゲット テーブルのスキーマの照合は、列の種類に基づいています。 列名の照合はありません。 クエリ結果のスキーマ列がテーブルと同じ順序であることを確認します。それ以外の場合は、データが間違った列に取り込まれます。

文字制限

クエリで $ 文字を持つエンティティ名が生成された場合、コマンドは失敗します。 名は名前付け規則に準拠している必要があるため、取り込みコマンドを成功させるには$文字を削除する必要があります。

たとえば、次のクエリでは、 search 演算子によって列 $tableが生成されます。 クエリ結果を格納するには、 project-rename を使用して列の名前を変更します。

.set Texas <| search State has 'Texas' | project-rename tableName=$table

例

LogsTable と同じスキーマを持ち、過去 1 時間のすべてのエラー レコードを保持する RecentErrors という名前の新しいテーブルをデータベースに作成します。

.set RecentErrors <|
   LogsTable
   | where Level == "Error" and Timestamp > now() - time(1h)

"ExtentId" という 1 つの列を持つデータベースに "OldExtents" という名前の新しいテーブルを作成し、30 日以上前に作成されたデータベース内のすべてのエクステントのエクステント ID を保持します。 データベースには、"MyExtents" という名前の既存のテーブルがあります。 データセットは 1 GB (約 100 万行を超える) を超えると予想されるため、 分散 フラグを使用します

.set async OldExtents with(distributed=true) <|
   MyExtents 
   | where CreatedOn < now() - time(30d)
   | project ExtentId

現在のデータベース内の "OldExtents" という名前の既存のテーブルにデータを追加します。このテーブルには、"extent ID" という 1 つの列があり、30 日よりも前に作成されたデータベース内のすべてのエクステントのエクステント ID が保持されます。 "MyExtents" という名前の既存のテーブルに基づいて、タグ tagA と tagB を使用して新しいエクステントにマークします。

.append OldExtents with(tags='["TagA","TagB"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

現在のデータベース内の "OldExtents" テーブルにデータを追加するか、テーブルがまだ存在しない場合は作成します。 新しいエクステントに ingest-by:myTag を使用してタグを付けます。 これは、"MyExtents" という名前の既存のテーブルに基づいて、ingest-by:myTag を使用してタグ付けされたエクステントがテーブルにまだ存在しない場合にのみ行います。

.set-or-append async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <|
   MyExtents
   | where CreatedOn < now() - time(30d)
   | project ExtentId

現在のデータベース内の "OldExtents" テーブルのデータを置き換えるか、テーブルがまだ存在しない場合は作成します。 新しいエクステントに ingest-by:myTag を使用してタグを付けます。

.set-or-replace async OldExtents with(tags='["ingest-by:myTag"]', ingestIfNotExists='["myTag"]') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId

エクステントの作成時間を過去の特定の日時に設定しながら、現在のデータベースの "OldExtents" テーブルにデータを追加します。

.append async OldExtents with(creationTime='2017-02-13T11:09:36.7992775Z') <| 
   MyExtents 
   | where CreatedOn < now() - time(30d) 
   | project ExtentId     

出力を返す

.set または .append コマンドによって作成されたエクステントに関する情報を返します。

出力例