次の方法で共有

LetterContent オブジェクト (Word)

  • [アーティクル]

レター ウィザードで作成されたレターの構成要素を表します。

注釈

GetLetterContent メソッドまたは CreateLetterContent メソッドを使用して、 LetterContent オブジェクトを取得します。 次の使用例は、作業中の文書からレターの受信者の名前を取得し、表示します。

Set myLetterContent = ActiveDocument.GetLetterContent 
MsgBox myLetterContent.RecipientName

次の使用例は、 CreateLetterContent メソッドを使用して、新しい LetterContent オブジェクトを作成します。作成されたオブジェクトは、 RunLetterWizard で使用されます。

Set myLetter = ActiveDocument _ 
 .CreateLetterContent(DateFormat:="July 11, 1996", _ 
 IncludeHeaderFooter:=False, _ 
 PageDesign:="C:\MSOffice\Templates\Letters & " _ 
 & "Faxes\Contemporary Letter.dot", _ 
 LetterStyle:=wdFullBlock, Letterhead:=True, _ 
 LetterheadLocation:=wdLetterTop, _ 
 LetterheadSize:=InchesToPoints(1.5), _ 
 RecipientName:="Dave Edson", _ 
 RecipientAddress:="100 Main St." & vbCr _ 
 & "Bellevue, WA 98004", _ 
 Salutation:="Dear Dave,", _ 
 SalutationType:=wdSalutationInformal, _ 
 RecipientReference:="", MailingInstructions:="", _ 
 AttentionLine:="", _ 
 Subject:="End of year report", CCList:="", ReturnAddress:="", _ 
 SenderName:="", Closing:="Sincerely yours,", _ 
 SenderCompany:="", _ 
 SenderJobTitle:="", SenderInitials:="", EnclosureNumber:=0) 
ActiveDocument.RunLetterWizard _ 
 LetterContent:=myLetter, WizardMode:=True

CreateLetterContent メソッドは LetterContent オブジェクトを作成しますが、多数の引数が必要になります。 設定するプロパティの数が少ない場合は、 New キーワードを使って新しい LetterContent オブジェクトを作成します。 次の使用例は、 LetterContent オブジェクトを作成し、一部のプロパティを設定し、次に、 RunLetterWizard メソッドで LetterContent オブジェクトを使用し、あらかじめ設定した値を既定値としてレター ウィザードを実行します。

Set myLetter = New LetterContent 
With myLetter 
 .AttentionLine = "Read this" 
 .EnclosureNumber = 1 
 .Letterhead = True 
 .LetterheadLocation = wdLetterTop 
 .LetterheadSize = InchesToPoints(2) 
End With 
Documents.Add.RunLetterWizard LetterContent:=myLetter, _ 
 WizardMode:=True

Duplicate プロパティを使って LetterContent オブジェクトを複製することができます。 次の使用例は、作業中の文書からレターの構成要素を取り出し、複製コピーを作成します。 この例では、複製コピーを aLetter に格納し、受信者の名前や住所を空の文字列に戻します。 RunLetterWizard メソッドは、変更された LetterContent オブジェクト (aLetter) の値を既定の設定として使用して、レター ウィザードを実行するために使用されます。

Set aLetter = ActiveDocument.GetLetterContent.Duplicate 
With aLetter 
 .RecipientName = "" 
 .RecipientAddress = "" 
End With 
Documents.Add.RunLetterWizard LetterContent:=aLetter, _ 
 WizardMode:=True

SetLetterContent メソッドは、指定した LetterContent オブジェクトの内容を挿入します。 次の使用例は、作業中の文書からレターの構成要素を取り出し、要件を変更し、次に、 SetLetterContent メソッドを使用して作業中の文書を更新し、変更を反映します。

Set myLetterContent = ActiveDocument.GetLetterContent 
myLetterContent.AttentionLine = "Greetings" 
ActiveDocument.SetLetterContent LetterContent:=myLetterContent

関連項目

Word オブジェクト モデル リファレンス

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。