다음을 통해 공유

부팅 트리거 예제(스크립팅)

  • 아티클

이 스크립팅 예제에서는 시스템이 부팅될 때 메모장을 실행하도록 예약된 작업을 만드는 방법을 보여줍니다. 이 작업에는 시스템이 부팅된 후 작업이 시작될 시작 경계 및 지연 시간을 지정하는 부팅 트리거가 포함되어 있습니다. 작업에는 메모장을 실행할 작업을 지정하는 작업도 포함됩니다. 작업은 로컬 서비스 계정을 사용하여 작업을 실행하는 보안 컨텍스트로 등록됩니다.

다음 절차에서는 시스템이 부팅될 때 시작되도록 메모장과 같은 실행 파일을 예약하는 방법을 설명합니다.

시스템이 부팅될 때 시작되도록 메모장을 예약하려면

  1. TaskService 개체를 만듭니다. 이 개체를 사용하면 지정된 폴더에 작업을 만들 수 있습니다.
  2. 작업 폴더를 가져와 작업을 만듭니다. TaskService.GetFolder 메서드를 사용하여 태스크가 저장된 폴더를 가져올 수 있고 TaskService.NewTask 메서드를 사용하여 작업을 나타내는 TaskDefinition 개체를 만듭니다.
  3. TaskDefinition 개체를 사용하여 작업에 대한 정보를 정의합니다. TaskDefinition.Settings 속성을 사용하여 작업 스케줄러 서비스가 작업을 수행하는 방법을 결정하는 설정을 정의하고 TaskDefinition.RegistrationInfo 속성을 사용하여 작업을 설명하는 정보를 정의합니다.
  4. TaskDefinition.Triggers 속성을 사용하여 로그온 트리거를 만듭니다. 이 속성은 TriggerCollection 개체에 대한 액세스를 제공합니다. TriggerCollection.Create 메서드(만들려는 트리거 유형 지정)를 사용하여 부팅 트리거를 만듭니다. 트리거를 만들 때 트리거의 StartBoundary 및 EndBoundary 속성을 설정하여 트리거를 활성화하고 비활성화합니다. 부팅 트리거의 Delay 속성에 대한 값을 지정할 수도 있습니다.
  5. TaskDefinition.Actions 속성을 사용하여 실행할 태스크에 대한 작업을 만듭니다. 이 속성은 ActionCollection 개체에 대한 액세스를 제공합니다. ActionCollection.Create 메서드를 사용하여 만들려는 작업 유형을 지정합니다. 이 예제에서는 실행 파일을 시작하는 작업을 나타내는 ExecAction 개체를 사용합니다.
  6. TaskFolder.RegisterTaskDefinition 메서드를 사용하여 작업을 등록합니다. 작업은 로컬 서비스 계정을 사용하여 작업을 실행하는 보안 컨텍스트로 등록됩니다.

다음 VBScript 예제에서는 시스템이 부팅된 후 30초 후에 메모장을 실행하도록 작업을 예약하는 방법을 보여줍니다.

'---------------------------------------------------------
' This sample schedules a task to start notepad.exe 30 seconds after
' the system is booted.
'---------------------------------------------------------

' A constant that specifies a boot trigger.
const TriggerTypeBoot = 8
' A constant that specifies an executable action.
const ActionTypeExecutable = 0   

'********************************************************
' Create the TaskService object.
Set service = CreateObject("Schedule.Service")
call service.Connect()

'********************************************************
' Get a folder to create a task definition in. 
Dim rootFolder
Set rootFolder = service.GetFolder("\")

' The taskDefinition variable is the TaskDefinition object.
Dim taskDefinition
' The flags parameter is 0 because it is not supported.
Set taskDefinition = service.NewTask(0) 

'********************************************************
' Define information about the task.

' Set the registration info for the task by 
' creating the RegistrationInfo object.
Dim regInfo
Set regInfo = taskDefinition.RegistrationInfo
regInfo.Description = "Task will execute Notepad when " & _
    "the computer is booted."
regInfo.Author = "Author Name"

' Set the task setting info for the Task Scheduler by
' creating a TaskSettings object.
Dim settings
Set settings = taskDefinition.Settings
settings.StartWhenAvailable = True

'********************************************************
' Create a boot trigger.
Dim triggers
Set triggers = taskDefinition.Triggers

Dim trigger
Set trigger = triggers.Create(TriggerTypeBoot)

' Trigger variables that define when the trigger is active.
Dim startTime, endTime
startTime = "2006-05-02T10:49:02"
endTime = "2006-05-02T10:52:02"

WScript.Echo "startTime :" & startTime
WScript.Echo "endTime :" & endTime

trigger.StartBoundary = startTime
trigger.EndBoundary = endTime
trigger.ExecutionTimeLimit = "PT5M"    ' Five minutes
trigger.Id = "BootTriggerId"
trigger.Delay = "PT30S"                ' 30 Seconds   

'***********************************************************
' Create the action for the task to execute.

' Add an action to the task. The action executes notepad.
Dim Action
Set Action = taskDefinition.Actions.Create( ActionTypeExecutable )
Action.Path = "C:\Windows\System32\notepad.exe"

WScript.Echo "Task definition created. About to submit the task..."

'***********************************************************
' Register (create) the task.
const createOrUpdateTask = 6
call rootFolder.RegisterTaskDefinition( _
    "Test Boot Trigger", taskDefinition, createOrUpdateTask, _
    "Local Service", , 5)

WScript.Echo "Task submitted."

작업 스케줄러 사용