다음을 통해 공유

series_dot_product_fl()

  • 아티클

적용 대상: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

두 숫자 벡터의 점 곱을 계산합니다.

이 함수 series_dot_product_fl() 는 두 개의 동적 숫자 배열이 포함된 식을 입력으로 사용하고 점 곱을 계산하는 UDF(사용자 정의 함수)입니다.

참고 항목

이 문서에 설명된 함수 대신 네이티브 함수 series_dot_product() 를 사용합니다. 네이티브 함수는 동일한 기능을 제공하며 성능 및 확장성을 위해 더 좋습니다. 이 문서는 참조용으로만 제공됩니다.

구문

series_dot_product_fl(vec1, vec2)

구문 규칙에 대해 자세히 알아봅니다.

매개 변수

이름 Type 필수 설명
vec1 dynamic ✔️ 숫자 값의 배열입니다.
vec2 dynamic ✔️ vec1과 길이가 같은 숫자 값의 배열입니다.

함수 정의

다음과 같이 해당 코드를 쿼리 정의 함수로 포함하거나 데이터베이스에 저장된 함수로 만들어 함수를 정의할 수 있습니다.

다음 let 문을 사용하여 함수를 정의합니다. 사용 권한이 필요 없습니다.

Important

let 문은 자체적으로 실행할 수 없습니다. 그 뒤에 테이블 형식 식 문이 있어야 합니다. 작업 예제 series_dot_product_fl()를 실행하려면 예제를 참조 하세요.

let series_dot_product_fl=(vec1:dynamic, vec2:dynamic)
{
    let elem_prod = series_multiply(vec1, vec2);
    let cum_sum = series_iir(elem_prod, dynamic([1]), dynamic([1,-1]));
    todouble(cum_sum[-1])
};
// Write your query to use the function here.

예시

쿼리 정의 함수를 사용하려면 포함된 함수 정의 후에 호출합니다.

let series_dot_product_fl=(vec1:dynamic, vec2:dynamic)
{
    let elem_prod = series_multiply(vec1, vec2);
    let cum_sum = series_iir(elem_prod, dynamic([1]), dynamic([1,-1]));
    todouble(cum_sum[-1])
};
union
(print 1 | project v1=range(1, 3, 1), v2=range(4, 6, 1)),
(print 1 | project v1=range(11, 13, 1), v2=range(14, 16, 1))
| extend v3=series_dot_product_fl(v1, v2)

출력

사용자 정의 함수 series_dot_product_fl 사용하여 2개의 벡터의 점 곱 결과를 보여 주는 표입니다.