ipv4_is_in_any_range()
適用対象: ✅Microsoft Fabric✅Azure データ エクスプローラー✅Azure Monitor✅Microsoft Sentinel
IPv4 文字列アドレスが、指定された IPv4 アドレス範囲のいずれかに含まれているかどうかを確認します。
パフォーマンスに関するヒント
Note
128 を超える検索用語を使用すると、テキスト インデックス検索の最適化が無効になり、クエリのパフォーマンスが低下する可能性があります。
構文
ipv4_is_in_any_range(Ipv4Address , Ipv4Range [ , Ipv4Range ...] )
ipv4_is_in_any_range(Ipv4Address , Ipv4Ranges )
構文規則について詳しく知る。
パラメーター
| 件名 | タイプ | Required | 説明 |
|---|---|---|---|
| Ipv4Address | string |
✔️ | IPv4 アドレスを表す式。 |
| Ipv4Range | string |
✔️ | |
| Ipv4Ranges | dynamic |
✔️ |
Note
1 つ以上の IPv4Range 文字列または IPv4Ranges 動的配列が必要です。
IP - プレフィックスの表記
IP プレフィックス表記 (CIDR 表記とも呼ばれます) は、IP アドレスとそれに関連付けられているネットワーク マスクを表す簡潔な方法です。 形式は <base IP>/<prefix length>で、プレフィックスの長さはネットマスク内の先頭の 1 ビットの数です。 プレフィックスの長さは、ネットワークに属する IP アドレスの範囲を決定します。
IPv4 の場合、プレフィックスの長さは 0 から 32 までの数値です。 したがって、表記 192.168.2.0/24 は、255.255.255.0 のネットマスクを持つ IP アドレス 192.168.2.0 を表します。 このネットマスクには、先頭に 1 ビットが 24 個、プレフィックスの長さが 24 個あります。
IPv6 の場合、プレフィックスの長さは 0 から 128 までの数値です。 そのため、表記 fe80::85d:e82c:9446:7994/120 は、ip アドレス fe80::85d:e82c:9446:7994 を ffff:ffff:ffff:ffff:ffff:ffff:ffff:ff00 のネットマスクで表します。 このネットマスクの先頭は 120 ビット、プレフィックス長は 120 です。
返品
true: IPv4 アドレスが、指定された IPv4 ネットワークの範囲内にある場合。false: それ以外の場合。null: 2 つの IPv4 文字列のいずれかの変換が成功しなかった場合。
例
文字列の一覧を使用した構文
print Result=ipv4_is_in_any_range('192.168.1.6', '192.168.1.1/24', '10.0.0.1/8', '127.1.0.1/16')
出力
| 結果 |
|---|
| true |
動的配列を使用した構文
print Result=ipv4_is_in_any_range("127.0.0.1", dynamic(["127.0.0.1", "192.168.1.1"]))
出力
| 結果 |
|---|
| true |
IPv4 範囲チェックを使用してテーブルを拡張する
let LocalNetworks=dynamic([
"192.168.1.1/16",
"127.0.0.1/8",
"10.0.0.1/8"
]);
let IPs=datatable(IP:string) [
"10.1.2.3",
"192.168.1.5",
"123.1.11.21",
"1.1.1.1"
];
IPs
| extend IsLocal=ipv4_is_in_any_range(IP, LocalNetworks)
出力
| IP | IsLocal |
|---|---|
| 10.1.2.3 | true |
| 192.168.1.5 | true |
| 123.1.11.21 | false |
| 1.1.1.1 | false |