pivot プラグイン

適用対象: ✅Microsoft Fabric✅Azure データ エクスプローラー

入力テーブルの 1 つの列から出力テーブルの複数の列に一意の値を変換してテーブルを回転させ、最終出力内の残りの列値に対して必要に応じて集計を実行します。

構文

T | evaluate pivot(pivotColumn[, aggregationFunction] [,column1 [,column2 ... ]]) [: OutputSchema]

構文規則について詳しく知る。

パラメーター

返品

Pivot は、指定された列 (column1、column2、...) とピボット列のすべての一意の値を含む、回転したテーブルを返します。 ピボットされた列の各セルには、集計関数の計算が含まれます。

例

列によるピボット

EventType と "AL" で始まる州ごとに、この州内のこの種類のイベント数を数えます。

StormEvents
| project State, EventType
| where State startswith "AL"
| where EventType has "Wind"
| evaluate pivot(State)

出力

集計関数を含む列によるピボット

EventType と "AR" で始まる州ごとに、直接の死因の合計数を表示します。

StormEvents
| where State startswith "AR"
| project State, EventType, DeathsDirect
| where DeathsDirect > 0
| evaluate pivot(State, sum(DeathsDirect))

出力

集計関数と 1 つの追加列を含む列によるピボット

結果は前の例と同じです。

StormEvents
| where State startswith "AR"
| project State, EventType, DeathsDirect
| where DeathsDirect > 0
| evaluate pivot(State, sum(DeathsDirect), EventType)

出力

ピボットされた列、集計関数、複数の追加列を指定する

イベントの種類、情報源、州ごとに、直接の死因の数を合計します。

StormEvents
| where State startswith "AR"
| where DeathsDirect > 0
| evaluate pivot(State, sum(DeathsDirect), EventType, Source)

出力

クエリ定義の出力スキーマを使用したピボット

次の例では、StormEvents テーブル内の特定の列を選択します。 これは、実際のクエリを実行する前に、さまざまな最適化を評価できる明示的なスキーマ定義を使用します。

StormEvents
| project State, EventType
| where EventType has "Wind"
| evaluate pivot(State): (EventType:string, ALABAMA:long, ALASKA:long)

出力