標準の日時書式指定文字列

標準の日付と時刻の書式指定文字列では、書式指定子として 1 文字を使用して、時刻と日付の値のテキスト表現を定義します。 空白を含む複数の文字で構成される日時書式指定文字列は、カスタム日時書式指定文字列として解釈されます。 標準書式指定文字列またはカスタム書式指定文字列を使用して、書式設定操作の結果のテキスト表現を定義できます。

書式指定子の表

標準日時書式指定子を次の表に示します。

標準書式指定文字列の動作

書式設定操作では、標準書式指定文字列はカスタム書式指定文字列のエイリアスにすぎません。 エイリアスを使ってカスタム書式指定文字列を表すことの利点は、カスタム書式指定文字列はそれ自体が変化する場合があるのに対し、エイリアスは不変であるという点です。 通常、日付と時刻の値の文字列形式はカルチャによって変わるため、この点は重要です。 たとえば、"d" 標準書式指定文字列は、日付と時刻の値を短い日付形式のパターンで表示することを意味します。 インバリアント カルチャでは、このパターンは "MM/dd/yyyy" になります。 fr-FR カルチャでは、これが "dd/MM/yyyy" になります。 ja-JP カルチャでは、これが "yyyy/MM/dd" になります。

書式設定操作の標準書式指定文字列が特定のカルチャのカスタム書式指定文字列に対応付けられている場合は、使用するカスタム書式指定文字列に該当するカルチャを次のいずれかの方法で定義できます。

• 既定の (現在の) カルチャを使用できます。 次の例では、現在のカルチャの短い日付形式を使って日付を表示します。 この場合、現在のカルチャは en-US です。

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d"])
          //Displays 3/15/2024
      }
  in
      Source
  

• 特定のカルチャの規則に従って日付の書式設定に使用されるカルチャを渡すことができます。 次の例では、pt-BR カルチャの短い日付形式を使って日付を表示します。

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d", Culture = "pt-BR"])
          //Displays 15/03/2024
     }
  in
      Source
  

標準書式指定文字列には、長いカスタム書式指定文字列に代わる、不変の省略形としての利用価値もあります。 このカテゴリに該当する標準書式指定文字列は、"O" (または "o")、"R" (または "r")、"s"、"u" の 4 つです。 これらの文字列は、インバリアント カルチャで定義されたカスタム書式指定文字列に対応します。 これらの書式指定文字列によって生成される日時値の文字列形式は、カルチャに関係なく一定です。 次の表で、この 4 つの標準日時書式指定文字列について説明します。

標準書式指定文字列は解析操作でも使用できます。解析操作を成功させるためには、入力文字列が特定のパターンに正確に準拠している必要があります。 多くの標準書式指定文字列は複数のカスタム書式指定文字列にマップされるため、日付と時刻の値をさまざまな形式で表すことができますが、解析操作は引き続き成功します。

次のセクションでは、 Date、 DateTime、 DateTimeZone、および Time 値の標準書式指定子について説明します。

日付の形式

このグループには、次の形式が含まれます。

• 短い形式の日付 ("d") 書式指定子
• 長い形式の日付 ("D") 書式指定子

短い形式の日付 ("d") 書式指定子

"d" 標準書式指定子は、特定のカルチャによって定義されたカスタム日付形式を表します。 たとえば、インバリアント カルチャによって返されるカスタム書式指定テキストは "MM/dd/yyyy" です。

次の例では、"d" 書式指定子を使用して日付値を表示します。

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = ""]),
        // Displays 04/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-US"]),
        // Displays 4/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-NZ"]),
        // Displays 10/4/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "de-DE"])
        // Displays 10.4.2024
    }
in
    Source

表のトップへ

長い形式の日付 ("D") 書式指定子

"D" 標準書式指定子は、特定のカルチャによって定義されたカスタム日付形式を表します。 たとえば、インバリアント カルチャのカスタム書式指定文字列は "dddd, dd MMMM yyyy" です。

次の例では、"D" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = ""]),
        // Displays Wednesday, 10 April, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "pt-BR"]),
        // Displays quarta-feira, 10 de abril de 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "es-MX"])
        // Displays miércoles, 10 de abril de 2024
    }
in
    Source

表のトップへ

日付と時刻の形式

このグループには、次の形式が含まれます。

• 完全な日付と短い形式の時刻 ("f") 書式指定子
• 完全な日付と長い形式の時刻 ("F") 書式指定子
• 一般の日付と短い形式の時刻 ("g") 書式指定子
• 一般の日付と長い形式の時刻 ("G") 書式指定子
• ラウンドトリップ ("O"、"o") 書式指定子
• RFC1123 ("R"、"r") 書式指定子
• 並べ替え可能な日付と時刻 ("s") 書式指定子
• 世界共通の並べ替え可能な日付と時刻 ("u") 書式指定子

完全な日付と短い形式の時刻 ("f") 書式指定子

"f" 標準書式指定子は、長い形式の日付 ("D") パターンと短い形式の時刻 ("t") パターンを空白で区切って組み合わせて表します。

結果文字列は、特定のカルチャの書式設定情報の影響を受けます。

次の例では、"f" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30
    }
in
    Source

表のトップへ

完全な日付と長い形式の時刻 ("F") 書式指定子

"F" 標準書式指定子は、特定のカルチャによって定義されたカスタムの日付と時刻の書式を表します。 たとえば、インバリアント カルチャのカスタム書式指定文字列は "dddd, dd MMMM yyyy HH:mm:ss" です。

結果文字列は、特定のカルチャの書式設定情報の影響を受けます。

次の例では、"F" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = ""]),
        // Displays Wednesday, 10 April, 2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30:00
    }
in
    Source

表のトップへ

一般の日付と短い形式の時刻 ("g") 書式指定子

"g" 標準書式指定子は、短い形式の日付 ("d") パターンと短い形式の時刻 ("t") パターンを空白で区切って組み合わせて表します。 結果のテキストは、特定のカルチャの書式設定情報の影響を受けます。

結果文字列は、特定のカルチャの書式設定情報の影響を受けます。

次の例では、"g" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = ""]),
        // Displays 04/10/2024 06:30

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "en-US"]),
        // Displays 4/10/2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "fr-BE"])
        // Displays 10-04-24 06:30
    }
in
    Source

表のトップへ

一般の日付と長い形式の時刻 ("G") 書式指定子

"G" 標準書式指定子は、短い形式の日付 ("d") パターンと長い形式の時刻 ("T") パターンを空白で区切って組み合わせて表します。 結果のテキストは、特定のカルチャの書式設定情報の影響を受けます。

結果文字列は、特定のカルチャの書式設定情報の影響を受けます。

次の例では、"G" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = ""]),
        // Displays 04/10/2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "en-US"]),
        // Displays 4/10/2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "nl-BE"])
        // Displays 10/04/2024 6:30:00
    }
in
    Source

表のトップへ

ラウンドトリップ ("O"、"o") 書式指定子

"O" または "o" 標準書式指定子は、タイム ゾーン情報を保持するパターンを使用するカスタム日時書式指定文字列を表し、ISO 8601 に準拠する結果文字列を生成します。 DateTimeZone値の場合、この書式指定子は、日付、時刻、およびタイムゾーンの値をテキストで保持するように設計されています。

"O" または "o" 標準書式指定子は、"yyyy'-'MM'-'dd'T'HH':'mm':'ss' に対応します。fffffffxxx" DateTimeZone 値のカスタム書式指定文字列。 このテキストでは、ハイフン、コロン、文字 "T" など、個々の文字を区切る単一引用符のペアは、個々の文字が変更できないリテラルであることを示します。 アポストロフィは出力文字列に表示されません。

"O" または "o" 標準書式指定子 (および "yyyy'-'MM'-'dd'T'HH':'mm':'ss'.'fffffffxxx" カスタム形式) は、ISO 8601 がタイム ゾーン情報を表す方法を利用して、DateTimeZone 値を保持します。

• DateTimeZone.ToLocal 日時値のタイム ゾーン コンポーネントは、UTC からのオフセットです (たとえば、+01:00、-07:00)。

• DateTimeZone.ToUtc 日時値のタイム ゾーン コンポーネントは、UTC を表すために +00.00 を使用します。

"O" または "o" 標準書式指定子は国際基準に準拠しているため、この指定子を使用する書式設定操作または解析操作では常に、インバリアント カルチャとグレゴリオ暦が使用されます。

次の例では、"o" 書式指定子を使用して、米国太平洋タイム ゾーン内のシステムに一連の DateTimeZone 値を表示します。

let
    date1 = #datetimezone(2024, 6, 15, 13, 45, 30, 0, 0),
    Source =
    {
        Text.Format("#{0} (Unspecified) --> #{1}", {date1, DateTimeZone.ToText(date1, [Format = "O"])}),
        Text.Format("#{0} (Utc) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToUtc(date1), [Format = "O"])}),
        Text.Format("#{0} (Local) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToLocal(date1), [Format = "O"])})
    }
in
    Source

// The example displays the following output:
//    6/15/2024 1:45:30 PM +00:00 (Unspecified) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Utc) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Local) --> 2024-06-15T08:45:30.0000000-07:00

次の例では、"o" 書式指定子を使用して書式設定された文字列を作成し、日付と時刻の解析ルーチンを呼び出して元の日付と時刻の値を復元します。

let
    // Round-trip a local time
    #"Origin Local Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0)
    ),
    #"Local Date Text" = DateTimeZone.ToText(
        #"Origin Local Date", [Format = "o"]
    ),
    #"New Local Date" = DateTimeZone.FromText(#"Local Date Text"),
    #"Local Round Trip" = Text.Format(
        "Round-tripped #{0} Local to #{1} Local.", 
        {
            DateTimeZone.ToText(#"Origin Local Date"), 
            DateTimeZone.ToText(#"New Local Date")
        }
    ),

    // Round-trip a UTC time
    #"Origin UTC Date" = DateTimeZone.ToUtc(
        #datetimezone(2024, 4, 12, 9, 30, 0, 0, 0)
    ),
    #"UTC Date Text" = DateTimeZone.ToText(
        #"Origin UTC Date", [Format = "o"]
    ),
    #"New UTC Date" = DateTimeZone.FromText(#"UTC Date Text"),
    #"UTC Round Trip" = Text.Format(
        "Round-tripped #{0} UTC to #{1} UTC.", 
        {
            DateTimeZone.ToText(#"Origin UTC Date"), 
            DateTimeZone.ToText(#"New UTC Date")
        }
    ),

    // Round-trip an 18 hour offset time
    #"Origin Offset Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0) + #duration(0, 18, 0, 0)
    ),
    #"Offset Date Text" = DateTimeZone.ToText(
        #"Origin Offset Date", [Format = "o"]
    ),
    #"New Offset Date" = DateTimeZone.FromText(#"Offset Date Text"),
    #"Offset Round Trip" = Text.Format(
        "Round-tripped #{0} to #{1}.", 
        {
            DateTimeZone.ToText(#"Origin Offset Date"), 
            DateTimeZone.ToText(#"New Offset Date")
        }
    ),

    #"Round Trip Results" = 
        {#"Local Round Trip", #"UTC Round Trip", #"Offset Round Trip"}
in
    #"Round Trip Results"

// The example displays the following output in Power Query Desktop:
//    Round-tripped 4/9/2024 11:30:00 PM -07:00 Local to 4/9/2024 11:30:00 PM -07:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/10/2024 5:30:00 PM -07:00 to 4/10/2024 5:30:00 PM -07:00.

// The example displays the following output in Power Query Online:
//    Round-tripped 4/10/2024 6:30:00 AM +00:00 Local to 4/10/2024 6:30:00 AM +00:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/11/2024 12:30:00 AM +00:00 to 4/11/2024 12:30:00 AM +00:00.

表のトップへ

RFC1123 ("R"、"r") 書式指定子

"R" または "r" 標準書式指定子は、特定のカルチャで定義されていないカスタム日時書式指定文字列を表します。 使用されるカルチャや指定された形式プロバイダーに関係なく、常に同じです。 カスタム書式指定文字列は、"ddd, dd MMM yyyy HH':'mm':'ss 'GMT'" です。 この標準書式指定子を使用した場合、書式設定操作または解析操作で常にインバリアント カルチャが使用されます。

RFC 1123 標準では時刻が協定世界時 (UTC) として表されますが、書式設定操作では、書式設定されている日付と時刻の値は変更されません。 したがって、書式設定操作を実行する前に、DateTimeZone.ToUtc 関数メソッドを呼び出して DateTime 値を UTC に変換する必要があります。

次の例では、"r" 書式指定子を使用して、米国太平洋タイム ゾーン (UTC から 7 時間遅れて) のシステムに時刻と日付の値を表示します。

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source = 
    {
        DateTimeZone.ToText(date1, [Format = "r"]),
        // Displays Wed, 10 Apr 2024 13:30:00 GMT

        DateTimeZone.ToText(dateOffset, [Format = "r"])
        // Displays Wed, 10 Apr 2024 13:30:00 GMT
    }
in
    Source

表のトップへ

並べ替え可能な日付と時刻 ("s") 書式指定子

"s" 標準書式指定子は、定義された標準 (ISO 8601) を反映するカスタム日時書式指定文字列を表し、読み取り専用です。 したがって、使用されるカルチャまたは指定された書式プロバイダーに関係なく、常に同じです。 カスタム書式指定文字列は、"yyyy'-'MM'-'dd'T'HH':'mm':'ss" です。 "s" 書式指定子の目的は、日付と時刻の値に基づいて、一貫して昇順または降順で並べ替える結果の文字列を作成することです。

この標準書式指定子を使用した場合、書式設定操作または解析操作で常にインバリアント カルチャが使用されます。

次の例では、"s" 書式指定子を使用して、米国太平洋タイム ゾーンのシステムに日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "s", Culture = "en-US"])
        // Displays 2024-04-10T06:30:00
    }
in
    Source

表のトップへ

世界共通の並べ替え可能な日付と時刻 ("u") 書式指定子

"u" 標準書式指定子は、使用されるカルチャまたは指定された書式プロバイダーに関係なく、常に同じカスタム日時書式指定文字列を表します。 カスタム書式指定文字列は、"yyyy'-'MM'-'dd HH':'mm':'ss'Z'" です。 このパターンは定義済みの標準を反映し、プロパティは読み取り専用です。 この標準書式指定子を使用した場合、書式設定操作または解析操作で常にインバリアント カルチャが使用されます。

結果文字列は協定世界時 (UTC) として時刻を表す必要がありますが、書式設定操作中に元の DateTimeZone 値の変換は実行されません。 そのため、書式設定する前に DateTimeZone.ToUtc 関数を呼び出して、DateTimeZone 値を UTC に変換する必要があります。

次の例では、"u" 書式指定子を使用して、日付と時刻の値を表示します。

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source =
    {
        DateTimeZone.ToText(dateOffset, [Format = "u"]),
        // Displays 2024-04-10 13:30:00Z
    }
in
    Source

表のトップへ

時刻の形式

このグループには、次の形式が含まれます。

• 短い形式の時刻 ("t") 書式指定子
• 長い形式の時刻 ("T") 書式指定子

短い形式の時刻 ("t") 書式指定子

"t" 標準書式指定子は、指定したカルチャによって定義されるカスタム日時書式指定文字列を表します。 たとえば、インバリアント カルチャのカスタム書式指定文字列は "HH:mm" です。

結果文字列は、特定のカルチャの書式設定情報の影響を受けます。

次の例では、"t" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = ""]),
        // Displays 06:30
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "en-US"]),
        // Displays 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "es-ES"])
        // Displays 6:30
    }
in
    Source

表のトップへ

長い形式の時刻 ("T") 書式指定子

"T" 標準書式指定子は、特定のカルチャによって定義されるカスタム日時書式指定文字列を表します。 たとえば、インバリアント カルチャのカスタム書式指定文字列は "HH:mm:ss" です。

次の例では、"T" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = ""]),
        // Displays 06:30:00
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "en-US"]),
        // Displays 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "es-ES"])
        // Displays 6:30:00
    }
in
    Source

表のトップへ

部分的な日付形式

このグループには、次の形式が含まれます。

• 月 ("M"、"m") 書式指定子
• 年月 ("Y"、"y") 書式指定子

月 ("M"、"m") 書式指定子

"M" または "m" 標準書式指定子は、特定のカルチャによって定義されるカスタム日時書式指定文字列を表します。 たとえば、インバリアント カルチャのカスタム書式指定文字列は "MMMM dd" です。

次の例では、"m" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = ""]),
        // Displays April 10
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "en-US"]),
        // Displays April 10

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "ms-MY"])
        // Displays 10 April
    }
in
    Source

表のトップへ

年月 ("Y"、"y") 書式指定子

"Y" または "y" 標準書式指定子は、特定のカルチャによって定義されるカスタム日付書式指定文字列を表します。 たとえば、インバリアント カルチャのカスタム書式指定文字列は "yyyy MMMM" です。

次の例では、"y" 書式指定子を使用して、日付と時刻の値を表示します。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = ""]),
        // Displays 2024 April
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = "en-US"]),
        // Displays April 2024

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "y", Culture = "af-ZA"])
        // Displays April 2024
    }
in
    Source

表のトップへ

関連するコンテンツ

• カルチャがテキストの書式設定にどのように影響するか
• Date、Time、DateTime、および DateTimeZone 型の変換
• Date 関数
• DateTime 関数
• DateTimeZone 関数
• Time 関数
• カスタム日時形式文字列