연습 - 매개 변수 및 데코레이터 추가

• 8분

HR 애플리케이션 마이그레이션의 일환으로 Azure 리소스를 배포하는 Bicep 템플릿을 만듭니다. 이 연습에서는 Azure App Service 요금제와 App Service 앱을 만듭니다. 예상하는 값이 항상 포함되도록 각 매개 변수에 데코레이터를 적용합니다.

프로세스 중에 다음 작업을 수행합니다.

이 연습에서는 Visual Studio Code용 Bicep 확장을 사용합니다. Visual Studio Code에서 해당 확장을 설치해야 합니다.

매개 변수를 사용하여 Bicep 템플릿 만들기

1. Visual Studio Code를 엽니다.

2. main.bicep이라는 새 파일을 만듭니다.

3. Visual Studio Code에서 Bicep 도구가 로드되도록 빈 파일을 저장합니다.

   파일>다른 이름으로 저장을 선택해도 되고 Windows에서 Ctrl+S(macOS는 ⌘+S) 키를 눌러도 됩니다. 파일을 저장한 위치를 기억해야 합니다. 예를 들어 파일을 저장할 scripts 폴더를 만들 수 있습니다.

4. 파일에 다음 내용을 추가합니다. 조금 뒤에 템플릿을 배포할 것입니다. 도구가 Bicep 파일을 작성하는 데 어떻게 도움이 되는지 확인할 수 있도록 복사하여 붙여넣지 말고 직접 입력합니다.

   param environmentName string = 'dev'
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   param appServicePlanInstanceCount int = 1
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   param location string = 'eastus'
   
   var appServicePlanName = '${environmentName}-${solutionName}-plan'
   var appServiceAppName = '${environmentName}-${solutionName}-app'
   

   여기서는 여러 매개 변수를 만들고 형식을 혼합해서 사용합니다. 각 매개 변수의 기본값을 정의합니다. 일부 기본값에는 문자열 보간 및 uniqueString() 함수가 포함됩니다.

   팁

   uniqueString() 함수는 전역적으로 고유한 리소스 이름을 만들 때 유용합니다. 동일한 리소스 그룹에 배포할 때마다 동일한 문자열을 반환하지만, 다른 리소스 그룹이나 구독에 배포할 때는 다른 문자열을 반환합니다.

   또한 Azure App Service 요금제와 App Service 앱의 이름을 구성하는 변수도 정의합니다. 그러한 값에는 지정한 일부 매개 변수가 포함됩니다. 매개 변수 값은 배포를 실행하는 사용자가 재정의할 수 있지만 변수 값은 재정의할 수 없습니다.

   팁

   location 매개 변수를 westus3로 설정하도록 지정합니다. 일반적으로 resourceGroup().location 속성을 사용하여 리소스 그룹과 동일한 위치에 리소스를 만듭니다. 그러나 Microsoft Learn 샌드박스를 사용하는 경우 리소스 그룹의 위치와 일치하지 않는 특정 Azure 지역을 사용해야 합니다.

5. Visual Studio Code의 main.bicep 파일에서 다음 코드를 파일의 맨 아래에 추가합니다.

   resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
     name: appServicePlanName
     location: location
     sku: {
       name: appServicePlanSku.name
       tier: appServicePlanSku.tier
       capacity: appServicePlanInstanceCount
     }
   }
   
   resource appServiceApp 'Microsoft.Web/sites@2023-12-01' = {
     name: appServiceAppName
     location: location
     properties: {
       serverFarmId: appServicePlan.id
       httpsOnly: true
     }
   }
   

   리소스는 사용자가 정의한 매개 변수의 값을 사용합니다.

6. 변경 내용을 파일에 저장합니다.

매개 변수 설명 추가

1. Visual Studio Code의 main.bicep 파일에서 @description 데코레이터를 이전 작업에서 만든 각 매개 변수 바로 위에 추가합니다. 매개 변수는 다음 예제와 비슷합니다.

   @description('The name of the environment. This must be dev, test, or prod.')
   param environmentName string = 'dev'
   
   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   
   @description('The number of App Service plan instances.')
   param appServicePlanInstanceCount int = 1
   
   @description('The name and tier of the App Service plan SKU.')
   param appServicePlanSku object = {
     name: 'F1'
     tier: 'Free'
   }
   
   @description('The Azure region into which the resources should be deployed.')
   param location string = 'eastus'
   

2. 변경 내용을 파일에 저장합니다.

입력 값 제한

장난감 회사에서 HR 애플리케이션을 dev, test, prod의 세 가지 환경에 배포합니다. 이러한 세 값만 허용하도록 environmentName 매개 변수를 제한합니다.

1. Visual Studio Code의 main.bicep 파일에서 environmentName 매개 변수를 찾습니다. @description 데코레이터 아래에 @allowed 데코레이터를 삽입합니다. 완료 후 매개 변수가 다음 예제와 같아야 합니다.

   @description('The name of the environment. This must be dev, test, or prod.')
   @allowed([
     'dev'
     'test'
     'prod'
   ])
   param environmentName string = 'dev'
   

   environmentName 매개 변수의 매개 변수 값은 dev, test, prod로만 제한합니다. 나중에 더 많은 환경을 추가할 경우에는 이 목록을 업데이트해야 합니다.

2. 변경 내용을 파일에 저장합니다.

입력 길이 제한

solutionName 매개 변수는 리소스의 이름을 생성할 때 사용됩니다. 최소 길이는 5자로, 최대 길이는 30자로 적용합니다.

1. Visual Studio Code의 main.bicep 파일에서 solutionName 매개 변수를 찾습니다. @minLength 및 @maxLength 데코레이터를 @description 데코레이터 아래에 추가합니다. 완료 후 매개 변수가 다음 예제와 같아야 합니다.

   @description('The unique name of the solution. This is used to ensure that resource names are unique.')
   @minLength(5)
   @maxLength(30)
   param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'
   

2. 변경 내용을 파일에 저장합니다.

숫자 값 제한

다음으로 appServicePlanInstanceCount 매개 변수는 1에서 10 사이의 값만 허용하게 합니다.

1. Visual Studio Code의 main.bicep 파일에서 appServicePlanInstanceCount 매개 변수를 찾습니다. @minValue 및 @maxValue 데코레이터를 @description 데코레이터 아래에 추가합니다. 완료 후 매개 변수가 다음 예제와 같아야 합니다.

   @description('The number of App Service plan instances.')
   @minValue(1)
   @maxValue(10)
   param appServicePlanInstanceCount int = 1
   

2. 변경 내용을 파일에 저장합니다.

Bicep 파일 확인

위의 모든 변경을 완료한 후에는 Bicep 파일이 다음 예제와 같아야 합니다.

@description('The name of the environment. This must be dev, test, or prod.')
@allowed([
  'dev'
  'test'
  'prod'
])
param environmentName string = 'dev'

@description('The unique name of the solution. This is used to ensure that resource names are unique.')
@minLength(5)
@maxLength(30)
param solutionName string = 'toyhr${uniqueString(resourceGroup().id)}'

@description('The number of App Service plan instances.')
@minValue(1)
@maxValue(10)
param appServicePlanInstanceCount int = 1

@description('The name and tier of the App Service plan SKU.')
param appServicePlanSku object = {
  name: 'F1'
  tier: 'Free'
}

@description('The Azure region into which the resources should be deployed.')
param location string = 'eastus'

var appServicePlanName = '${environmentName}-${solutionName}-plan'
var appServiceAppName = '${environmentName}-${solutionName}-app'

resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: appServicePlanSku.name
    tier: appServicePlanSku.tier
    capacity: appServicePlanInstanceCount
  }
}

resource appServiceApp 'Microsoft.Web/sites@2023-12-01' = {
  name: appServiceAppName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
  }
}

아닌 경우 예제를 복사하거나 예제와 일치하도록 템플릿을 조정합니다.

Azure에 Bicep 템플릿 배포

az bicep install && az bicep upgrade

az configure --defaults group="<rgn>[sandbox resource group name]</rgn>"

az deployment group create --template-file main.bicep

Set-AzDefault -ResourceGroupName <rgn>[sandbox resource group name]</rgn>

New-AzResourceGroupDeployment -TemplateFile main.bicep

배포 확인

1. Azure Portal로 이동하여 샌드박스 구독에 있는지 확인합니다.

   1. 페이지의 오른쪽 위에 있는 아바타를 선택합니다.
   2. 디렉터리 전환을 선택합니다. 목록에서 Microsoft Learn 샌드박스 디렉터리를 선택합니다.

2. 왼쪽 패널에서 리소스 그룹을 선택합니다.

3. [샌드박스 리소스 그룹 이름]을 선택합니다.

4. 개요에 성공한 배포 하나가 표시될 것입니다.

   

5. ‘1 성공’을 선택하여 배포 세부 정보를 확인합니다.

   

6. main이라는 배포를 선택하여 어떤 리소스가 배포되었는지 확인한 다음, 배포 정보를 선택하여 확장합니다. 이 경우에는 App Service 요금제와 앱이 있습니다.

   

7. 왼쪽 메뉴에서 입력을 선택합니다.

   

8. 매개 변수와 그 값이 나열됩니다.

   

9. 브라우저에서 페이지를 열어 둡니다. 나중에 배포를 다시 확인합니다.