series_exp_smoothing_fl()
적용 대상: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel
기본 지수 평활화 필터를 계열에 적용합니다.
이 함수 series_exp_smoothing_fl() 는 동적 숫자 배열이 포함된 식을 입력으로 사용하고 기본 지수 평활 필터를 적용하는 UDF(사용자 정의 함수)입니다.
구문
series_exp_smoothing_fl( y_series [, alpha ])
구문 규칙에 대해 자세히 알아봅니다.
매개 변수
| 이름 | Type | 필수 | 설명 |
|---|---|---|---|
| y_series | dynamic |
✔️ | 숫자 값의 배열 셀입니다. |
| 알파 | real |
마지막 점의 가중치와 이전 점의 가중치를 지정하는 [0-1] 범위의 값입니다 1 - alpha. 기본값은 0.5입니다. |
함수 정의
다음과 같이 해당 코드를 쿼리 정의 함수로 포함하거나 데이터베이스에 저장된 함수로 만들어 함수를 정의할 수 있습니다.
다음 let 문을 사용하여 함수를 정의합니다. 사용 권한이 필요 없습니다.
Important
let 문은 자체적으로 실행할 수 없습니다. 그 뒤에 테이블 형식 식 문이 있어야 합니다. 작업 예제 series_exp_smoothing_fl()를 실행하려면 예제를 참조 하세요.
let series_exp_smoothing_fl = (y_series:dynamic, alpha:double=0.5)
{
series_iir(y_series, pack_array(alpha), pack_array(1, alpha-1))
};
// Write your query to use the function here.
예시
쿼리 정의 함수를 사용하려면 포함된 함수 정의 후에 호출합니다.
let series_exp_smoothing_fl = (y_series:dynamic, alpha:double=0.5)
{
series_iir(y_series, pack_array(alpha), pack_array(1, alpha-1))
};
range x from 1 to 50 step 1
| extend y = x % 10
| summarize x = make_list(x), y = make_list(y)
| extend exp_smooth_y = series_exp_smoothing_fl(y, 0.4)
| render linechart
출력
