次の方法で共有

AddressEntry.GetExchangeUser メソッド (Outlook)

  • [アーティクル]

AddressEntry がグローバル アドレス一覧 (GAL) などの Exchange AddressList オブジェクトに属し、Exchange ユーザーに対応する場合は、AddressEntry を表す ExchangeUser オブジェクトを返します。

構文

式。 GetExchangeUser

式AddressEntry オブジェクトを表す変数。

戻り値

AddressEntry オブジェクトを表す ExchangeUser オブジェクトを返します。 AddressEntry オブジェクトが Exchange ユーザーに対応していない場合は、Null (Visual Basic では Nothing) を返します。

注釈

このメソッドを使用するには、Exchange サーバーに接続している必要があります。

このメソッドを使用して渡された文字列に既存のアドレスのエントリに類似している文字セットがある場合、渡された文字列の最初の文字に一致するエントリが戻り値に含まれる場合があります。

たとえば、アドレス エントリ "Jai" が Outlook アドレス帳に含まれ "Jack" が含まれない場合、Exchange ユーザーに文字列 "Jack" を渡すとします。 "Jack" エントリが Outlook アドレス帳で使用できない場合でも、返される電子メール アドレスは "Null" ではなく、"Jai" です。

例

次のコード サンプルでは、勤務先電話番号、オフィスの場所、および Exchange のグローバル アドレス一覧内のすべての Exchange ユーザーのエントリの役職を取得する方法を示します。 役職 を使用して最初にグローバル アドレス一覧を検索します。 該当する AddressList オブジェクトに含まれている各 AddressEntry オブジェクトに対し、 AddressEntryUserType を使用して、その AddressEntry オブジェクトが Exchange ユーザーを表しているかどうかを確認します。 Exchange ユーザーが見つかったら、 GetExchangeUser を使用して、そのユーザーに関するさまざまなデータを取得して出力します。

Sub DemoAE() 
 
 Dim colAL As Outlook.AddressLists 
 Dim oAL As Outlook.AddressList 
 Dim colAE As Outlook.AddressEntries 
 Dim oAE As Outlook.AddressEntry 
 Dim oExUser As Outlook.ExchangeUser 
 Set colAL = Application.Session.AddressLists 
 
 For Each oAL In colAL 
    'Address list is an Exchange Global Address List 
    If oAL.AddressListType = olExchangeGlobalAddressList Then 
        Set colAE = oAL.AddressEntries 
        
        For Each oAE In colAE 
            If oAE.AddressEntryUserType = olExchangeUserAddressEntry _ 
               Or oAE.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then 
               
                Set oExUser = oAE.GetExchangeUser 
                Debug.Print (oExUser.JobTitle) 
                Debug.Print (oExUser.OfficeLocation) 
                Debug.Print (oExUser.BusinessTelephoneNumber) 
            End If 
        Next 
    End If 
 Next 
 
End Sub

関連項目

AddressEntry オブジェクト

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。