다음을 통해 공유

series_clean_anomalies_fl()

  • 아티클

적용 대상: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

계열에서 비정상적인 점을 정리합니다.

이 함수 series_clean_anomalies_fl() 는 동적 숫자 배열을 입력으로 사용하고 변칙의 또 다른 숫자 배열을 사용하고 입력 배열의 변칙을 인접 지점의 보간된 값으로 대체하는 UDF(사용자 정의 함수) 입니다.

구문

series_clean_anomalies_fl(, y_series 변칙)

구문 규칙에 대해 자세히 알아봅니다.

매개 변수

이름 Type 필수 설명
y_series dynamic ✔️ 숫자 값의 입력 배열입니다.
예외 dynamic ✔️ 보통 점의 경우 0 또는 비정상 점의 다른 값을 포함하는 변칙 배열입니다.

함수 정의

다음과 같이 해당 코드를 쿼리 정의 함수로 포함하거나 데이터베이스에 저장된 함수로 만들어 함수를 정의할 수 있습니다.

다음 let 문을 사용하여 함수를 정의합니다. 사용 권한이 필요 없습니다.

Important

let 문은 자체적으로 실행할 수 없습니다. 그 뒤에 테이블 형식 식 문이 있어야 합니다. 작업 예제 series_clean_anomalies_fl()를 실행하려면 예제를 참조 하세요.

let series_clean_anomalies_fl = (y_series:dynamic, anomalies:dynamic)
{
    let fnum = array_iff(series_not_equals(anomalies, 0), real(null), y_series);  //  replace anomalies with null values
    series_fill_linear(fnum)
};
// Write your query to use the function here.

예시

쿼리 정의 함수를 사용하려면 포함된 함수 정의 후에 호출합니다.

let series_clean_anomalies_fl = (y_series:dynamic, anomalies:dynamic)
{
    let fnum = array_iff(series_not_equals(anomalies, 0), real(null), y_series);  //  replace anomalies with null values
    series_fill_linear(fnum)
}
;
let min_t = datetime(2016-08-29);
let max_t = datetime(2016-08-31);
demo_make_series1
| make-series num=count() on TimeStamp from min_t to max_t step 20m by OsVer
| extend anomalies = series_decompose_anomalies(num, 0.8)
| extend num_c = series_clean_anomalies_fl(num, anomalies)
| render anomalychart with (anomalycolumns=anomalies)

출력

정리 전후에 변칙이 있는 시계열의 그래프입니다.