Azure IoT Operations에서 데이터 흐름 구성

작업 환경에서 데이터 흐름을 만들려면 데이터 흐름 만들기 데이터 흐름을> 선택합니다. 그런 다음 데이터 흐름에 대한 원본, 변환 및 대상을 구성할 수 있는 페이지가 표시됩니다.

Bicep .bicep 파일을 만들어 데이터 흐름 만들기를 시작합니다. 이 예제에서는 원본, 변환 및 대상 구성을 포함하는 데이터 흐름의 구조를 보여 줍니다.

param aioInstanceName string = '<AIO_INSTANCE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'
param dataflowName string = '<DATAFLOW_NAME>'

resource aioInstance 'Microsoft.IoTOperations/instances@2024-11-01' existing = {
  name: aioInstanceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

resource defaultDataflowEndpoint 'Microsoft.IoTOperations/instances/dataflowEndpoints@2024-11-01' existing = {
  parent: aioInstance
  name: 'default'
}

// Pointer to the default dataflow profile
resource defaultDataflowProfile 'Microsoft.IoTOperations/instances/dataflowProfiles@2024-11-01' existing = {
  parent: aioInstance
  name: 'default'
}

resource dataflow 'Microsoft.IoTOperations/instances/dataflowProfiles/dataflows@2024-11-01' = {
  // Reference to the parent dataflow profile, the default profile in this case
  // Same usage as profileRef in Kubernetes YAML
  parent: defaultDataflowProfile
  name: dataflowName
  extendedLocation: {
    name: customLocation.id
    type: 'CustomLocation'
  }
  properties: {
    mode: 'Enabled'
    operations: [
      {
        operationType: 'Source'
        sourceSettings: {
          // See source configuration section
        }
      }
      // Transformation optional
      {
        operationType: 'BuiltInTransformation'
        builtInTransformationSettings: {
          // See transformation configuration section
        }
      }
      {
        operationType: 'Destination'
        destinationSettings: {
          // See destination configuration section
        }
      }
    ]
  }
}

Kubernetes 매니페스트 .yaml 파일을 만들어 데이터 흐름 만들기를 시작합니다. 이 예제에서는 원본, 변환 및 대상 구성을 포함하는 데이터 흐름의 구조를 보여 줍니다.

apiVersion: connectivity.iotoperations.azure.com/v1
kind: Dataflow
metadata:
  name: <DATAFLOW_NAME>
  namespace: azure-iot-operations
spec:
  # Reference to the default dataflow profile
  # This field is required when configuring via Kubernetes YAML
  # The syntax is different when using Bicep
  profileRef: default 
  mode: Enabled
  operations:
    - operationType: Source
      sourceSettings:
        # See source configuration section
      # Transformation optional
    - operationType: BuiltInTransformation
      builtInTransformationSettings:
        # See transformation configuration section
    - operationType: Destination
      destinationSettings:
        # See destination configuration section

1. 원본 세부 정보에서 MQTT를 선택합니다.

   

2. MQTT 원본에 대해 다음 설정을 입력합니다.

   설정	설명
   MQTT 항목	들어오는 메시지를 구독할 MQTT 토픽 필터입니다. MQTT 또는 Kafka 구성 항목을 참조 하세요.
   메시지 스키마	들어오는 메시지를 역직렬화하는 데 사용할 스키마입니다. 데이터를 역직렬화하려면 스키마 지정을 참조하세요.

3. 적용을 선택합니다.

MQTT 엔드포인트는 Bicep 템플릿 파일에 구성됩니다. 예를 들어 다음 엔드포인트는 데이터 흐름의 원본입니다.

sourceSettings: {
  endpointRef: 'default'
  dataSources: [
    'thermostats/+/telemetry/temperature/#'
    'humidifiers/+/telemetry/humidity/#'
  ]
}

여기서는 dataSources 엔드포인트 구성을 수정할 필요 없이 여러 MQTT 또는 Kafka 토픽을 지정할 수 있습니다. 이러한 유연성은 토픽이 달라도 여러 데이터 흐름에서 동일한 엔드포인트를 다시 사용할 수 있습니다. 자세한 내용은 데이터 원본 구성을 참조 하세요.

예를 들어 MQTT 엔드포인트와 두 개의 MQTT 토픽 필터를 사용하여 원본을 구성하려면 다음 구성을 사용합니다.

sourceSettings:
  endpointRef: default
  dataSources:
    - thermostats/+/telemetry/temperature/#
    - humidifiers/+/telemetry/humidity/#

엔드포인트 구성을 수정하지 않고 MQTT 또는 Kafka 토픽을 지정할 수 있으므로 dataSources 토픽이 다르더라도 여러 데이터 흐름에 엔드포인트를 다시 사용할 수 있습니다. 자세한 내용은 데이터 원본 구성을 참조 하세요.

자산을 데이터 흐름의 원본으로 사용할 수 있습니다. 자산을 원본으로 사용하는 것은 작업 환경에서만 사용할 수 있습니다.

1. 원본 세부 정보에서 자산을 선택합니다.

2. 원본 엔드포인트로 사용할 자산을 선택합니다.

3. 계속을 선택합니다.

   선택한 자산에 대한 데이터 요소 목록이 표시됩니다.

   

4. 적용을 선택하여 자산을 원본 엔드포인트로 사용합니다.

자산을 원본으로 구성하는 작업은 작업 환경에서만 사용할 수 있습니다.

자산을 원본으로 구성하는 작업은 작업 환경에서만 사용할 수 있습니다.

사용자 지정 MQTT 또는 Kafka 엔드포인트를 원본으로 사용하는 것은 현재 작업 환경에서 지원되지 않습니다.

sourceSettings: {
  endpointRef: '<CUSTOM_ENDPOINT_NAME>'
  dataSources: [
    '<TOPIC_1>'
    '<TOPIC_2>'
    // See section on configuring MQTT or Kafka topics for more information
  ]
}

sourceSettings:
  endpointRef: <CUSTOM_ENDPOINT_NAME>
  dataSources:
  - <TOPIC_1>
  - <TOPIC_2>
  # See section on configuring MQTT or Kafka topics for more information

작업 환경 데이터 흐름 원본 세부 정보에서 MQTT를 선택한 다음 MQTT 토픽 필드를 사용하여 들어오는 메시지를 구독할 MQTT 토픽 필터를 지정합니다.

sourceSettings: {
  endpointRef: '<MQTT_ENDPOINT_NAME>'
  dataSources: [
    '<MQTT_TOPIC_FILTER_1>'
    '<MQTT_TOPIC_FILTER_2>'
    // Add more MQTT topic filters as needed
  ]
}

와일드카드가 있는 여러 MQTT 토픽 필터가 있는 예제:

sourceSettings: {
  endpointRef: 'default'
  dataSources: [
    'thermostats/+/telemetry/temperature/#'
    'humidifiers/+/telemetry/humidity/#'
  ]
}

여기서 와일드카드 + 는 항목 아래의 humidifiers 모든 디바이스를 thermostats 선택하는 데 사용됩니다. # 와일드카드는 토픽의 temperature humidity 모든 하위 항목에서 모든 원격 분석 메시지를 선택하는 데 사용됩니다.

sourceSettings:
  endpointRef: <MQTT_ENDPOINT_NAME>
  dataSources:
    - <MQTT_TOPIC_FILTER_1>
    - <MQTT_TOPIC_FILTER_2>
    # Add more MQTT topic filters as needed

와일드카드가 있는 여러 MQTT 토픽 필터가 있는 예제:

sourceSettings:
  endpointRef: default
  dataSources:
    - thermostats/+/telemetry/temperature/#
    - humidifiers/+/telemetry/humidity/#

여기서 와일드카드 + 는 항목 아래의 humidifiers 모든 디바이스를 thermostats 선택하는 데 사용됩니다. # 와일드카드는 토픽의 temperature humidity 모든 하위 항목에서 모든 원격 분석 메시지를 선택하는 데 사용됩니다.

작업 환경 데이터 흐름 원본 세부 정보에서 MQTT를 선택하고 MQTT 토픽 필드를 사용하여 공유 구독 그룹 및 토픽을 지정합니다.

sourceSettings: {
  dataSources: [
    '$shared/<GROUP_NAME>/<TOPIC_FILTER>'
  ]
}

sourceSettings:
  dataSources:
    - $shared/<GROUP_NAME>/<TOPIC_FILTER>

Kafka 엔드포인트를 원본으로 사용하는 것은 현재 작업 환경에서 지원되지 않습니다.

sourceSettings: {
  endpointRef: '<KAFKA_ENDPOINT_NAME>'
  dataSources: [
    '<KAFKA_TOPIC_1>'
    '<KAFKA_TOPIC_2>'
    // Add more Kafka topics as needed
  ]
}

sourceSettings:
  endpointRef: <KAFKA_ENDPOINT_NAME>
  dataSources:
    - <KAFKA_TOPIC_1>
    - <KAFKA_TOPIC_2>
    # Add more Kafka topics as needed

작업 환경 데이터 흐름 원본 세부 정보에서 MQTT를 선택하고 메시지 스키마 필드를 사용하여 스키마를 지정합니다. 업로드 단추를 사용하여 스키마 파일을 먼저 업로드할 수 있습니다. 자세한 내용은 메시지 스키마 이해를 참조하세요.

스키마 레지스트리를 사용하여 스키마를 저장한 후에는 데이터 흐름 구성에서 스키마를 참조할 수 있습니다.

sourceSettings: {
  serializationFormat: 'Json'
  schemaRef: 'aio-sr://<SCHEMA_NAMESPACE>/<SCHEMA_NAME>:<VERSION>'
}

스키마 레지스트리를 사용하여 스키마를 저장한 후에는 데이터 흐름 구성에서 스키마를 참조할 수 있습니다.

sourceSettings:
  serializationFormat: Json
  schemaRef: 'aio-sr://<SCHEMA_NAMESPACE>/<SCHEMA_NAME>:<VERSION>'

작업 환경에서 데이터 흐름>변환 추가(선택 사항)를 선택합니다.

builtInTransformationSettings: {
  datasets: [
    // See section on enriching data
  ]
  filter: [
    // See section on filtering data
  ]
  map: [
    // See section on mapping data
  ]
}

builtInTransformationSettings:
  datasets:
    # See section on enriching data
  filter:
    # See section on filtering data
  map:
    # See section on mapping data

현재 보강 단계는 작업 환경에서 지원되지 않습니다.

이 예제에서는 원본 데이터의 필드를 사용하여 deviceId 데이터 세트의 필드와 asset 일치시킬 수 있는 방법을 보여 줍니다.

builtInTransformationSettings: {
  datasets: [
    {
      key: 'assetDataset'
      inputs: [
        '$source.deviceId' // ---------------- $1
        '$context(assetDataset).asset' // ---- $2
      ]
      expression: '$1 == $2'
    }
  ]
}

예를 들어, 원본 데이터의 deviceId 필드를 사용하여 데이터 세트의 asset 필드와 일치시킬 수 있습니다.

builtInTransformationSettings:
  datasets:
  - key: assetDataset
    inputs:
      - $source.deviceId # ------------- $1
      - $context(assetDataset).asset # - $2
    expression: $1 == $2

1. 변환(선택 사항)에서 필터>추가를 선택합니다.

   

2. 필요한 설정을 입력합니다.

   설정	설명
   필터 조건	원본 데이터의 필드를 기반으로 데이터를 필터링하는 조건입니다.
   설명	필터 조건에 대한 설명을 제공합니다.

   필터 조건 필드에 Ctrl + 공백을 입력 @ 하거나 선택하여 드롭다운에서 데이터 포인트를 선택합니다.

   형식 @$metadata.user_properties.<property> 을 사용하여 MQTT 메타데이터 속성을 입력할 수 있습니다 @$metadata.topic. 형식 @$metadata.<header>을 사용하여 $metadata 헤더를 입력할 수도 있습니다. 구문은 $metadata 메시지 헤더의 일부인 MQTT 속성에만 필요합니다. 자세한 내용은 필드 참조를 참조 하세요.

   조건은 원본 데이터의 필드를 사용할 수 있습니다. 예를 들어 온도 필드를 기준으로 20보다 작거나 같은 데이터를 필터링하는 필터 @temperature > 20 조건을 사용할 수 있습니다.

3. 적용을 선택합니다.

예를 들어, 원본 데이터의 temperature 필드를 사용하여 데이터를 필터링할 수 있습니다.

builtInTransformationSettings: {
  filter: [
    {
      inputs: [
        'temperature ? $last'
      ]
      expression: '$1 > 20'
    }
  ]
}

temperature 필드가 20보다 큰 경우, 데이터는 다음 단계로 전달됩니다. temperature 필드가 20보다 작거나 같으면 데이터가 필터링됩니다.

예를 들어, 원본 데이터의 temperature 필드를 사용하여 데이터를 필터링할 수 있습니다.

builtInTransformationSettings:
  filter:
    - inputs:
      - temperature ? $last # - $1
      expression: "$1 > 20"

temperature 필드가 20보다 큰 경우, 데이터는 다음 단계로 전달됩니다. temperature 필드가 20보다 작거나 같으면 데이터가 필터링됩니다.

작업 환경에서는 현재 컴퓨팅, 이름 바꾸기 및 새 속성 변환을 사용하여 매핑이 지원됩니다.

Compute

컴퓨팅 변환을 사용하여 원본 데이터에 수식을 적용할 수 있습니다. 이 작업은 원본 데이터에 수식을 적용하고 결과 필드를 저장하는 데 사용됩니다.

1. 변환(선택 사항)에서 컴퓨팅 추가를>선택합니다.

   

2. 필요한 설정을 입력합니다.

   설정	설명
   수식 선택	드롭다운에서 기존 수식을 선택하거나 사용자 지정을 선택하여 수식을 수동으로 입력합니다.
   출력	결과의 출력 표시 이름을 지정합니다.
   수식	원본 데이터에 적용할 수식을 입력합니다.
   설명	변환에 대한 설명을 제공합니다.
   마지막으로 알려진 값	필요에 따라 현재 값을 사용할 수 없는 경우 마지막으로 알려진 값을 사용합니다.

   수식 필드에 수식을 입력하거나 편집할 수 있습니다. 수식은 원본 데이터의 필드를 사용할 수 있습니다. 드롭다운에서 데이터 포인트를 선택하려면 Ctrl+스페이스바를 입력 @ 하거나 선택합니다.

   형식 @$metadata.user_properties.<property> 을 사용하여 MQTT 메타데이터 속성을 입력할 수 있습니다 @$metadata.topic. 형식 @$metadata.<header>을 사용하여 $metadata 헤더를 입력할 수도 있습니다. 구문은 $metadata 메시지 헤더의 일부인 MQTT 속성에만 필요합니다. 자세한 내용은 필드 참조를 참조 하세요.

   수식은 원본 데이터의 필드를 사용할 수 있습니다. 예를 들어 원본 데이터의 필드를 사용하여 temperature 온도를 섭씨로 변환하고 출력 필드에 저장할 수 있습니다 temperatureCelsius .

3. 적용을 선택합니다.

이름 바꾸기

이름 바꾸기 변환을 사용하여 데이터 포인트의 이름을 바꿀 수 있습니다. 이 작업은 원본 데이터의 데이터 포인트 이름을 새 이름으로 바꾸는 데 사용됩니다. 새 이름은 데이터 흐름의 후속 단계에서 사용할 수 있습니다.

1. 변환(선택 사항)에서 추가 이름 바꾸기>를 선택합니다.

   

2. 필요한 설정을 입력합니다.

   설정	설명
   데이터 포인트	드롭다운에서 데이터 포인트를 선택하거나 $metadata 헤더를 입력합니다.
   새 데이터 포인트 이름	데이터 포인트의 새 이름을 입력합니다.
   설명	변환에 대한 설명을 제공합니다.

   드롭다운에서 데이터 포인트를 선택하려면 Ctrl+스페이스바를 입력 @ 하거나 선택합니다.

   형식 @$metadata.user_properties.<property> 을 사용하여 MQTT 메타데이터 속성을 입력할 수 있습니다 @$metadata.topic. 형식 @$metadata.<header>을 사용하여 $metadata 헤더를 입력할 수도 있습니다. 구문은 $metadata 메시지 헤더의 일부인 MQTT 속성에만 필요합니다. 자세한 내용은 필드 참조를 참조 하세요.

3. 적용을 선택합니다.

새 속성

New 속성 변환을 사용하여 원본 데이터에 새 속성을 추가할 수 있습니다. 이 작업은 원본 데이터에 새 속성을 추가하는 데 사용됩니다. 새 속성은 데이터 흐름의 후속 단계에서 사용할 수 있습니다.

1. 변환(선택 사항)에서 새 속성>추가를 선택합니다.

   

2. 필요한 설정을 입력합니다.

   설정	설명
   속성 키	새 속성의 키를 입력합니다.
   속성 값	새 속성의 값을 입력합니다.
   설명	새 속성에 대한 설명을 제공합니다.

3. 적용을 선택합니다.

형식 $metadata.user_properties.<property> 을 사용하여 MQTT 메타데이터 속성에 액세스할 수 있습니다 $metadata.topic. 형식 $metadata.<header>을 사용하여 $metadata 헤더를 입력할 수도 있습니다. 자세한 내용은 필드 참조를 참조 하세요.

예를 들어, 원본 데이터의 temperature 필드를 사용하여 온도를 섭씨로 변환하고 temperatureCelsius 필드에 저장할 수 있습니다. 또한 컨텍스트화 데이터 세트의 location 필드를 사용하여 원본 데이터를 보강할 수도 있습니다.

builtInTransformationSettings: {
  map: [
    {
      inputs: [
        'temperature'
      ]
      output: 'temperatureCelsius'
      expression: '($1 - 32) * 5/9'
    }
    {
      inputs: [
        '$context(assetDataset).location'
      ]
      output: 'location'
    }
  ]
}

형식 $metadata.user_properties.<property> 을 사용하여 MQTT 메타데이터 속성에 액세스할 수 있습니다 $metadata.topic. 형식 $metadata.<header>을 사용하여 $metadata 헤더를 입력할 수도 있습니다. 자세한 내용은 필드 참조를 참조 하세요.

예를 들어, 원본 데이터의 temperature 필드를 사용하여 온도를 섭씨로 변환하고 temperatureCelsius 필드에 저장할 수 있습니다. 또한 컨텍스트화 데이터 세트의 location 필드를 사용하여 원본 데이터를 보강할 수도 있습니다.

builtInTransformationSettings:
  map:
    - inputs:
      - temperature # - $1
      expression: "($1 - 32) * 5/9"
      output: temperatureCelsius
    - inputs:
      - $context(assetDataset).location  
      output: location

작업 환경의 경우 데이터 흐름 엔드포인트 세부 정보에서 스키마 및 serialization 형식을 지정합니다. serialization 형식을 지원하는 엔드포인트는 Microsoft Fabric OneLake, Azure Data Lake Storage Gen 2 및 Azure Data Explorer입니다. 예를 들어 델타 형식으로 데이터를 직렬화하려면 스키마 레지스트리에 스키마를 업로드하고 데이터 흐름 대상 엔드포인트 구성에서 참조해야 합니다.

스키마 레지스트리에 스키마를 업로드한 후에는 데이터 흐름 구성에서 스키마를 참조할 수 있습니다.

builtInTransformationSettings: {
  serializationFormat: 'Delta'
  schemaRef: 'aio-sr://<SCHEMA_NAMESPACE>/<SCHEMA>:<VERSION>'
}

스키마 레지스트리에 스키마를 업로드한 후에는 데이터 흐름 구성에서 스키마를 참조할 수 있습니다.

builtInTransformationSettings:
  serializationFormat: Delta
  schemaRef: 'aio-sr://<SCHEMA_NAMESPACE>/<SCHEMA>:<VERSION>'

1. 대상으로 사용할 데이터 흐름 엔드포인트를 선택합니다.

   

   스토리지 엔드포인트에는 serialization을 위한 스키마가 필요합니다. Microsoft Fabric OneLake, Azure Data Lake Storage, Azure Data Explorer 또는 로컬 스토리지 대상 엔드포인트를 선택하는 경우 스키마 참조를 지정해야 합니다. 예를 들어 데이터를 델타 형식으로 Microsoft Fabric 엔드포인트로 직렬화하려면 스키마 레지스트리에 스키마를 업로드하고 데이터 흐름 대상 엔드포인트 구성에서 참조해야 합니다.

   

2. [진행]을 선택하여 대상을 구성합니다.

3. 데이터를 보낼 토픽 또는 테이블을 포함하여 대상에 필요한 설정을 입력합니다. 자세한 내용은 데이터 대상 구성(토픽, 컨테이너 또는 테이블)을 참조하세요.

destinationSettings: {
  endpointRef: '<CUSTOM_ENDPOINT_NAME>'
  dataDestination: '<TOPIC_OR_TABLE>' // See section on configuring data destination
}

destinationSettings:
  endpointRef: <CUSTOM_ENDPOINT_NAME>
  dataDestination: <TOPIC_OR_TABLE> # See section on configuring data destination

작업 환경을 사용하는 경우 데이터 대상 필드는 엔드포인트 유형에 따라 자동으로 해석됩니다. 예를 들어 데이터 흐름 엔드포인트가 스토리지 엔드포인트인 경우 대상 세부 정보 페이지에서 컨테이너 이름을 입력하라는 메시지를 표시합니다. 데이터 흐름 엔드포인트가 MQTT 엔드포인트인 경우 대상 세부 정보 페이지에서 토픽을 입력하라는 메시지를 표시합니다.

구문은 모든 데이터 흐름 엔드포인트에 대해 동일합니다.

destinationSettings: {
  endpointRef: "<CUSTOM_ENDPOINT_NAME>"
  dataDestination: '<TOPIC_OR_TABLE>'
}

예를 들어 정적 MQTT 토픽을 로컬 MQTT 브로커로 다시 보내려면 다음 구성을 사용합니다.

destinationSettings: {
  endpointRef: 'default'
  dataDestination: 'example-topic'
}

또는 사용자 지정 이벤트 허브 엔드포인트가 있는 경우 구성은 다음과 같습니다.

destinationSettings: {
  endpointRef: 'my-eh-endpoint'
  dataDestination: 'individual-event-hub'
}

스토리지 엔드포인트를 대상으로 사용하는 또 다른 예:

destinationSettings: {
  endpointRef: 'my-adls-endpoint'
  dataDestination: 'my-container'
}

구문은 모든 데이터 흐름 엔드포인트에 대해 동일합니다.

destinationSettings:
  endpointRef: <CUSTOM_ENDPOINT_NAME>
  dataDestination: <TOPIC_OR_TABLE>

예를 들어 정적 MQTT 토픽을 로컬 MQTT 브로커로 다시 보내려면 다음 구성을 사용합니다.

destinationSettings:
  endpointRef: default
  dataDestination: example-topic

또는 사용자 지정 이벤트 허브 엔드포인트가 있는 경우 구성은 다음과 같습니다.

destinationSettings:
  endpointRef: my-eh-endpoint
  dataDestination: individual-event-hub

스토리지 엔드포인트를 대상으로 사용하는 또 다른 예:

destinationSettings:
  endpointRef: my-adls-endpoint
  dataDestination: my-container

구성 예제는 Bicep 또는 Kubernetes 탭을 참조하세요.

param aioInstanceName string = '<AIO_INSTANCE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'
param dataflowName string = '<DATAFLOW_NAME>'

resource aioInstance 'Microsoft.IoTOperations/instances@2024-11-01' existing = {
  name: aioInstanceName
}

resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}

// Pointer to the default dataflow endpoint
resource defaultDataflowEndpoint 'Microsoft.IoTOperations/instances/dataflowEndpoints@2024-11-01' existing = {
  parent: aioInstance
  name: 'default'
}

// Pointer to the default dataflow profile
resource defaultDataflowProfile 'Microsoft.IoTOperations/instances/dataflowProfiles@2024-11-01' existing = {
  parent: aioInstance
  name: 'default'
}

resource dataflow 'Microsoft.IoTOperations/instances/dataflowProfiles/dataflows@2024-11-01' = {
  // Reference to the parent dataflow profile, the default profile in this case
  // Same usage as profileRef in Kubernetes YAML
  parent: defaultDataflowProfile
  name: dataflowName
  extendedLocation: {
    name: customLocation.id
    type: 'CustomLocation'
  }
  properties: {
    mode: 'Enabled'
    operations: [
      {
        operationType: 'Source'
        sourceSettings: {
          // Use the default MQTT endpoint as the source
          endpointRef: defaultDataflowEndpoint.name
          // Filter the data from the MQTT topic azure-iot-operations/data/thermostat
          dataSources: [
            'azure-iot-operations/data/thermostat'
          ]
        }
      }
      // Transformation optional
      {
        operationType: 'BuiltInTransformation'
        builtInTransformationSettings: {
          // Filter the data where temperature * "Tag 10" < 100000
          filter: [
            {
              inputs: [
                'temperature.Value'
                '"Tag 10".Value'
              ]
              expression: '$1 * $2 < 100000'
            }
          ]
          map: [
            // Passthrough all values by default
            {
              inputs: [
                '*'
              ]
              output: '*'
            }
            // Convert temperature to Fahrenheit and output it to TemperatureF
            {
              inputs: [
                'temperature.Value'
              ]
              output: 'TemperatureF'
              expression: 'cToF($1)'
            }
          // Extract the "Tag 10" value and output it to Humidity
            {
              inputs: [
                '"Tag 10".Value'
              ]
              output: 'Humidity'
            }
          ]
        }
      }
      {
        operationType: 'Destination'
        destinationSettings: {
          // Use the default MQTT endpoint as the destination
          endpointRef: defaultDataflowEndpoint.name
          // Send the data to the MQTT topic factory
          dataDestination: 'factory'
        }
      }
    ]
  }
}

apiVersion: connectivity.iotoperations.azure.com/v1
kind: Dataflow
metadata:
  name: my-dataflow
  namespace: azure-iot-operations
spec:
  # Reference to the default dataflow profile
  profileRef: default
  mode: Enabled
  operations:
    - operationType: Source
      sourceSettings:
        # Use the default MQTT endpoint as the source
        endpointRef: default
        # Filter the data from the MQTT topic azure-iot-operations/data/thermostat
        dataSources:
          - azure-iot-operations/data/thermostat
    # Transformation optional
    - operationType: builtInTransformation
      builtInTransformationSettings:
        # Filter the data where temperature * "Tag 10" < 100000
        filter:
          - inputs:
              - 'temperature.Value'
              - '"Tag 10".Value'
            expression: '$1 * $2 < 100000'
        map:
          # Passthrough all values by default
          - inputs:
              - '*'
            output: '*'
          # Convert temperature to Fahrenheit and output it to TemperatureF
          - inputs:
              - temperature.Value
            output: TemperatureF
            expression: cToF($1)
          # Extract the "Tag 10" value and output it to Humidity
          - inputs:
              - '"Tag 10".Value'
            output: 'Humidity'
    - operationType: Destination
      destinationSettings:
        # Use the default MQTT endpoint as the destination
        endpointRef: default
        # Send the data to the MQTT topic factory
        dataDestination: factory

내보낼 데이터 흐름을 선택하고 도구 모음에서 내보내기를 선택합니다.

Bicep은 코드로서의 인프라이며 내보내기가 필요하지 않습니다. Bicep 템플릿 파일을 사용하여 데이터 흐름을 빠르게 설정하고 구성하는 데이터 흐름을 만듭니다.

kubectl get dataflow my-dataflow -o yaml > my-dataflow.yaml