배포 스택에서 리소스 분리 및 삭제

• 7분

예금 애플리케이션을 계속 변경하고 있습니다. 팀은 애플리케이션에서 리소스를 제거하기로 결정했습니다. 일부 리소스는 Azure에 계속 존재해야 하지만, 다른 리소스는 삭제해도 안전합니다. 사용자는 Azure가 배포 스택에서 더 이상 관리하지 않는 리소스를 어떻게 처리하는지 자세히 알아야 합니다.

이 단원에서는 Azure가 관리되지 않는 작업 매개 변수를 사용하여 배포 스택에서 분리된 리소스를 처리하는 방법을 어떻게 제어할 수 있는지 알아봅니다.

관리되지 않는 작업 재검토

배포 스택에서 관리되지 않는 작업 매개 변수를 사용하여 Azure에서 분리된 리소스, 리소스 그룹 및 관리 그룹의 처리 방법을 제어할 수 있습니다. 배포 스택을 만들거나, 수정하거나, 삭제할 때 관리되지 않는 작업 매개 변수를 설정할 수 있습니다. 세 작업에서 모두 관리되지 않는 작업 매개 변수의 동작을 설정할 수 있습니다. 마지막 설정 값이 우선시된다는 점에 유의하세요.

관리되는 리소스 분리

관리되지 않는 리소스라고도 하는 분리된 리소스는 더 이상 배포 스택에서 추적 또는 관리하지 않지만, 리소스는 여전히 Azure에 있는 리소스입니다. 배포 스택의 기본 동작은 리소스를 삭제하지 않고 분리하는 것입니다. 예를 들면, 나중에 다른 배포 스택에서 사용할 수 있도록 리소스를 유지해야 하거나 데이터를 삭제해도 안전한지 수동으로 확인해야 할 수도 있습니다.

배포 스택에서 더 이상 관리하지 않을 때 리소스, 리소스 그룹 및 관리 그룹을 분리하는 관리되지 않는 작업 매개 변수의 값이 두 가지 있습니다.

지난 단원의 Bicep 파일을 살펴보겠습니다. 템플릿 파일은 App Service 요금제, 웹앱, Azure SQL Server 및 데이터베이스, Log Analytics 작업 영역, Application Insights 인스턴스를 정의합니다. 지난 단원에서 만든 Log Analytics 작업 영역과 Application Insights 인스턴스를 제거해야 한다고 가정해 보겠습니다. Bicep 파일을 편집하여 웹앱을 참조하는 강조 표시된 코드를 제거합니다.

// Parameters
@description('The location for all resources.')
param location string = 'eastus'

@description('The name of the SQL database.')
param sqlDatabaseName string = 'sqldb-${uniqueString(resourceGroup().id)}'

@description('The password of the admin user.')
param sqlServerAdminUserName string

@description('The name of the admin user.')
@secure()
param sqlServerAdminPassword string

@description('The name of the SQL server.')
param sqlServerName string = 'sql-${uniqueString(resourceGroup().id)}'

@description('The name of the web application.')
param webApplicationName string = 'webapp-${uniqueString(resourceGroup().id)}'

// Variables
@description('The name of the Application Insights instance.')
var applicationInsightsName = 'appinsights-deposits'

@description('The name of the app service plan.')
var appServicePlanName = 'plan-deposits'

@description('The name of the Log Analytics Workspace.')
var logAnalyticsWorkspaceName = 'log-deposits'

// Resource - App Service Plan
resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: 'S1'
    capacity: 1
  }
}

// Resource - Web App
resource webApplication 'Microsoft.Web/sites@2023-12-01' = {
  name: webApplicationName
  location: location
  properties: {
    serverFarmId: appServicePlan.id
    siteConfig: {
      appSettings: [
        {
          name: 'APPINSIGHTS_INSTRUMENTATIONKEY'
          value: applicationInsights.properties.InstrumentationKey
        }     
      ]
    }    
  }
}

// Resource - SQL Server
resource sqlServer 'Microsoft.Sql/servers@2021-11-01' ={
  name: sqlServerName
  location: location
  properties: {
    administratorLogin: sqlServerAdminUserName
    administratorLoginPassword: sqlServerAdminPassword
  }
}

// Resource - SQL Database
resource sqlServerDatabase 'Microsoft.Sql/servers/databases@2021-11-01' = {
  parent: sqlServer
  name: sqlDatabaseName
  location: location
  sku: {
    name: 'Standard'
    tier: 'Standard'
  }
}

// Resource - Log Analytics Workspace
resource logAnalyticsWorkspace 'Microsoft.OperationalInsights/workspaces@2023-09-01' = {
  name: logAnalyticsWorkspaceName
  location: location
  properties: {
    retentionInDays: 30
    sku: {
      name: 'PerGB2018'
    }
  }
}

// Resource - Application Insights
resource applicationInsights 'Microsoft.Insights/components@2020-02-02' = {
  name: applicationInsightsName
  location: location
  kind: 'web'
  properties: {
    Application_Type: 'web'
    WorkspaceResourceId: logAnalyticsWorkspace.id
  }
}

az stack group create \
    --name stack-deposits \
    --resource-group rg-depositsApplication \
    --template-file ./main.bicep \
    --action-on-unmanage detachAll \
    --deny-settings-mode none

Set-AzResourceGroupDeploymentStack `
    -Name stack-deposits `
    -ResourceGroupName rg-depositsApplication `
    -TemplateFile ./main.bicep `
    -ActionOnUnmanage DetachAll `
    -DenySettingsMode None

관리되는 리소스 삭제

배포 스택은 신뢰할 수 있는 리소스 정리 기능을 제공합니다. 배포 스택을 업데이트하거나 삭제하면 관리되는 리소스, 리소스 그룹 및 관리 그룹도 삭제할 수 있습니다. 배포 스택에서 더 이상 관리하지 않을 때 삭제할 리소스, 리소스 그룹 및 관리 그룹을 설정하는 관리되지 않는 작업 매개 변수의 값이 두 가지 있습니다.

이전 섹션의 Bicep 파일을 살펴보겠습니다. 템플릿 파일은 App Service 요금제, 웹앱, Azure SQL Server 및 데이터베이스를 정의합니다. Azure SQL Server 및 데이터베이스를 제거해야 한다고 가정해 보겠습니다. Bicep 파일을 편집하여 웹앱을 참조하는 강조 표시된 코드를 제거합니다.

// Parameters
@description('The location for all resources.')
param location string = 'eastus'

@description('The name of the SQL database.')
param sqlDatabaseName string = 'sqldb-${uniqueString(resourceGroup().id)}'

@description('The password of the admin user.')
param sqlServerAdminUserName string

@description('The name of the admin user.')
@secure()
param sqlServerAdminPassword string

@description('The name of the SQL server.')
param sqlServerName string = 'sql-${uniqueString(resourceGroup().id)}'

@description('The name of the web application.')
param webApplicationName string = 'webapp-${uniqueString(resourceGroup().id)}'

// Variables
@description('The name of the app service plan.')
var appServicePlanName = 'plan-deposits'

// Resource - App Service Plan
resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: 'F1'
    capacity: 1
  }
}

// Resource - Web App
resource webApplication 'Microsoft.Web/sites@2023-12-01' = {
  name: webApplicationName
  location: location
  properties: {
    serverFarmId: appServicePlan.id  
  }
}

// Resource - SQL Server
resource sqlServer 'Microsoft.Sql/servers@2021-11-01' ={
  name: sqlServerName
  location: location
  properties: {
    administratorLogin: sqlServerAdminUserName
    administratorLoginPassword: sqlServerAdminPassword
  }
}

// Resource - SQL Database
resource sqlServerDatabase 'Microsoft.Sql/servers/databases@2021-11-01' = {
  parent: sqlServer
  name: sqlDatabaseName
  location: location
  sku: {
    name: 'Standard'
    tier: 'Standard'
  }
}

파일에 다음 코드가 남아 있습니다.

// Parameters
@description('The location for all resources.')
param location string = 'eastus'

@description('The name of the web application.')
param webApplicationName string = 'webapp-${uniqueString(resourceGroup().id)}'

// Variables
@description('The name of the app service plan.')
var appServicePlanName = 'plan-deposits'

// Resource - App Service Plan
resource appServicePlan 'Microsoft.Web/serverfarms@2023-12-01' = {
  name: appServicePlanName
  location: location
  sku: {
    name: 'F1'
    capacity: 1
  }
}

// Resource - Web App
resource webApplication 'Microsoft.Web/sites@2023-12-01' = {
  name: webApplicationName
  location: location
  properties: {
    serverFarmId: appServicePlan.id  
  }
}

az stack group create \
    --name stack-deposits \
    --resource-group rg-depositsApplication \
    --template-file ./main.bicep \
    --action-on-unmanage deleteAll \
    --deny-settings-mode none

Set-AzResourceGroupDeploymentStack `
    -Name stack-deposits `
    -ResourceGroupName rg-depositsApplication `
    -TemplateFile ./main.bicep `
    -ActionOnUnmanage DeleteAll `
    -DenySettingsMode None