Join 句 (Visual Basic)
2 つのコレクションを単一のコレクションに結合します。 結合操作は、一致するキーに基づき、Equals 演算子を使用します。
構文
Join element In collection _
[ joinClause _ ]
[ groupJoinClause ... _ ]
On key1 Equals key2 [ And key3 Equals key4 [... ]
指定項目
element 必須。 結合されるコレクションの制御変数。
collection
必須です。 Join 演算子の左側に指定されているコレクションと結合するコレクション。 Join 句は、別の Join 句、または Group Join 句で入れ子にすることができます。
joinClause
任意。 クエリをさらに絞り込むための 1 つ以上の追加の Join 句。
groupJoinClause
任意。 クエリをさらに絞り込むための 1 つ以上の追加の Group Join 句。
key1 Equals key2
必須です。 結合されるコレクションのキーを識別します。 Equals 演算子を使用して、結合されるコレクションのキーを比較する必要があります。 結合条件を組み合わせるには、複数のキーを識別するために、And 演算子を使用します。 key1 は、Join 演算子の左側にあるコレクションのものである必要があります。 key2 は、Join 演算子の右側にあるコレクションのものである必要があります。
結合条件で使用されるキーは、コレクションからの複数の項目を含む式にすることができます。 ただし、各キー式には、それぞれのコレクションの項目のみを含めることができます。
Remarks
Join 句は、結合されるコレクションからの一致するキー値に基づいて、2 つのコレクションを組み合わせます。 結果のコレクションには、Join 演算子の左側に指定されたコレクションと、Join 句で指定されたコレクションからの値の任意の組み合わせが含まれる可能性があります。 クエリから返されるのは、Equals 演算子によって指定された条件を満たした結果だけです。 これは、SQL の INNER JOIN と同じです。
クエリで複数の Join 句を使用して、複数のコレクションを 1 つのコレクションに結合できます。
暗黙的結合を実行して、Join 句を使用せずにコレクションを結合することができます。 これを行うには、From 句に複数の In 句を含め、結合に使用するキーを識別する Where 句を指定します。
Group Join 句を使用して、コレクションを、単一の階層コレクションに結合することができます。 これは、SQL の LEFT OUTER JOIN に似ています。
例 1
次のコード例では、暗黙的結合を実行して、顧客のリストと注文を結合しています。
Dim customerIDs() = {"ALFKI", "VICTE", "BLAUS", "TRAIH"}
Dim customerList = From cust In customers, custID In customerIDs
Where cust.CustomerID = custID
Select cust.CompanyName
For Each companyName In customerList
Console.WriteLine(companyName)
Next
例 2
次のコード例では、Join 句を使用して 2 つのコレクションを結合しています。
Imports System.Diagnostics
Public Class JoinSample
Public Sub ListProcesses()
Dim processDescriptions As New List(Of ProcessDescription)
processDescriptions.Add(New ProcessDescription With {
.ProcessName = "explorer",
.Description = "Windows Explorer"})
processDescriptions.Add(New ProcessDescription With {
.ProcessName = "winlogon",
.Description = "Windows Logon"})
processDescriptions.Add(New ProcessDescription With {
.ProcessName = "cmd",
.Description = "Command Window"})
processDescriptions.Add(New ProcessDescription With {
.ProcessName = "iexplore",
.Description = "Internet Explorer"})
Dim processes = From proc In Process.GetProcesses
Join desc In processDescriptions
On proc.ProcessName Equals desc.ProcessName
Select proc.ProcessName, proc.Id, desc.Description
For Each proc In processes
Console.WriteLine("{0} ({1}), {2}",
proc.ProcessName, proc.Id, proc.Description)
Next
End Sub
End Class
Public Class ProcessDescription
Public ProcessName As String
Public Description As String
End Class
この例では、次のような出力が生成されます。
winlogon (968), Windows Logon
explorer (2424), File Explorer
cmd (5136), Command Window
例 3
次のコード例では、2 つのキー列で Join 句を使用して、2 つのコレクションを結合しています。
Imports System.Diagnostics
Public Class JoinSample2
Public Sub ListProcesses()
Dim processDescriptions As New List(Of ProcessDescription2)
' 8 = Normal priority, 13 = High priority
processDescriptions.Add(New ProcessDescription2 With {
.ProcessName = "explorer",
.Description = "Windows Explorer",
.Priority = 8})
processDescriptions.Add(New ProcessDescription2 With {
.ProcessName = "winlogon",
.Description = "Windows Logon",
.Priority = 13})
processDescriptions.Add(New ProcessDescription2 With {
.ProcessName = "cmd",
.Description = "Command Window",
.Priority = 8})
processDescriptions.Add(New ProcessDescription2 With {
.ProcessName = "iexplore",
.Description = "Internet Explorer",
.Priority = 8})
Dim processes = From proc In Process.GetProcesses
Join desc In processDescriptions
On proc.ProcessName Equals desc.ProcessName And
proc.BasePriority Equals desc.Priority
Select proc.ProcessName, proc.Id, desc.Description,
desc.Priority
For Each proc In processes
Console.WriteLine("{0} ({1}), {2}, Priority = {3}",
proc.ProcessName,
proc.Id,
proc.Description,
proc.Priority)
Next
End Sub
End Class
Public Class ProcessDescription2
Public ProcessName As String
Public Description As String
Public Priority As Integer
End Class
この例では、次のような出力が生成されます。
winlogon (968), Windows Logon, Priority = 13
cmd (700), Command Window, Priority = 8
explorer (2424), File Explorer, Priority = 8
関連項目
.NET