CA2224: 같음 연산자를 오버로드할 때 Equals를 재정의하세요

원인

퍼블릭 형식은 같음 연산자를 구현하지만 System.Object.Equals를 재정의하지 않습니다.

규칙 설명

같음 연산자는 구문상 편리하게 Equals 메서드 기능에 액세스하는 방법입니다. 같음 연산자를 구현하는 경우 해당 논리는 Equals의 논리와 동일해야 합니다.

위반 문제를 해결하는 방법

이 규칙 위반 문제를 해결하려면 같음 연산자의 구현을 제거하거나 Equals를 재정의하고 두 메서드가 같은 값을 반환해야 합니다. 같음 연산자에서 일관되지 않은 동작을 도입하지 않는 경우 기본 클래스의 Equals메서드를 호출하는 Equals의 구현을 제공하여 위반을 해결할 수 있습니다.

경고를 표시하지 않는 경우

같음 연산자가 Equals의 상속된 구현과 동일한 값을 반환하는 경우에는 이 규칙에서 경고를 표시하지 않아도 됩니다. 이 문서의 예제에는 이 규칙에서 경고를 안전하게 표시하지 않을 수 있는 형식이 포함되어 있습니다.

경고 표시 안 함

단일 위반만 표시하지 않으려면 원본 파일에 전처리기 지시문을 추가하여 규칙을 사용하지 않도록 설정한 후 다시 사용하도록 설정합니다.

#pragma warning disable CA2224
// The code that's violating the rule is on this line.
#pragma warning restore CA2224

파일, 폴더 또는 프로젝트에 대한 규칙을 사용하지 않도록 설정하려면 구성 파일에서 심각도를 none으로 설정합니다.

[*.{cs,vb}]
dotnet_diagnostic.CA2224.severity = none

자세한 내용은 방법: 코드 분석 경고 표시 안 함을 참조하세요.

예시

다음 예제에서는 이 규칙을 위반하는 클래스(참조 형식)를 보여 줍니다.

' This class violates the rule.
Public Class Point

    Public Property X As Integer
    Public Property Y As Integer

    Public Sub New(x As Integer, y As Integer)
        Me.X = x
        Me.Y = y
    End Sub

    Public Overrides Function GetHashCode() As Integer
        Return HashCode.Combine(X, Y)
    End Function

    Public Shared Operator =(pt1 As Point, pt2 As Point) As Boolean
        If pt1 Is Nothing OrElse pt2 Is Nothing Then
            Return False
        End If

        If pt1.GetType() <> pt2.GetType() Then
            Return False
        End If

        Return pt1.X = pt2.X AndAlso pt1.Y = pt2.Y
    End Operator

    Public Shared Operator <>(pt1 As Point, pt2 As Point) As Boolean
        Return Not pt1 = pt2
    End Operator

End Class

다음 예에서는 System.Object.Equals를 재정의하여 위반을 수정합니다.

' This class satisfies the rule.
Public Class Point

    Public Property X As Integer
    Public Property Y As Integer

    Public Sub New(x As Integer, y As Integer)
        Me.X = x
        Me.Y = y
    End Sub

    Public Overrides Function GetHashCode() As Integer
        Return HashCode.Combine(X, Y)
    End Function

    Public Overrides Function Equals(obj As Object) As Boolean

        If obj = Nothing Then
            Return False
        End If

        If [GetType]() <> obj.GetType() Then
            Return False
        End If

        Dim pt As Point = CType(obj, Point)

        Return X = pt.X AndAlso Y = pt.Y

    End Function

    Public Shared Operator =(pt1 As Point, pt2 As Point) As Boolean
        ' Object.Equals calls Point.Equals(Object).
        Return Object.Equals(pt1, pt2)
    End Operator

    Public Shared Operator <>(pt1 As Point, pt2 As Point) As Boolean
        ' Object.Equals calls Point.Equals(Object).
        Return Not Object.Equals(pt1, pt2)
    End Operator

End Class

관련 규칙

• CA1046: 참조 형식에 같음 연산자를 오버로드하지 마십시오.
• CA2218: Equals를 재정의할 때 GetHashCode를 재정의하십시오.
• CA2225: 연산자 오버로드에는 명명된 대체 항목이 있습니다.
• CA2226: 연산자에는 대칭 오버로드가 있어야 합니다.
• CA2231: ValueType.Equals를 재정의할 때 같음 연산자를 오버로드하십시오.

참고 항목

• CS0660