Bicep에 대한 문자열 함수
이 문서에서는 문자열 작업을 위한 Bicep 함수에 대해 설명합니다.
base64
base64(inputString)
입력 문자열의 base64 표현을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| inputString | 예 | string | base64 표현으로 반환할 값입니다. |
반환 값
Base64 표현을 포함하는 문자열입니다.
예제
다음 예에서는 base64 함수를 사용하는 방법을 보여 줍니다.
param stringData string = 'one, two, three'
param jsonFormattedData string = '{\'one\': \'a\', \'two\': \'b\'}'
var base64String = base64(stringData)
var base64Object = base64(jsonFormattedData)
output base64Output string = base64String
output toStringOutput string = base64ToString(base64String)
output toJsonOutput object = base64ToJson(base64Object)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| base64Output | 문자열 | b25lLCB0d28sIHRocmVl |
| toStringOutput | 문자열 | one, two, three |
| toJsonOutput | Object | {“one”: “a”, “two”: “b”} |
base64ToJson
base64ToJson(base64Value)
base64 표현을 JSON 개체로 변환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| base64Value | 예 | string | JSON 개체로 변환할 base64 표현입니다. |
반환 값
JSON 개체입니다.
예제
다음 예제에서는 base64ToJson 함수를 사용하여 base64 값을 변환합니다.
param stringData string = 'one, two, three'
param jsonFormattedData string = '{\'one\': \'a\', \'two\': \'b\'}'
var base64String = base64(stringData)
var base64Object = base64(jsonFormattedData)
output base64Output string = base64String
output toStringOutput string = base64ToString(base64String)
output toJsonOutput object = base64ToJson(base64Object)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| base64Output | 문자열 | b25lLCB0d28sIHRocmVl |
| toStringOutput | 문자열 | one, two, three |
| toJsonOutput | Object | {“one”: “a”, “two”: “b”} |
base64ToString
base64ToString(base64Value)
base64 표현을 문자열로 변환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| base64Value | 예 | string | 문자열로 변환할 base64 표현입니다. |
반환 값
변환된 base64 값의 문자열입니다.
예제
다음 예제에서는 base64ToString 함수를 사용하여 base64 값을 변환합니다.
param stringData string = 'one, two, three'
param jsonFormattedData string = '{\'one\': \'a\', \'two\': \'b\'}'
var base64String = base64(stringData)
var base64Object = base64(jsonFormattedData)
output base64Output string = base64String
output toStringOutput string = base64ToString(base64String)
output toJsonOutput object = base64ToJson(base64Object)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| base64Output | 문자열 | b25lLCB0d28sIHRocmVl |
| toStringOutput | 문자열 | one, two, three |
| toJsonOutput | Object | {“one”: “a”, “two”: “b”} |
concat
concat(arg1, arg2, arg3, ...)
여러 문자열 값을 결합하고 연결된 문자열을 반환하거나 여러 배열을 결합하고 연결된 배열을 반환합니다. 가독성을 개선하려면 concat() 함수 대신 문자열 보간을 사용합니다. 그러나 다중 선 문자열의 문자열 대체와 같은 경우에 concat() 함수 또는 replace() 함수를 다시 사용해야 할 수 있습니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| arg1 | 예 | 문자열 또는 배열 | 연결할 첫 번째 문자열 또는 배열입니다. |
| 더 많은 인수 | 아니요 | 문자열 또는 배열 | 연결 순서로 나타낸 더 많은 문자열 또는 배열입니다. |
이 함수는 인수를 개수에 관계없이 사용할 수 있으며 매개 변수에 대한 문자열이나 배열 중 하나를 사용할 수 있습니다. 그러나 매개 변수에 대한 배열과 문자열을 둘 다 제공할 수는 없습니다. 문자열은 다른 문자열과만 연결됩니다.
반환 값
연결된 값의 문자열 또는 배열입니다.
예제
다음 예제에서는 보간 사용과 concat() 함수 사용 간의 비교를 보여 줍니다. 두 출력은 동일한 값을 반환합니다.
param prefix string = 'prefix'
output concatOutput string = concat(prefix, 'And', uniqueString(resourceGroup().id))
output interpolationOutput string = '${prefix}And${uniqueString(resourceGroup().id)}'
기본값이 있는 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| concatOutput | 문자열 | prefixAnd5yj4yjf5mbg72 |
| interpolationOutput | 문자열 | prefixAnd5yj4yjf5mbg72 |
보간은 현재 다중 선 문자열에서 지원되지 않습니다. 다음 예제에서는 보간 사용과 concat() 함수 사용 간의 비교를 보여 줍니다.
var blocked = 'BLOCKED'
output concatOutput string = concat('''interpolation
is ''', blocked)
output interpolationOutput string = '''interpolation
is ${blocked}'''
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| concatOutput | 문자열 | interpolation\nis BLOCKED |
| interpolationOutput | 문자열 | interpolation\nis ${blocked} |
contains
contains(container, itemToFind)
배열에 값이 포함되는지, 개체에 키가 포함되는지 또는 문자열에 하위 문자열이 포함되는지를 확인합니다. 문자열 비교에서는 대/소문자를 구분합니다. 그러나 개체에 키가 포함되어 있는지를 테스트할 때는 비교에서 대/소문자를 구분하지 않습니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| 컨테이너 | 예 | 배열, 개체 또는 문자열 | 찾을 값을 포함하는 값입니다. |
| itemToFind | 예 | 문자열 또는 int | 찾을 값입니다. |
반환 값
True항목을 찾았으면
예제
다음 예제에서는 여러 다른 형식의 contains를 사용하는 방법을 보여 줍니다.
param stringToTest string = 'OneTwoThree'
param objectToTest object = {
one: 'a'
two: 'b'
three: 'c'
}
param arrayToTest array = [
'one'
'two'
'three'
]
output stringTrue bool = contains(stringToTest, 'e')
output stringFalse bool = contains(stringToTest, 'z')
output objectTrue bool = contains(objectToTest, 'one')
output objectFalse bool = contains(objectToTest, 'a')
output arrayTrue bool = contains(arrayToTest, 'three')
output arrayFalse bool = contains(arrayToTest, 'four')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| stringTrue | Bool | True |
| stringFalse | Bool | False |
| objectTrue | Bool | True |
| objectFalse | Bool | False |
| arrayTrue | Bool | True |
| arrayFalse | Bool | False |
dataUri
dataUri(stringToConvert)
값을 데이터 URI로 변환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToConvert | 예 | string | 데이터 URI로 변환할 값입니다. |
반환 값
데이터 URI로 형식이 지정된 문자열입니다.
예제
다음 예제에서는 값을 데이터 URI로 변환하고 데이터 URI를 문자열로 변환합니다.
param stringToTest string = 'Hello'
param dataFormattedString string = 'data:;base64,SGVsbG8sIFdvcmxkIQ=='
output dataUriOutput string = dataUri(stringToTest)
output toStringOutput string = dataUriToString(dataFormattedString)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| dataUriOutput | 문자열 | data:text/plain;charset=utf8;base64,SGVsbG8= |
| toStringOutput | 문자열 | Hello, World! |
dataUriToString
dataUriToString(dataUriToConvert)
데이터 URI로 형식이 지정된 값을 문자열로 변환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| dataUriToConvert | 예 | string | 변환할 데이터 URI 값입니다. |
반환 값
변환된 값을 포함하는 문자열입니다.
예제
다음 예제에서는 값을 데이터 URI로 변환하고 데이터 URI를 문자열로 변환합니다.
param stringToTest string = 'Hello'
param dataFormattedString string = 'data:;base64,SGVsbG8sIFdvcmxkIQ=='
output dataUriOutput string = dataUri(stringToTest)
output toStringOutput string = dataUriToString(dataFormattedString)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| dataUriOutput | 문자열 | data:text/plain;charset=utf8;base64,SGVsbG8= |
| toStringOutput | 문자열 | Hello, World! |
empty
empty(itemToTest)
배열, 개체 또는 문자열이 비어 있는지 null인지 확인합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| itemToTest | 예 | 배열, 개체 또는 문자열 | 비어 있는지 null인지 확인할 값입니다. |
반환 값
값이 비어 있거나 null이면 True를 반환하고, 그렇지 않으면 False를 반환합니다.
예제
다음 예제에서는 배열, 개체 및 문자열이 비어 있는지 여부를 확인합니다.
param testArray array = []
param testObject object = {}
param testString string = ''
param testNullString string?
output arrayEmpty bool = empty(testArray)
output objectEmpty bool = empty(testObject)
output stringEmpty bool = empty(testString)
output stringNull bool = empty(testNullString)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| arrayEmpty | Bool | True |
| objectEmpty | Bool | True |
| stringEmpty | Bool | True |
| stringNull | Bool | True |
endsWith
endsWith(stringToSearch, stringToFind)
문자열이 값으로 끝나는지 여부를 결정합니다. 비교는 대/소문자를 구분합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToSearch | 예 | string | 찾을 값을 포함하는 값입니다. |
| stringToFind | 예 | string | 찾을 값입니다. |
반환 값
True문자열의 마지막 문자 또는 문자가 값과 일치하면 이고, 그렇지 않으면 . False
예제
다음 예제에서는 startsWith 및 endsWith 함수를 사용하는 방법을 보여 줍니다.
output startsTrue bool = startsWith('abcdef', 'ab')
output startsCapTrue bool = startsWith('abcdef', 'A')
output startsFalse bool = startsWith('abcdef', 'e')
output endsTrue bool = endsWith('abcdef', 'ef')
output endsCapTrue bool = endsWith('abcdef', 'F')
output endsFalse bool = endsWith('abcdef', 'e')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| startsTrue | Bool | True |
| startsCapTrue | Bool | True |
| startsFalse | Bool | False |
| endsTrue | Bool | True |
| endsCapTrue | Bool | True |
| endsFalse | Bool | False |
첫째
first(arg1)
문자열의 첫 번째 문자 또는 배열의 첫 번째 요소를 반환합니다. 빈 문자열이 지정되면 함수는 빈 문자열을 반환합니다. 빈 배열의 경우 함수는 null을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| arg1 | 예 | 배열 또는 문자열 | 첫 번째 요소 또는 문자를 검색할 값입니다. |
반환 값
배열의 첫 번째 문자의 문자열 또는 첫 번째 요소의 형식(문자열, int, 배열 또는 개체)입니다.
예제
다음 예제에서는 배열 및 문자열에 첫 번째 함수를 사용하는 방법을 보여 줍니다.
param arrayToTest array = [
'one'
'two'
'three'
]
output arrayOutput string = first(arrayToTest)
output stringOutput string = first('One Two Three')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| arrayOutput | 문자열 | 1 |
| stringOutput | 문자열 | O |
format
format(formatString, arg1, arg2, ...)
입력 값에서 형식이 지정된 문자열을 만듭니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| formatString | 예 | string | 복합 형식 문자열입니다. |
| arg1 | 예 | 문자열, 정수 또는 부울 | 서식이 지정된 문자열에 포함할 값입니다. |
| 추가 인수 | 아니요 | 문자열, 정수 또는 부울 | 서식이 지정된 문자열에 포함할 추가 값입니다. |
설명
Bicep 파일에서 문자열의 서식을 지정하려면 이 함수를 사용합니다. .NET의 System.String.Format 메서드와 동일한 서식 옵션을 사용합니다.
예제
다음 예제에서는 서식 함수를 사용하는 방법을 보여 줍니다.
param greeting string = 'Hello'
param name string = 'User'
param numberToFormat int = 8175133
param objectToFormat object = { prop: 'value' }
output formatTest string = format('{0}, {1}. Formatted number: {2:N0}', greeting, name, numberToFormat)
output formatObject string = format('objectToFormat: {0}', objectToFormat)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| formatTest | 문자열 | Hello, User. Formatted number: 8,175,133 |
| formatObject | 문자열 | objectToFormat: {'prop':'value'} |
guid
guid(baseString, ...)
매개 변수로 제공된 값을 기반으로 고유 식별자 형식의 값을 만듭니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| baseString | 예 | string | GUID를 만들기 위해 해시 함수에 사용되는 값입니다. |
| 필요에 따라 추가하는 매개 변수 | 아니요 | string | 고유성 수준을 지정하는 값을 만들기 위해 필요한 만큼 문자열을 추가할 수 있습니다. |
설명
이 함수는 고유 식별자 형식의 값을 만들어야 할 때 유용합니다. 결과의 고유성 범위를 제한하는 매개 변수 값을 제공합니다. 구독, 리소스 그룹 또는 배포까지 해당 이름이 고유한지 여부를 지정할 수 있습니다.
반환된 값은 임의 문자열이 아닌 매개 변수의 해시 함수 결과입니다. 반환된 값은 36자입니다. 전역적으로 고유하지 않습니다. 매개 변수의 해당 해시 값을 기준으로 하지 않는 새 GUID를 만들려면 newGuid 함수를 사용합니다.
참고 항목
매개 변수의 순서는 반환된 값에 영향을 줍니다. 예시:
guid('hello', 'world') 및 guid('world', 'hello')
동일한 값을 반환하지 마세요.
다음 예제에서는 guid를 사용하여 일반적으로 사용하는 수준에 대해 고유한 값을 만드는 방법을 보여 줍니다.
구독에 범위가 지정된 고유함
guid(subscription().subscriptionId)
리소스 그룹에 범위가 지정된 고유함
guid(resourceGroup().id)
리소스 그룹의 배포에 범위가 지정된 고유함
guid(resourceGroup().id, deployment().name)
guid 함수는 RFC 4122 §4.3에서 알고리즘을 구현합니다. 원본은 GuidUtility에서 찾을 수 있으며 일부 수정 사항이 있습니다.
반환 값
고유 식별자 형식의 문자 36자를 포함하고 있는 문자열입니다.
예제
다음 예에서는 guid에서 결과를 반환합니다.
output guidPerSubscription string = guid(subscription().subscriptionId)
output guidPerResourceGroup string = guid(resourceGroup().id)
output guidPerDeployment string = guid(resourceGroup().id, deployment().name)
indexof
indexOf(stringToSearch, stringToFind)
문자열 내 값의 첫 번째 위치를 반환합니다. 비교는 대/소문자를 구분합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToSearch | 예 | string | 찾을 값을 포함하는 값입니다. |
| stringToFind | 예 | string | 찾을 값입니다. |
반환 값
찾을 항목의 위치를 나타내는 정수입니다. 값은 0부터 시작합니다. 항목을 찾을 수 없으면 -1이 반환됩니다.
예제
다음 예제에서는 indexOf 및 lastIndexOf 함수를 사용하는 방법을 보여 줍니다.
output firstT int = indexOf('test', 't')
output lastT int = lastIndexOf('test', 't')
output firstString int = indexOf('abcdef', 'CD')
output lastString int = lastIndexOf('abcdef', 'AB')
output notFound int = indexOf('abcdef', 'z')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| firstT | 정수 | 0 |
| lastT | 정수 | 3 |
| firstString | 정수 | 2 |
| lastString | 정수 | 0 |
| notFound | 정수 | -1 |
join
join(inputArray, delimiter)
구분 기호를 사용하여 구분된 단일 문자열에 문자열 배열을 조인합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| inputArray | 예 | 문자열 배열입니다. | 조인할 문자열의 배열입니다. |
| delimiter | 예 | 문자열 분할에 사용할 구분 기호입니다. |
반환 값
문자열입니다.
예제
다음 예제에서는 입력 문자열 배열을 쉼표 또는 세미콜론으로 구분된 문자열에 조인합니다.
var arrayString = [
'one'
'two'
'three'
]
output firstOutput string = join(arrayString, ',')
output secondOutput string = join(arrayString, ';')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| firstOutput | 문자열 | "one,two,three" |
| secondOutput | 문자열 | "one;two;three" |
이 함수에는 Bicep CLI 버전 0.8.X 이상이 필요합니다.
json
json(arg1)
유효한 JSON 문자열을 JSON 데이터 형식으로 변환합니다. 자세한 내용은 json 함수를 참조하세요.
네임스페이스: sys.
마지막
last(arg1)
문자열의 마지막 문자 또는 배열의 마지막 요소를 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| arg1 | 예 | 배열 또는 문자열 | 마지막 요소 또는 문자를 검색할 값입니다. |
반환 값
배열의 마지막 문자의 문자열 또는 마지막 요소의 형식(문자열, int, 배열 또는 개체)입니다.
예제
다음 예제에서는 배열 및 문자열에 마지막 함수를 사용하는 방법을 보여 줍니다.
param arrayToTest array = [
'one'
'two'
'three'
]
output arrayOutput string = last(arrayToTest)
output stringOutput string = last('One Two Three')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| arrayOutput | 문자열 | three |
| stringOutput | 문자열 | e |
lastindexof
lastIndexOf(stringToSearch, stringToFind)
문자열 내 값의 마지막 위치를 반환합니다. 비교는 대/소문자를 구분합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToSearch | 예 | string | 찾을 값을 포함하는 값입니다. |
| stringToFind | 예 | string | 찾을 값입니다. |
반환 값
찾을 항목의 마지막 위치를 나타내는 정수입니다. 값은 0부터 시작합니다. 항목을 찾을 수 없으면 -1이 반환됩니다.
예제
다음 예제에서는 indexOf 및 lastIndexOf 함수를 사용하는 방법을 보여줍니다.
output firstT int = indexOf('test', 't')
output lastT int = lastIndexOf('test', 't')
output firstString int = indexOf('abcdef', 'CD')
output lastString int = lastIndexOf('abcdef', 'AB')
output notFound int = indexOf('abcdef', 'z')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| firstT | 정수 | 0 |
| lastT | 정수 | 3 |
| firstString | 정수 | 2 |
| lastString | 정수 | 0 |
| notFound | 정수 | -1 |
length
length(string)
문자열의 문자 수, 배열의 요소 수 또는 개체의 루트 수준 속성 수를 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| arg1 | 예 | 배열, 문자열 또는 개체 | 요소의 수를 가져오는 데 사용할 배열, 문자 수를 가져오는 데 사용할 문자열 또는 루트 수준의 속성 수를 가져오려는 데 사용할 개체입니다. |
반환 값
int입니다.
예제
다음 예제에서는 배열 및 문자열에 length를 사용하는 방법을 보여 줍니다.
param arrayToTest array = [
'one'
'two'
'three'
]
param stringToTest string = 'One Two Three'
param objectToTest object = {
propA: 'one'
propB: 'two'
propC: 'three'
propD: {
'propD-1': 'sub'
'propD-2': 'sub'
}
}
output arrayLength int = length(arrayToTest)
output stringLength int = length(stringToTest)
output objectLength int = length(objectToTest)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| arrayLength | 정수 | 3 |
| stringLength | 정수 | 13 |
| objectLength | 정수 | 4 |
newGuid
newGuid()
전역적으로 고유한 식별자의 형식으로 값을 반환합니다. 이 함수는 매개 변수의 기본값에만 사용할 수 있습니다.
네임스페이스: sys.
설명
이 함수는 매개 변수의 기본값에 대한 언어 식 내에서만 사용할 수 있습니다. Bicep 파일의 다른 위치에서 이 함수를 사용하면 오류가 반환됩니다. 호출될 때마다 다른 값을 반환하는 함수이므로 Bicep 파일의 다른 부분에서는 허용되지 않습니다. 동일한 매개 변수를 사용하여 동일한 Bicep 파일을 배포하면 동일한 결과가 안정적으로 생성되지 않습니다.
newGuid 함수는 매개 변수를 사용하지 않으므로 guid 함수와 다릅니다. 동일한 매개 변수로 guid를 호출하면 매번 동일한 식별자를 반환합니다. 특정 환경에 대해 동일한 GUID를 안정적으로 생성해야 하는 경우 guid를 사용합니다. 테스트 환경에 리소스를 배포하는 것과 같이 매번 다른 식별자가 필요한 경우 newGuid를 사용합니다.
newGuid 함수는 .NET Framework의 Guid 구조를 사용하여 전역적으로 고유한 식별자를 생성합니다.
이전에 성공한 배포를 다시 배포하는 옵션을 사용하고 이전 배포에 newGuid를 사용하는 매개 변수가 포함된 경우 해당 매개 변수는 재평가되지 않습니다. 대신 이전 배포의 매개 변수 값이 롤백 배포에서 자동으로 다시 사용됩니다.
테스트 환경에서는 짧은 시간 동안만 지속되는 리소스를 반복적으로 배포해야 할 수 있습니다. 고유 이름을 생성하는 대신 uniqueString과 함께 newGuid를 사용하여 고유한 이름을 만들 수 있습니다.
기본값에 대한 newGuid 함수에 의존하는 Bicep 파일은 주의를 기울여 재배포해야 합니다. 재배포할 때 매개 변수 값을 제공하지 않으면 함수는 재평가됩니다. 새 리소스를 만드는 대신 기존 리소스를 업데이트하려면 이전 배포의 매개 변수 값을 제공해야 합니다.
반환 값
고유 식별자 형식의 문자 36자를 포함하고 있는 문자열입니다.
예제
다음 예제에서는 새 식별자를 포함하는 매개 변수를 보여 줍니다.
param guidValue string = newGuid()
output guidOutput string = guidValue
이전 예제의 출력은 각 배포마다 다르지만 다음과 유사합니다.
| 이름 | 타입 | 값 |
|---|---|---|
| guidOutput | string | b76a51fc-bd72-4a77-b9a2-3c29e7d2e551 |
다음 예제에서는 newGuid 함수를 사용하여 스토리지 계정에 대한 고유한 이름을 만듭니다. 이 Bicep 파일은 스토리지 계정이 짧은 시간 동안 존재하고 다시 배포되지 않는 테스트 환경에 사용할 수 있습니다.
param guidValue string = newGuid()
var storageName = 'storage${uniqueString(guidValue)}'
resource myStorage 'Microsoft.Storage/storageAccounts@2023-04-01' = {
name: storageName
location: 'West US'
sku: {
name: 'Standard_LRS'
}
kind: 'StorageV2'
properties: {}
}
output nameOutput string = storageName
이전 예제의 출력은 각 배포마다 다르지만 다음과 유사합니다.
| 이름 | 타입 | 값 |
|---|---|---|
| nameOutput | string | storagenziwvyru7uxie |
padLeft
padLeft(valueToPad, totalLength, paddingCharacter)
지정된 총 길이에 도달할 때까지 왼쪽에 문자를 추가하여 오른쪽 맞추어진 문자열을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| valueToPad | 예 | 문자열 또는 int | 오른쪽으로 맞출 값입니다. |
| totalLength | 예 | int | 반환된 문자열에서 문자의 총수입니다. |
| paddingCharacter | 아니요 | 단일 문자 | 총 길이에 도달할 때까지 왼쪽 여백에 사용되는 문자입니다. 기본값은 공백입니다. |
원래 문자열이 채울 문자 수보다 긴 경우 문자가 추가되지 않습니다.
반환 값
최소한 지정된 문자의 수를 포함하는 문자열입니다.
예제
다음 예제는 문자열이 총 문자 수에 도달할 때까지 0 문자를 추가하여 사용자가 제공한 매개 변수 값을 채우는 방법을 보여줍니다.
param testString string = '123'
output stringOutput string = padLeft(testString, 10, '0')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| stringOutput | 문자열 | 0000000123 |
replace
replace(originalString, oldString, newString)
다른 문자열로 대체한 어떤 문자열의 인스턴스를 포함한 새 문자열을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| originalString | 예 | string | 다른 문자열로 대체한 어떤 문자열의 인스턴스를 포함하는 값입니다. |
| oldString | 예 | string | 원래 문자열에서 제거할 문자열입니다. |
| newString | 예 | string | 제거된 문자열 대신 추가할 문자열입니다. |
반환 값
문자가 대체된 문자열입니다.
예제
다음 예제에서는 사용자가 제공한 문자열에서 모든 대시를 제거하는 방법 및 문자열의 일부를 다른 문자열로 대체하는 방법을 보여줍니다.
param testString string = '123-123-1234'
output firstOutput string = replace(testString, '-', '')
output secondOutput string = replace(testString, '1234', 'xxxx')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| firstOutput | 문자열 | 1231231234 |
| secondOutput | 문자열 | 123-123-xxxx |
skip
skip(originalValue, numberToSkip)
지정된 문자 수 이후의 모든 문자를 포함하는 문자열 또는 지정된 요소 수 이후의 모든 요소를 포함하는 배열을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| originalValue | 예 | 배열 또는 문자열 | 건너뛰는 데 사용할 배열 또는 문자열입니다. |
| numberToSkip | 예 | int | 건너뛸 요소 또는 문자 수입니다. 이 값이 0 이하이면 값의 모든 요소 또는 문자가 반환됩니다. 이 값이 배열 또는 문자열의 길이보다 크면 빈 배열 또는 문자열이 반환됩니다. |
반환 값
배열 또는 문자열입니다.
예제
다음 예제에서는 배열에서 지정된 요소 수 및 문자열에서 지정된 수의 문자를 건너뜁니다.
param testArray array = [
'one'
'two'
'three'
]
param elementsToSkip int = 2
param testString string = 'one two three'
param charactersToSkip int = 4
output arrayOutput array = skip(testArray, elementsToSkip)
output stringOutput string = skip(testString, charactersToSkip)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| arrayOutput | 배열 | ["three"] |
| stringOutput | 문자열 | two three |
split
split(inputString, delimiter)
지정된 구분 기호로 구분되는 입력 문자열의 부분 문자열을 포함하는 문자열의 배열을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| inputString | 예 | string | 분할할 문자열입니다. |
| delimiter | 예 | 문자열 또는 문자열 배열 | 문자열 분할에 사용할 구분 기호입니다. |
반환 값
문자열 배열입니다.
예제
다음 예제에서는 쉼표를 사용하여 또는 쉼표 또는 세미콜론을 사용하여 입력 문자열을 분할합니다.
param firstString string = 'one,two,three'
param secondString string = 'one;two,three'
var delimiters = [
','
';'
]
output firstOutput array = split(firstString, ',')
output secondOutput array = split(secondString, delimiters)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| firstOutput | 배열 | [“one”, “two”, “three”] |
| secondOutput | 배열 | [“one”, “two”, “three”] |
startswith
startsWith(stringToSearch, stringToFind)
문자열이 값으로 시작하는지 여부를 결정합니다. 비교는 대/소문자를 구분합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToSearch | 예 | string | 찾을 값을 포함하는 값입니다. |
| stringToFind | 예 | string | 찾을 값입니다. |
반환 값
True문자열의 첫 번째 문자 또는 문자가 값과 일치하면 이고, 그렇지 않으면 . False
예제
다음 예제에서는 startsWith 및 endsWith 함수를 사용하는 방법을 보여 줍니다.
output startsTrue bool = startsWith('abcdef', 'ab')
output startsCapTrue bool = startsWith('abcdef', 'A')
output startsFalse bool = startsWith('abcdef', 'e')
output endsTrue bool = endsWith('abcdef', 'ef')
output endsCapTrue bool = endsWith('abcdef', 'F')
output endsFalse bool = endsWith('abcdef', 'e')
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| startsTrue | Bool | True |
| startsCapTrue | Bool | True |
| startsFalse | Bool | False |
| endsTrue | Bool | True |
| endsCapTrue | Bool | True |
| endsFalse | Bool | False |
string
string(valueToConvert)
지정한 값을 문자열로 변환합니다.
문자열은 있는 그대로 반환됩니다. 다른 형식은 해당 JSON 표현으로 변환됩니다.
문자열을 JSON으로 변환해야 하는 경우(예: 따옴표/이스케이프) substring(string([value]), 1, length(string([value]) - 2)를 사용할 수 있습니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| valueToConvert | 예 | 모두 | 문자열로 변환할 값입니다. 개체 및 배열을 비롯하여 모든 값 형식을 변환할 수 있습니다. |
반환 값
변환된 값의 문자열입니다.
예제
다음 예제에서는 다른 형식의 값을 문자열로 변환하는 방법을 보여 줍니다.
param testObject object = {
valueA: 10
valueB: 'Example Text'
}
param testArray array = [
'\'a\''
'"b"'
'\\c\\'
]
param testInt int = 5
param testString string = 'foo " \' \\'
output objectOutput string = string(testObject)
output arrayOutput string = string(testArray)
output intOutput string = string(testInt)
output stringOutput string = string(testString)
output stringEscapedOutput string = substring(string([testString]), 1, length(string([testString])) - 2)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| objectOutput | 문자열 | {"valueA":10,"valueB":"Example Text"} |
| arrayOutput | 문자열 | ["'a'","\"b\"","\\c\\"] |
| intOutput | 문자열 | 5 |
| stringOutput | 문자열 | foo " ' \ |
| stringEscapedOutput | 문자열 | "foo \" ' \\" |
substring
substring(stringToParse, startIndex, length)
지정된 문자 위치에서 시작하고 지정한 개수의 문자를 포함하는 부분 문자열을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToParse | 예 | string | 부분 문자열을 추출할 원래 문자열입니다. |
| startIndex | 아니요 | int | 부분 문자열의 0부터 시작하는 문자 위치입니다. |
| length | 아니요 | int | 부분 문자열에 대한 문자 수입니다. 문자열 내 위치를 참조해야 합니다. 0 이상이어야 합니다. 생략하면 시작 위치에서 문자열의 나머지 부분이 반환됩니다. |
반환 값
하위 문자열입니다. 또는 길이가 0인 경우 빈 문자열입니다.
설명
함수는 부분 문자열이 문자열의 끝을 넘어 확장되거나 길이가 0보다 작은 경우 실패합니다. 다음 예제는 "인덱스 및 길이 매개 변수는 문자열 내 위치를 참조해야 합니다. 인덱스 매개 변수: '0', 길이 매개 변수: '11', 문자열 매개 변수의 길이: '10'." 오류와 함께 실패합니다.
param inputString string = '1234567890'
var prefix = substring(inputString, 0, 11)
예제
다음 예제에서는 매개 변수에서 하위 문자열을 추출합니다.
param testString string = 'one two three'
output substringOutput string = substring(testString, 4, 3)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| substringOutput | 문자열 | two |
take
take(originalValue, numberToTake)
문자열 시작부터 지정된 수의 문자를 포함하는 문자열 또는 배열 시작부터 지정된 수의 요소를 포함하는 배열을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| originalValue | 예 | 배열 또는 문자열 | 요소를 가져올 배열 또는 문자열입니다. |
| numberToTake | 예 | int | 수락할 요소 또는 문자의 수입니다. 이 값이 0 이하이면 빈 배열 또는 문자열이 반환됩니다. 지정된 배열 또는 문자열의 길이보다 크면 배열 또는 문자열의 모든 요소가 반환됩니다. |
반환 값
배열 또는 문자열입니다.
예제
다음 예제에서는 배열에서 지정된 수의 요소 및 문자열의 문자를 가져옵니다.
param testArray array = [
'one'
'two'
'three'
]
param elementsToTake int = 2
param testString string = 'one two three'
param charactersToTake int = 2
output arrayOutput array = take(testArray, elementsToTake)
output stringOutput string = take(testString, charactersToTake)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| arrayOutput | 배열 | ["one", "two"] |
| stringOutput | 문자열 | On |
toLower
toLower(stringToChange)
지정된 문자열을 소문자로 변환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToChange | 예 | string | 소문자로 변환할 값입니다. |
반환 값
소문자로 변환된 문자열입니다.
예제
다음 예제는 매개 변수 값을 소문자 및 대문자로 변환합니다.
param testString string = 'One Two Three'
output toLowerOutput string = toLower(testString)
output toUpperOutput string = toUpper(testString)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| toLowerOutput | 문자열 | one two three |
| toUpperOutput | 문자열 | ONE TWO THREE |
toUpper
toUpper(stringToChange)
지정된 문자열을 대문자로 변환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToChange | 예 | string | 대문자로 변환할 값입니다. |
반환 값
대문자로 변환된 문자열입니다.
예제
다음 예제는 매개 변수 값을 소문자 및 대문자로 변환합니다.
param testString string = 'One Two Three'
output toLowerOutput string = toLower(testString)
output toUpperOutput string = toUpper(testString)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| toLowerOutput | 문자열 | one two three |
| toUpperOutput | 문자열 | ONE TWO THREE |
trim
trim(stringToTrim)
지정된 문자열에서 모든 선행 및 후행 공백 문자를 제거합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToTrim | 예 | string | 자를 값입니다. |
반환 값
선행 및 후행 공백 문자가 없는 문자열입니다.
예제
다음은 매개 변수에서 공백 문자를 자르는 예입니다.
param testString string = ' one two three '
output return string = trim(testString)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| return | 문자열 | one two three |
uniqueString
uniqueString(baseString, ...)
매개 변수로 제공된 값을 기반으로 결정 해시 문자열을 만듭니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| baseString | 예 | string | 고유한 문자열을 만들기 위해 해시 함수에서 사용되는 값입니다. |
| 필요에 따라 추가하는 매개 변수 | 아니요 | string | 고유성 수준을 지정하는 값을 만들기 위해 필요한 만큼 문자열을 추가할 수 있습니다. |
설명
이 함수는 리소스의 고유한 이름을 만들어야 할 때 유용합니다. 결과의 고유성 범위를 제한하는 매개 변수 값을 제공합니다. 구독, 리소스 그룹 또는 배포까지 해당 이름이 고유한지 여부를 지정할 수 있습니다.
반환된 값은 임의 문자열이 아닌 해시 함수의 결과입니다. 반환된 값은 13자입니다. 전역적으로 고유하지 않습니다. 의미있는 이름을 만들기 위해 해당 값과 명명 규칙의 접두사를 결합할 수도 있습니다. 다음 예제에서는 반환된 값의 형식을 보여 줍니다. 실제 값은 제공된 매개 변수에 따라 달라집니다.
tcvhiyu5h2o5o
다음 예제에서는 uniqueString를 사용하여 일반적으로 사용하는 수준에 대해 고유한 값을 만드는 방법을 보여 줍니다.
구독에 범위가 지정된 고유함
uniqueString(subscription().subscriptionId)
리소스 그룹에 범위가 지정된 고유함
uniqueString(resourceGroup().id)
리소스 그룹의 배포에 범위가 지정된 고유함
uniqueString(resourceGroup().id, deployment().name)
다음 예제에서는 리소스 그룹에 따라 스토리지 계정에 고유한 이름을 만드는 방법을 보여 줍니다. 리소스 그룹의 내부에서 같은 방식으로 생성된 경우 이름은 고유하지 않습니다.
resource mystorage 'Microsoft.Storage/storageAccounts@2023-04-01' = {
name: 'storage${uniqueString(resourceGroup().id)}'
...
}
Bicep 파일을 배포할 때마다 새 고유 이름을 만들어야 하고 리소스를 업데이트 하지 않으려는 경우 uniqueString에 utcNow 함수를 사용할 수 있습니다. 이 방법은 테스트 환경에서 사용할 수 있습니다. 예제는 utcNow를 참조하세요. utcNow 함수는 매개 변수의 기본값에 대한 표현식 내에서만 사용할 수 있습니다.
반환 값
13개의 문자를 포함하는 문자열입니다.
예제
다음 예제에서는 uniquestring에서 결과 반환합니다.
output uniqueRG string = uniqueString(resourceGroup().id)
output uniqueDeploy string = uniqueString(resourceGroup().id, deployment().name)
uri
uri(baseUri, relativeUri)
baseUri와 relativeUri 문자열을 결합하여 절대 URI를 만듭니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| baseUri | 예 | string | 기본 uri 문자열입니다. 이 표 다음에 설명된 대로 후행 슬래시('/')의 처리와 관련된 동작을 주의해서 살펴봅니다. |
| relativeUri | 예 | string | 기본 uri 문자열에 추가할 상대 uri 문자열입니다. |
후행 슬래시로 끝나는 경우
baseUri결과는 단순히baseUri뒤에 잇relativeUri습니다. 선행 슬래시로 시작하는 경우relativeUri후행 슬래시와 선행 슬래시가 하나로 결합됩니다.baseUri후행 슬래시로 끝나지 않으면 두 가지 중 하나가 발생합니다.앞면 근처의 "//"를 제외하고 슬래시가 전혀 없는 경우
baseUri결과는 단순히baseUri뒤에 잇relativeUri습니다.슬래시가 있지만 슬래시로 끝나지 않는 경우
baseUri마지막 슬래시 이후의 모든 항목이 제거되고baseUri그 다음에 결과가baseUrirelativeUri나옵니다.
다음 몇 가지 예를 참조하세요.
uri('http://contoso.org/firstpath', 'myscript.sh') -> http://contoso.org/myscript.sh
uri('http://contoso.org/firstpath/', 'myscript.sh') -> http://contoso.org/firstpath/myscript.sh
uri('http://contoso.org/firstpath/', '/myscript.sh') -> http://contoso.org/firstpath/myscript.sh
uri('http://contoso.org/firstpath/azuredeploy.json', 'myscript.sh') -> http://contoso.org/firstpath/myscript.sh
uri('http://contoso.org/firstpath/azuredeploy.json/', 'myscript.sh') -> http://contoso.org/firstpath/azuredeploy.json/myscript.sh
자세한 내용을 baseUri 보려면 RFC 3986 섹션 5에 지정된 대로 매개 변수와 relativeUri 매개 변수가 확인됩니다.
반환 값
기본 및 상대 값에 대한 절대 URI를 나타내는 문자열입니다.
예제
다음 예제에서는 uri, uriComponent 및 uriComponentToString를 사용하는 방법을 보여 줍니다.
var uriFormat = uri('http://contoso.com/resources/', 'nested/azuredeploy.json')
var uriEncoded = uriComponent(uriFormat)
output uriOutput string = uriFormat
output componentOutput string = uriEncoded
output toStringOutput string = uriComponentToString(uriEncoded)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| uriOutput | 문자열 | http://contoso.com/resources/nested/azuredeploy.json |
| componentOutput | 문자열 | http%3A%2F%2Fcontoso.com%2Fresources%2Fnested%2Fazuredeploy.json |
| toStringOutput | 문자열 | http://contoso.com/resources/nested/azuredeploy.json |
uriComponent
uricomponent(stringToEncode)
URI를 인코딩합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| stringToEncode | 예 | string | 인코딩할 값입니다. |
반환 값
URI로 인코딩된 값의 문자열입니다.
예제
다음 예제에서는 uri, uriComponent 및 uriComponentToString를 사용하는 방법을 보여 줍니다.
var uriFormat = uri('http://contoso.com/resources/', 'nested/azuredeploy.json')
var uriEncoded = uriComponent(uriFormat)
output uriOutput string = uriFormat
output componentOutput string = uriEncoded
output toStringOutput string = uriComponentToString(uriEncoded)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| uriOutput | 문자열 | http://contoso.com/resources/nested/azuredeploy.json |
| componentOutput | 문자열 | http%3A%2F%2Fcontoso.com%2Fresources%2Fnested%2Fazuredeploy.json |
| toStringOutput | 문자열 | http://contoso.com/resources/nested/azuredeploy.json |
uriComponentToString
uriComponentToString(uriEncodedString)
URI로 인코딩된 값의 문자열을 반환합니다.
네임스페이스: sys.
매개 변수
| 매개 변수 | 필수 | Type | 설명 |
|---|---|---|---|
| uriEncodedString | 예 | string | 문자열로 변환할 URI 인코딩 값입니다. |
반환 값
URI로 인코딩된 값의 디코딩된 문자열입니다.
예제
다음 예제에서는 uri, uriComponent 및 uriComponentToString를 사용하는 방법을 보여 줍니다.
var uriFormat = uri('http://contoso.com/resources/', 'nested/azuredeploy.json')
var uriEncoded = uriComponent(uriFormat)
output uriOutput string = uriFormat
output componentOutput string = uriEncoded
output toStringOutput string = uriComponentToString(uriEncoded)
기본 값을 사용한 이전 예제의 출력은 다음과 같습니다.
| 이름 | 타입 | 값 |
|---|---|---|
| uriOutput | 문자열 | http://contoso.com/resources/nested/azuredeploy.json |
| componentOutput | 문자열 | http%3A%2F%2Fcontoso.com%2Fresources%2Fnested%2Fazuredeploy.json |
| toStringOutput | 문자열 | http://contoso.com/resources/nested/azuredeploy.json |
다음 단계
- Bicep 파일의 섹션에 대한 설명은 Bicep 파일의 구조 및 구문 이해를 참조하세요.
- 리소스 종류를 만들 때 지정된 횟수만큼 반복하려면 Bicep의 반복 루프를 참조하세요.
- 생성한 Bicep 파일을 배포하는 방법을 알아보려면 Bicep 및 Azure PowerShell을 사용하여 리소스 배포를 참조하세요.