地理空間の視覚化

適用対象: ✅Microsoft Fabric✅Azure データ エクスプローラー✅Azure Monitor✅Microsoft Sentinel

地理空間データは、Kusto Desktop Explorer の render 演算子を使用して視覚化できます。 Kusto デスクトップ エクスプローラーをダウンロードするには、「 Kusto.Explorer のインストールとユーザー インターフェイスを参照してください。

地理空間クラスタリングの詳細については、「 地理空間クラスタリング」を参照してください。

マップ上のポイントを視覚化する

[経度、緯度] 列、または GeoJSON 列を使用してポイントを視覚化できます。 系列列の使用は省略可能です。 [経度、緯度] ペアは、各ポイントをその順序で定義します。

例: マップ上のポイントを視覚化する

次の例では、Storm イベントを検索し、マップ上で 100 を視覚化します。

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

例: マップ上の複数の一連のポイントを視覚化する

次の例では、複数の一連のポイントを視覚化します。ここで、[経度、緯度] ペアは各ポイントを定義し、3 番目の列は系列を定義します。 この例では、系列は EventType。

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

例: 複数の列を持つデータ上の一連のポイントを視覚化する

次の例では、マップ上の一連のポイントを視覚化します。 結果に複数の列がある場合は、xcolumn (経度)、ycolumn (緯度)、系列に使用する列を指定する必要があります。

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

例: GeoJSON 動的値によって定義されたマップ上のポイントを視覚化する

次の例では、GeoJSON 動的値を使用してマップ上のポイントを視覚化し、ポイントを定義します。

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

マップ上の円またはバブルの視覚化

[経度、緯度] 列、または GeoJSON 列を使用して、円またはバブルを視覚化できます。 これらの視覚エフェクトは、色軸または数値軸を使用して作成できます。

例: 円グラフを場所別に視覚化する

次の例は、S2 セルで集計された Storm イベントを示しています。 グラフは、円グラフのイベントを場所別に集計します。

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map) // pie map rendering available only in Kusto Explorer desktop

例: 色軸を使用してバブルを視覚化する

次の例は、S2 セルで集計された Storm イベントを示しています。 グラフは、バブルのイベントを場所別に集計します。 色軸 ("count") はすべてのイベントで同じであるため、 render 演算子はバブルを生成します。

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map) // pie map rendering available only in Kusto Explorer desktop

関連するコンテンツ

• 地理空間クラスタリング
• Render 演算子
• 自動車テストフリートのデータ分析 (地理空間クラスタリングのユース ケース)
• 地理空間データの処理と分析のための Azure アーキテクチャについて説明します