Application Insights의 메트릭

다음 섹션에서는 지원되는 집계 및 차원이 있는 메트릭을 나열합니다. 로그 기반 메트릭에 대한 세부 정보에는 기본 Kusto 쿼리 문이 포함됩니다.

다음 섹션에서는 지원되는 집계 및 차원이 있는 메트릭을 나열합니다. 로그 기반 메트릭에 대한 세부 정보에는 기본 Kusto 쿼리 문이 포함됩니다. 편의를 위해 각 쿼리는 시간 세분성, 차트 종류 및 때로는 분할 차원에 기본값을 사용하므로 수정할 필요 없이 Log Analytics에서 쿼리를 사용하면 간소화됩니다.

메트릭 탐색기에서 동일한 메트릭을 그리는 경우 기본값이 없습니다. 쿼리는 차트 설정에 따라 동적으로 조정됩니다.

• 선택한 시간 범위는 선택한 시간 범위 에서만 이벤트를 선택하기 위해 추가 where timestamp... 절로 변환됩니다. 예를 들어 가장 최근 24시간 동안의 데이터를 보여 주는 차트에는 쿼리가 포함됩니다 | where timestamp > ago(24 h).

• 선택한 시간 세분성이 최종 summarize ... by bin(timestamp, [time grain]) 절에 삽입됩니다.

• 선택한 필터 차원은 추가 where 절로 변환됩니다.

• 선택한 분할 차트 차원이 추가 요약 속성으로 변환됩니다. 예를 들어 차트를 5분 단위 summarize 로 location분할하고 5분 단위로 그리는 경우 절이 요약됩니다... by bin(timestamp, 5 m), location.

가용성(availabilityResults/availabilityPercentage)

가용성 메트릭은 문제를 감지하지 못한 웹 테스트 실행의 백분율을 보여 줍니다. 가능한 가장 낮은 값은 0으로, 모든 웹 테스트 실행이 실패했음을 나타냅니다. 값이 100이면 모든 웹 테스트 실행이 유효성 검사 조건을 통과했음을 의미합니다.

가용성 테스트 기간(availabilityResults/duration)

‘가용성 테스트 기간’ 메트릭은 웹 테스트를 실행하는 데 걸린 시간을 보여 줍니다. 다단계 웹 테스트의 경우 메트릭은 모든 단계의 총 실행 시간을 반영합니다.

가용성 테스트(availabilityResults/count)

가용성 테스트 메트릭은 Azure Monitor에서 실행하는 웹 테스트의 수를 반영합니다.

가용성(availabilityResults/availabilityPercentage)

가용성 메트릭은 문제를 감지하지 못한 웹 테스트 실행의 백분율을 보여 줍니다. 가능한 가장 낮은 값은 0으로, 모든 웹 테스트 실행이 실패했음을 나타냅니다. 값이 100이면 모든 웹 테스트 실행이 유효성 검사 조건을 통과했음을 의미합니다.

availabilityResults
| summarize ['availabilityResults/availabilityPercentage_avg'] = sum(todouble(success == 1) * 100) / count() by bin(timestamp, 15m)
| render timechart

가용성 테스트 결과 수(availabilityResults/count)

가용성 테스트 메트릭은 Azure Monitor에서 실행하는 웹 테스트의 수를 반영합니다.

availabilityResults
| summarize ['availabilityResults/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

테스트 기간(availabilityResults/duration)

‘가용성 테스트 기간’ 메트릭은 웹 테스트를 실행하는 데 걸린 시간을 보여 줍니다. 다단계 웹 테스트의 경우 메트릭은 모든 단계의 총 실행 시간을 반영합니다.

availabilityResults
| where notempty(duration)
| extend availabilityResult_duration = iif(itemType == 'availabilityResult', duration, todouble(''))
| summarize ['availabilityResults/duration_avg'] = sum(availabilityResult_duration) / sum(itemCount) by bin(timestamp, 5m)
| render timechart

브라우저 페이지 로드 시간(browserTimings/totalDuration)

클라이언트 처리 시간(browserTiming/processingDuration)

페이지 로드 네트워크 연결 시간(browserTimings/networkDuration)

응답 시간 수신(browserTimings/receiveDuration)

요청 시간 보내기(browserTimings/sendDuration)

브라우저 페이지 로드 시간(browserTimings/totalDuration)

사용자 요청부터 DOM까지의 시간, 스타일시트, 스크립트 및 이미지가 로드됩니다.

browserTimings
| where notempty(totalDuration)
| extend _sum = totalDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/totalDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

클라이언트 처리 시간(browserTiming/processingDuration)

DOM이 로드될 때까지 문서의 마지막 바이트를 받는 시간입니다. 비동기 요청은 여전히 처리 중일 수 있습니다.

browserTimings
| where notempty(processingDuration)
| extend _sum = processingDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/processingDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

페이지 로드 네트워크 연결 시간(browserTimings/networkDuration)

사용자 요청과 네트워크 연결 사이의 시간입니다. DNS 조회 및 전송 연결을 포함합니다.

browserTimings
| where notempty(networkDuration)
| extend _sum = networkDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/networkDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

응답 시간 수신(browserTimings/receiveDuration)

첫 번째 바이트와 마지막 바이트 사이의 시간 또는 연결이 끊어질 때까지의 시간입니다.

browserTimings
| where notempty(receiveDuration)
| extend _sum = receiveDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/receiveDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

요청 시간 보내기(browserTimings/sendDuration)

네트워크 연결과 첫 번째 바이트 수신 사이의 시간입니다.

browserTimings
| where notempty(sendDuration)
| extend _sum = sendDuration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['browserTimings/sendDuration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

브라우저 예외(예외/브라우저)

이 메트릭은 브라우저에서 실행되는 애플리케이션 코드에서 throw된 예외 수를 반영합니다. trackException() Application Insights API 호출로 추적되는 예외만이 메트릭에 포함됩니다.

종속성 호출 실패(dependencies/failed)

실패한 종속성 호출 수입니다.

예외(예외/개수)

Application Insights에 예외를 기록할 때마다 SDK의 trackException() 메서드에 대한 호출이 있습니다. 예외 메트릭에는 로깅된 예외의 수가 표시됩니다.

실패한 요청(요청/실패)

실패한 것으로 표시된 추적된 서버 요청의 수입니다. 기본적으로 Application Insights SDK는 HTTP 응답 코드 5xx 또는 4xx를 반환한 각 서버 요청을 실패한 요청으로 자동으로 표시합니다. 사용자 지정 원격 분석 이니셜라이저에서 요청 원격 분석 항목의 성공 속성을 수정하여 이 논리를 사용자 지정할 수 있습니다.

서버 예외(exceptions/server)

이 메트릭은 서버 예외 수를 보여 줍니다.

브라우저 예외(예외/브라우저)

이 메트릭은 브라우저에서 실행되는 애플리케이션 코드에서 throw된 예외 수를 반영합니다. trackException() Application Insights API 호출로 추적되는 예외만이 메트릭에 포함됩니다.

exceptions
| where client_Type == 'Browser'
| summarize ['exceptions/browser_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

종속성 호출 실패(dependencies/failed)

실패한 종속성 호출 수입니다.

dependencies
| where success == 'False'
| summarize ['dependencies/failed_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

예외(예외/개수)

Application Insights에 예외를 기록할 때마다 SDK의 trackException() 메서드에 대한 호출이 있습니다. 예외 메트릭에는 로깅된 예외의 수가 표시됩니다.

exceptions
| summarize ['exceptions/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

실패한 요청(요청/실패)

실패한 것으로 표시된 추적된 서버 요청의 수입니다. 기본적으로 Application Insights SDK는 HTTP 응답 코드 5xx 또는 4xx를 반환한 각 서버 요청을 실패한 요청으로 자동으로 표시합니다. 사용자 지정 원격 분석 이니셜라이저에서 요청 원격 분석 항목의 성공 속성을 수정하여 이 논리를 사용자 지정할 수 있습니다.

requests
| where success == 'False'
| summarize ['requests/failed_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

서버 예외(exceptions/server)

이 메트릭은 서버 예외 수를 보여 줍니다.

exceptions
| where client_Type != 'Browser'
| summarize ['exceptions/server_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

사용 가능한 메모리(performanceCounters/availableMemory)

예외율(performanceCounters/exceptionRate)

HTTP 요청 실행 시간(performanceCounters/requestExecutionTime)

HTTP 요청 속도(performanceCounters/requestsPerSecond)

애플리케이션 큐의 HTTP 요청(performanceCounters/requestsInQueue)

CPU 프로세스(performanceCounters/processCpuPercentage)

메트릭은 모니터링되는 앱을 호스팅하는 프로세스에서 사용되는 총 프로세서 용량의 양을 보여 줍니다.

프로세스 IO 속도(performanceCounters/processIOBytesPerSecond)

프로세스 프라이빗 바이트(performanceCounters/processPrivateBytes)

모니터링된 프로세스가 해당 데이터에 할당한 공유되지 않은 메모리의 양입니다.

프로세서 시간(performanceCounters/processorCpuPercentage)

모니터링되는 서버 인스턴스에서 실행 중인 ‘모든’ 프로세스의 CPU 소비량입니다.

ASP.NET 요청 실행 시간(performanceCounters/requestExecutionTime)

performanceCounters
| where ((category == "ASP.NET Applications" and counter == "Request Execution Time") or name == "requestExecutionTime")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/requestExecutionTime_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render barchart

ASP.NET 요청 속도(performanceCounters/requestsPerSecond)

performanceCounters
| where ((category == "ASP.NET Applications" and counter == "Requests/Sec") or name == "requestsPerSecond")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/requestsPerSecond_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render barchart

애플리케이션 큐의 ASP.NET 요청(performanceCounters/requestsInQueue)

performanceCounters
| where ((category == "ASP.NET Applications" and counter == "Requests In Application Queue") or name == "requestsInQueue")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/requestsInQueue_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render barchart

사용 가능한 메모리(performanceCounters/availableMemory)

performanceCounters
| where ((category == "Memory" and counter == "Available Bytes") or name == "memoryAvailableBytes")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/memoryAvailableBytes_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

예외율(performanceCounters/exceptionRate)

performanceCounters
| where ((category == ".NET CLR Exceptions" and counter == "# of Exceps Thrown / sec") or name == "exceptionsPerSecond")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/exceptionsPerSecond_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

GC 총 개수(performanceCounters/GC 총 개수)

performanceCounters
| where name == "GC Total Count"
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/GC Total Count_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

GC 총 시간(performanceCounters/GC 총 시간)

performanceCounters
| where name == "GC Total Time"
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/GC Total Time_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

사용된 힙 메모리(MB)(performanceCounters/힙 메모리 사용(MB))

performanceCounters
| where name == "Heap Memory Used (MB)"
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/Heap Memory Used (MB)_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

HTTP 요청 실행 시간(performanceCounters/requestExecutionTime)

performanceCounters
| where ((category == "ASP.NET Applications" and counter == "Request Execution Time") or name == "requestExecutionTime")
| extend performanceCounter_value = iif(itemType == "performanceCounter", value, todouble(''))
| summarize sum(performanceCounter_value) / count() by bin(timestamp, 1m)
| render timechart

HTTP 요청 속도(performanceCounters/requestsPerSecond)

performanceCounters
| where ((category == "ASP.NET Applications" and counter == "Requests/Sec") or name == "requestsPerSecond")
| extend performanceCounter_value = iif(itemType == "performanceCounter", value, todouble(''))
| summarize sum(performanceCounter_value) / count() by bin(timestamp, 1m)
| render timechart

애플리케이션 큐의 HTTP 요청(performanceCounters/requestsInQueue)

performanceCounters
| where ((category == "ASP.NET Applications" and counter == "Requests In Application Queue") or name == "requestsInQueue")
| extend performanceCounter_value = iif(itemType == "performanceCounter", value, todouble(''))
| summarize sum(performanceCounter_value) / count() by bin(timestamp, 1m)
| render timechart

CPU 프로세스(performanceCounters/processCpuPercentage)

메트릭은 모니터링되는 앱을 호스팅하는 프로세스에서 사용되는 총 프로세서 용량의 양을 보여 줍니다.

performanceCounters
| where ((category == "Process" and counter == "% Processor Time Normalized") or name == "processCpuPercentage")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/processCpuPercentage_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

프로세스 CPU(모든 코어)(performanceCounters/processCpuPercentageTotal)

performanceCounters
| where ((category == "Process" and counter == "% Processor Time") or name == "processCpuPercentageTotal")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/processCpuPercentageTotal_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

프로세스 IO 속도(performanceCounters/processIOBytesPerSecond)

performanceCounters
| where ((category == "Process" and counter == "IO Data Bytes/sec") or name == "processIOBytesPerSecond")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/processIOBytesPerSecond_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

프로세스 프라이빗 바이트(performanceCounters/processPrivateBytes)

모니터링된 프로세스가 해당 데이터에 할당한 공유되지 않은 메모리의 양입니다.

performanceCounters
| where ((category == "Process" and counter == "Private Bytes") or name == "processPrivateBytes")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/processPrivateBytes_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

프로세서 시간(performanceCounters/processorCpuPercentage)

모니터링되는 서버 인스턴스에서 실행 중인 ‘모든’ 프로세스의 CPU 소비량입니다.

performanceCounters
| where ((category == "Processor" and counter == "% Processor Time") or name == "processorCpuPercentage")
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/processorCpuPercentage_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

의심되는 교착 상태 스레드(performanceCounters/의심되는 교착 상태 스레드)

performanceCounters
| where name == "Suspected Deadlocked Threads"
| extend performanceCounter_value = iif(itemType == 'performanceCounter', value, todouble(''))
| summarize ['performanceCounters/Suspected Deadlocked Threads_avg'] = sum(performanceCounter_value) / count() by bin(timestamp, 15m)
| render timechart

종속성 호출(종속성/개수)

이 메트릭은 종속성 호출 수와 관련이 있습니다.

종속성 기간(dependencies/duration)

이 메트릭은 종속성 호출의 기간을 나타냅니다.

서버 요청 비율(요청/비율)

이 메트릭은 웹 애플리케이션에서 수신한 들어오는 서버 요청 수를 반영합니다.

서버 요청(요청/수)

서버 응답 시간(요청/기간)

이 메트릭은 서버가 들어오는 요청을 처리하는 데 걸린 시간을 반영합니다.

종속성 호출(종속성/개수)

이 메트릭은 종속성 호출 수와 관련이 있습니다.

dependencies
| summarize ['dependencies/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

종속성 기간(dependencies/duration)

이 메트릭은 종속성 호출의 기간을 나타냅니다.

dependencies
| where notempty(duration)
| extend dependency_duration = iif(itemType == 'dependency', duration, todouble(''))
| extend _sum = dependency_duration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['dependencies/duration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

서버 요청(요청/수)

이 메트릭은 웹 애플리케이션에서 수신한 들어오는 서버 요청 수를 반영합니다.

requests
| summarize ['requests/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

서버 응답 시간(요청/기간)

이 메트릭은 서버가 들어오는 요청을 처리하는 데 걸린 시간을 반영합니다.

requests
| where notempty(duration)
| extend request_duration = iif(itemType == 'request', duration, todouble(''))
| extend _sum = request_duration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['requests/duration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render timechart

페이지 보기 로드 시간(pageViews/duration)

이 메트릭은 PageView 이벤트가 로드되는 데 걸린 시간을 나타냅니다.

페이지 보기(pageViews/count)

TrackPageView() Application Insights API로 기록된 페이지 보기 이벤트의 수입니다.

추적(추적/개수)

TrackTrace() Application Insights API 호출로 기록된 추적 문의 수입니다.

이벤트(customEvents/count)

customEvents
| summarize ['customEvents/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

페이지 보기 로드 시간(pageViews/duration)

이 메트릭은 PageView 이벤트가 로드되는 데 걸린 시간을 나타냅니다.

pageViews
| where notempty(duration)
| extend pageView_duration = iif(itemType == 'pageView', duration, todouble(''))
| extend _sum = pageView_duration
| extend _count = itemCount
| extend _sum = _sum * _count
| summarize ['pageViews/duration_avg'] = sum(_sum) / sum(_count) by bin(timestamp, 15m)
| render barchart

페이지 보기(pageViews/count)

TrackPageView() Application Insights API로 기록된 페이지 보기 이벤트의 수입니다.

pageViews
| summarize ['pageViews/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

세션(sessions/count)

이 메트릭은 고유한 세션 ID의 수를 나타냅니다.

union traces, requests, pageViews, dependencies, customEvents, availabilityResults, exceptions, customMetrics, browserTimings
| where notempty(session_Id)
| summarize ['sessions/count_unique'] = dcount(session_Id) by bin(timestamp, 15m)
| render barchart

추적(추적/개수)

TrackTrace() Application Insights API 호출로 기록된 추적 문의 수입니다.

traces
| summarize ['traces/count_sum'] = sum(itemCount) by bin(timestamp, 15m)
| render barchart

사용자(사용자/수)

애플리케이션에 액세스한 고유 사용자의 수입니다. 이 메트릭의 정확도는 원격 분석 샘플링 및 필터링 사용에 상당한 영향을 받을 수 있습니다.

union traces, requests, pageViews, dependencies, customEvents, availabilityResults, exceptions, customMetrics, browserTimings
| where notempty(user_Id)
| summarize ['users/count_unique'] = dcount(user_Id) by bin(timestamp, 15m)
| render barchart

사용자, 인증됨(사용자/인증됨)

애플리케이션에 인증된 고유 사용자의 수입니다.

union traces, requests, pageViews, dependencies, customEvents, availabilityResults, exceptions, customMetrics, browserTimings
| where notempty(user_AuthenticatedId)
| summarize ['users/authenticated_unique'] = dcount(user_AuthenticatedId) by bin(timestamp, 15m)
| render barchart

표준 메트릭에는 적용되지 않습니다.

사용자 지정 메트릭은 메트릭 저장소와 로그 모두에 저장되므로 Kusto 쿼리를 사용하여 검색할 수 있습니다.

예를 들어 GetMetric 및 TrackValue를 사용하여 애플리케이션 _telemetryClient.GetMetric("Sales Amount").TrackValue(saleAmount); 을 계측하여 사용자 지정 메트릭 Sales Amount를 추적하는 경우 사용 가능한 각 집계에 대해 다음 Kusto 쿼리를 사용할 수 있습니다.

평균(avg)

customMetrics
| where name == "Sales Amount"
| extend
    customMetric_valueSum = iif(itemType == 'customMetric', valueSum, todouble('')),
    customMetric_valueCount = iif(itemType == 'customMetric', valueCount, toint(''))
| summarize ['customMetrics/Sales Amount_avg'] = sum(customMetric_valueSum) / sum(customMetric_valueCount) by bin(timestamp, 15m)
| order by timestamp desc
| render timechart

최소(분)

customMetrics
| where name == "Sales Amount"
| extend customMetric_valueMin = iif(itemType == 'customMetric', valueMin, todouble(''))
| summarize ['customMetrics/Sales Amount_min'] = min(customMetric_valueMin) by bin(timestamp, 15m)
| render timechart

최대(최대)

customMetrics
| where name == "Sales Amount"
| extend customMetric_valueMax = iif(itemType == 'customMetric', valueMax, todouble(''))
| summarize ['customMetrics/Sales Amount_max'] = max(customMetric_valueMax) by bin(timestamp, 15m)
| render timechart

합계(합계)

customMetrics
| where name == "Sales Amount"
| extend customMetric_valueSum = iif(itemType == 'customMetric', valueSum, todouble(''))
| summarize ['customMetrics/Sales Amount_sum'] = sum(customMetric_valueSum) by bin(timestamp, 15m)
| render barchart

개수(개수)

customMetrics
| where name == "Sales Amount"
| extend customMetric_valueCount = iif(itemType == 'customMetric', valueCount, toint(''))
| summarize ['customMetrics/Sales Amount_count'] = sum(customMetric_valueCount) by bin(timestamp, 15m)
| render barchart

고유(고유)

customMetrics
| where name == "Sales Amount"
| extend customMetric_value = iif(itemType == 'customMetric', value, todouble(''))
| summarize ['customMetrics/Sales Amount_unique'] = dcount(customMetric_value) by bin(timestamp, 15m)
| render barchart