次の方法で共有

横棒グラフ

  • [アーティクル]

適用対象: ✅Microsoft Fabric✅Azure データ エクスプローラー✅Azure Monitor✅Microsoft Sentinel

横棒グラフのビジュアルでは、クエリ結果に少なくと 2 つの列が必要です。 既定では、最初の列が y 軸として使用されます。 この列には、text、datetime、または numeric のデータ型を含めることができます。 その他の列は x 軸として使用され、横線として表示される numeric のデータ型が含まれます。 横棒グラフは、主に数値と不連続の公称値を比較するために使用されます。各線の長さはその値を表します。

Note

この視覚化は、 render 演算子のコンテキストでのみ使用できます。

構文

T | render barchart [with (propertyName = propertyValue [, ...])]

構文規則について詳しく知る。

パラメーター

件名 タイプ Required 説明
T string ✔️ 入力テーブル名。
propertyName, propertyValue string キーと値のプロパティのペアのコンマ区切りのリスト。 サポートされるプロパティを参照してください。

サポートされるプロパティ

すべてのプロパティは省略可能です。

PropertyName PropertyValue
accumulate 各メジャーの値がすべての先行タスク (true または false) に追加されるかどうか。
kind 視覚化の種類のさらに詳細な設定。 詳細については、「 kind プロパティ」を参照してください。
legend 凡例を表示するかどうか (visible または hidden)。
series レコードごとに結合された値によってそのレコードが属する系列が定義される、コンマ区切りの列のリスト。
ymin Y 軸に表示される最小値。
ymax Y 軸に表示される最大値。
title 視覚化のタイトル (string 型)。
xaxis x 軸のスケールを設定する方法 (linear または log)。
xcolumn x 軸に使用される結果の列。
xtitle x 軸のタイトル (string 型)。
yaxis y 軸のスケールを設定する方法 (linear または log)。
ycolumns x 列の値ごとに提供された値で構成される列のコンマ区切りのリスト。
ytitle y 軸のタイトル (string 型)。
ysplit 視覚化を複数の y 軸の値に分割する方法。 詳細については、「 ysplit プロパティ」を参照してください。

ysplit プロパティ

この視覚化では、複数の y 軸値への分割がサポートされています。

ysplit 説明
none 1 つの y 軸がすべての系列データに表示されます。 これが既定です。
axes 1 つのグラフに、複数の y 軸 (系列ごとに 1 つ) が表示されます。
panels ycolumn値ごとに 1 つのグラフがレンダリングされます。

サポートされるプロパティ

すべてのプロパティは省略可能です。

PropertyName PropertyValue
kind 視覚化の種類のさらに詳細な設定。 詳細については、「 kind プロパティ」を参照してください。
series レコードごとに結合された値によってそのレコードが属する系列が定義される、コンマ区切りの列のリスト。
title 視覚化のタイトル (string 型)。

kind プロパティ

この視覚化は、 kind プロパティを指定することでさらに詳しく説明できます。 このプロパティでサポートされている値は次のとおりです。

kind 値 説明
default 各 "横棒" は独立しています。
unstacked default と同じ。
stacked "横棒" を積み上げます。
stacked100 "横棒" を積み上げて、それぞれを他と同じ幅に伸縮します。

例

横棒グラフをレンダリングする

次のクエリでは、各状態の Storm イベントの数を表示する横棒グラフを作成し、10 を超えるイベントを含む状態のみをフィルター処理します。 このグラフは、さまざまな状態にわたるイベント分布を視覚的に表しています。

StormEvents
| summarize event_count=count() by State
| project State, event_count
| render barchart
    with (
    title="Storm count by state",
    ytitle="Storm count",
    xtitle="State",
    legend=hidden
    )

ラベル付き横棒グラフのスクリーンショット。

stacked横棒グラフをレンダリングする

次のクエリでは、選択したテキサス州、カリフォルニア州、フロリダ州の種類別の嵐イベントの合計数を示す stacked 横棒グラフを作成します。 各バーは Storm イベントの種類を表し、積み重ねられたバーには、各種類の状態別の Storm イベントの内訳が表示されます。

StormEvents
| where State in ("TEXAS", "CALIFORNIA", "FLORIDA")
| summarize EventCount = count() by EventType, State
| order by EventType asc, State desc
| render barchart with (kind=stacked)

積み上げ横棒グラフの視覚化のスクラム ショット。

stacked100横棒グラフをレンダリングする

次のクエリでは、選択したテキサス州、カリフォルニア州、フロリダ州の種類別の嵐イベントの合計数を示す stacked100 横棒グラフを作成します。 グラフには、各種類内の州間の Storm イベントの分布が表示されます。 スタックは視覚的に最大 100 個まで合計されますが、実際には、値はパーセンテージではなくイベントの数を表します。 この視覚化は、割合と実際のイベント数の両方を理解するのに役立ちます。

StormEvents
| where State in ("TEXAS", "CALIFORNIA", "FLORIDA")
| summarize EventCount = count() by EventType, State
| order by EventType asc, State desc
| render barchart with (kind=stacked100)

積み上げ横棒グラフの視覚化のスクリーンショット。

ysplit プロパティを使用する

クエリを実行する

StormEvents
| summarize
    TotalInjuries = sum(InjuriesDirect) + sum(InjuriesIndirect),
    TotalDeaths = sum(DeathsDirect) + sum(DeathsIndirect)
    by bin(StartTime, 1d)
| project StartTime, TotalInjuries, TotalDeaths
| render barchart with (ysplit=axes)

ysplit axes プロパティを使用した縦棒グラフのスクリーンショット。

ビューを個別のパネルに分割するには、axesではなくpanelsを指定します。

クエリを実行する

StormEvents
| summarize
    TotalInjuries = sum(InjuriesDirect) + sum(InjuriesIndirect),
    TotalDeaths = sum(DeathsDirect) + sum(DeathsIndirect)
    by bin(StartTime, 1d)
| project StartTime, TotalInjuries, TotalDeaths
| render barchart with (ysplit=panels)

ysplit パネル プロパティを使用した縦棒グラフのスクリーンショット。