연습: 각 Windows Form을 별개의 스레드에서 표시하여 COM Interop 지원

아티클
08/09/2011

Application.Run 메서드를 사용하여 만들어지는 .NET Framework 메시지 루프에 폼을 표시하여 COM 상호 운용성 문제를 해결할 수 있습니다.

COM 클라이언트 응용 프로그램에서 Windows Form이 올바르게 작동하도록 하려면 응용 프로그램을 Windows Forms 메시지 루프에서 실행해야 합니다. 이렇게 하려면 다음 방법 중 하나를 사용합니다.

Form.ShowDialog 메서드를 사용하여 Windows Form을 표시합니다. 자세한 내용은 방법: ShowDialog 메서드로 Windows Form을 표시하여 COM Interop 지원을 참조하십시오.
각 Windows Form을 별도의 스레드에서 표시합니다.

다음 절차에서는 별도의 스레드에서 Windows Form을 표시하는 방법을 보여 줍니다.

이 항목의 코드를 단일 목록으로 복사하려면 방법: 각 Windows Form을 별개의 스레드에서 표시하여 COM Interop 지원을 참조하십시오.

절차

폼을 별도의 스레드에 배치한 다음 Application.Run 메서드를 호출하여 해당 스레드에서 Windows Forms 메시지 펌프를 시작합니다. 이 방법을 사용하려면 Invoke 메서드를 사용하여 관리되지 않는 응용 프로그램에서 폼에 대한 모든 호출을 마샬링해야 합니다.

이 방법을 수행하려면 폼의 각 인스턴스가 자체 메시지 루프를 사용하여 자체 스레드에서 실행되어야 합니다. 한 스레드에서 한 개의 메시지 루프만 실행할 수 있습니다. 그러므로 클라이언트 응용 프로그램의 메시지 루프를 변경할 수 없습니다. 그러나 .NET Framework 구성 요소를 수정하여 자체 메시지 루프를 사용하는 새 스레드를 시작할 수 있습니다.

각 Windows Form 인스턴스를 새 스레드에서 만들려면

새 클래스 라이브러리 프로젝트를 만들고 이름을 COMWinform으로 지정합니다.
기본 Class1.vb 파일을 삭제합니다.
프로젝트 메뉴에서 클래스 추가를 클릭합니다.
COM 클래스 템플릿을 선택합니다.
이름 상자에 COMForm.vb를 입력한 다음 추가를 클릭합니다.
다음 코드 문을 COMForm 파일의 위쪽, 클래스 정의 앞에 붙여넣습니다.
```
Imports System.Windows.Forms
Imports System.Runtime.InteropServices
```

COMForm 클래스 정의에서 생성자 정의 아래에 다음 코드를 붙여넣습니다.

Private WithEvents frmManager As FormManager

Public Sub ShowForm1()
    ' Call the StartForm method by using a new instance
    ' of the Form1 class.
    StartForm(New Form1)
End Sub

Private Sub StartForm(ByVal frm As Form)

    ' This procedure is used to show all forms
    ' that the client application requests. When the first form
    ' is displayed, this code will create a new message
    ' loop that runs on a new thread. The new form will
    ' be treated as the main form.

    ' Later forms will be shown on the same message loop.
    If IsNothing(frmManager) Then
        frmManager = New FormManager(frm)
    Else
        frmManager.ShowForm(frm)
    End If
End Sub

Private Sub frmManager_MessageLoopExit() _
Handles frmManager.MessageLoopExit

    'Release the reference to the frmManager object.
    frmManager = Nothing

End Sub

프로젝트 메뉴에서 클래스 추가를 클릭하고 클래스 템플릿을 선택합니다.
이름 상자에 FormManager.vb를 입력한 다음 추가를 클릭합니다.

FormManager 파일의 내용을 다음 코드로 변경합니다.

Imports System.Runtime.InteropServices
Imports System.Threading
Imports System.Windows.Forms

<ComVisible(False)> _
Friend Class FormManager
    ' This class is used so that you can generically pass any
    ' form that you want to the delegate.

    Private WithEvents appContext As ApplicationContext
    Private Delegate Sub FormShowDelegate(ByVal form As Form)
    Event MessageLoopExit()

    Public Sub New(ByVal MainForm As Form)
        Dim t As Thread
        If IsNothing(appContext) Then
            appContext = New ApplicationContext(MainForm)
            t = New Thread(AddressOf StartMessageLoop)
            t.IsBackground = True
            t.SetApartmentState(ApartmentState.STA)
            t.Start()
        End If
    End Sub

    Private Sub StartMessageLoop()
        ' Call the Application.Run method to run the form on its own message loop.
        Application.Run(appContext)
    End Sub

    Public Sub ShowForm(ByVal form As Form)

        Dim formShow As FormShowDelegate

        ' Start the main form first. Otherwise, focus will stay on the 
        ' calling form.
        appContext.MainForm.Activate()

        ' Create a new instance of the FormShowDelegate method, and
        ' then invoke the delegate off the MainForm object.
        formShow = New FormShowDelegate( _
        AddressOf ShowFormOnMainForm_MessageLoop)

        appContext.MainForm.Invoke(formShow, New Object() {form})
    End Sub

    Private Sub ShowFormOnMainForm_MessageLoop(ByVal form As Form)
        form.Show()
    End Sub

    Private Sub ac_ThreadExit( _
    ByVal sender As Object, _
    ByVal e As System.EventArgs) _
    Handles appContext.ThreadExit
        appContext.MainForm.Dispose()
        appContext.MainForm = Nothing
        appContext.Dispose()
        appContext = Nothing
        RaiseEvent MessageLoopExit()
    End Sub
End Class

프로젝트 메뉴에서 Windows Form 추가를 클릭한 다음 추가를 클릭합니다.
폼에 일부 TextBox 컨트롤과 Button 컨트롤을 추가합니다.
Button1을 두 번 클릭하여 Click 이벤트 처리기를 추가합니다.

Click 이벤트 처리기에 다음 코드를 추가합니다.

Private Sub Button1_Click( _
ByVal sender As System.Object, _
ByVal e As System.EventArgs) _
Handles Button1.Click
    MessageBox.Show("Clicked button")
End Sub

솔루션을 빌드합니다.

또한 이 단계에서는 COM interop 프로젝트를 이 컴퓨터에 등록합니다.

COM interop를 보여 주는 실행 파일을 만들려면

Microsoft Visual Basic 6.0을 시작합니다.
새 표준 EXE 프로젝트를 만듭니다.
프로젝트 메뉴에서 참조를 클릭합니다.
Visual Basic 2005 솔루션을 빌드할 때 생성된 COMWinform 형식 라이브러리에 참조를 추가합니다.

또는

해당 라이브러리가 목록에 없으면 찾아보기를 클릭하여 형식 라이브러리 파일(.tlb)을 직접 찾습니다.
폼에 단추를 추가합니다.
보기 메뉴에서 코드를 클릭하고 다음 코드를 폼 모듈에 추가합니다.

[Visual Basic]

Option Explicit

Private Sub Command1_Click()
    Dim frm As COMWinform.COMForm
    Set frm = New COMWinform.COMForm
    frm.ShowForm1
End Sub

파일 메뉴에서 EXE 만들기를 클릭하여 프로젝트를 컴파일합니다.
컴파일된 Visual Basic 6.0 실행 파일을 실행합니다.
단추를 클릭하여 앞에서 만든 클래스 라이브러리의 Windows Form을 표시합니다.
Windows Form의 TextBox 컨트롤 중 하나에 포커스를 설정한 다음 Tab 키를 눌러 컨트롤 사이를 이동합니다.

Tab 키를 누르면 컨트롤에서 컨트롤로 포커스가 이동하고 Enter 키를 누르면 단추의 Click 이벤트가 발생합니다.