다음을 통해 공유

WMI 작업: 날짜 및 시간

  • 아티클

CIM 날짜/시간 형식을 구문 분석하거나 변환하는 WMI 클래스와 스크립팅 개체가 여러 개 있습니다. 다른 예제는 https://www.microsoft.com/technet에서 TechNet ScriptCenter를 참조하세요.

이 항목에 표시된 스크립트 예제는 로컬 컴퓨터에서만 데이터를 가져옵니다. 스크립트를 사용하여 원격 컴퓨터에서 데이터를 가져오는 방법에 대한 자세한 내용은 원격 컴퓨터에서 WMI에 연결을 참조하세요.

스크립트를 실행하려면

다음 절차에서 스크립트를 실행하는 방법을 설명합니다.

  1. 코드를 복사하고 확장자가 .vbs인 파일(예: filename.vbs)에 저장합니다. 텍스트 편집기가 파일에 .txt 확장자를 추가하지 않는지 확인합니다.
  2. 명령 프롬프트 창을 열고 파일을 저장한 디렉터리로 이동합니다.
  3. 명령 프롬프트에 cscript filename.vbs를 입력합니다.
  4. 이벤트 로그에 액세스할 수 없는 경우 관리자 권한 명령 프롬프트에서 실행 중인지 확인합니다. 보안 이벤트 로그와 같은 일부 이벤트 로그는 UAC(사용자 액세스 제어)로 보호될 수 있습니다.

참고

기본적으로 cscript는 명령 프롬프트 창에 스크립트의 출력을 표시합니다. WMI 스크립트는 많은 양의 출력을 생성할 수 있으므로 출력을 파일로 리디렉션할 수 있습니다. 명령 프롬프트에 cscript filename.vbs > outfile.txt를 입력하여 filename.vbs 스크립트의 출력을 outfile.txt로 리디렉션합니다.

다음 표에는 로컬 컴퓨터에서 다양한 형식의 데이터를 가져오는 데 사용할 수 있는 스크립트 예제가 나와 있습니다.

어떻게 할까요? WMI 클래스 또는 메서드
WMI 날짜를 표준 날짜 및 시간으로 변환할 수 있나요?
 SWbemDateTime 개체를 사용하여 이러한 날짜 및 시간을 일반 날짜 및 시간으로 변환합니다.
VB 
Set dtmInstallDate = CreateObject("WbemScripting.SWbemDateTime")
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set objOS = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")
For Each strOS in objOS
    dtmInstallDate.Value = strOS.InstallDate
    Wscript.Echo dtmInstallDate.GetVarDate
Next

또는 코드가 작업을 수동으로 수행하게 합니다.

VB 
Function WMIDateStringToDate(dtmInstallDate) 
    WMIDateStringToDate = CDate(Mid(dtmInstallDate, 5, 2) & "/" & Mid(dtmInstallDate, 7, 2) _
                        & "/" & Left(dtmInstallDate, 4) & " " & Mid (dtmInstallDate, 9, 2) & ":" _
                        & Mid(dtmInstallDate, 11, 2) & ":" & Mid(dtmInstallDate,13, 2)) 
End Function

컴퓨터에 현재 구성된 시간을 확인할 수 있나요?

Win32_LocalTime 클래스를 사용합니다.

VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_LocalTime")
For Each objItem in colItems
    Wscript.Echo "Day:           " & objItem.Day & VBNewLine _
               & "Day Of Week:   " & objItem.DayOfWeek & VBNewLine _
               & "Hour:          " & objItem.Hour & VBNewLine _
               & "Minute:        " & objItem.Minute & VBNewLine _
               & "Month:         " & objItem.Month & VBNewLine _
               & "Quarter:       " & objItem.Quarter & VBNewLine _
               & "Second:        " & objItem.Second & VBNewLine _
               & "Week In Month: " & objItem.WeekInMonth & VBNewLine _
               & "Year:          " & objItem.Year 
Next

PowerShell 
# 컴퓨터를 지정하고 현지 시간 $Computer = "." $times = Get-WmiObject Win32_LocalTime -computer $computer 
<# Now display the result #>


Foreach ($time in $times) {
"Day : {0}" -f $Time.Day
"Day Of Week : {0}" -f $Time.DayOfWeek
"Hour : {0}" -f $Time.Hour
"Minute : {0}" -f $Time.Minute
"Month : {0}" -f $Time.Month
"Quarter : {0}" -f $Time.Quarter
"Second : {0}" -f $time.Second
"Week In Month: {0}" -f $Time.WeekInMonth
"Year : {0}" -f $Time.Year
}

컴퓨터가 실행되는 표준 시간대의 이름을 확인할 수 있나요?

Win32_TimeZone 클래스를 사용하고 Description 속성 값을 확인합니다.

VB 
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_TimeZone")
For Each objItem in colItems
    Wscript.Echo "Description:   " & objItem.Description
    Wscript.Echo "Daylight Name: " & objItem.DaylightName
    Wscript.Echo "Standard Name: " & objItem.StandardName
    Wscript.Echo
Next
PowerShell 
$Computer = "."  
$timezone = Get-WMIObject -class Win32_TimeZone -ComputerName $computer  
  
<# Display details  #>
if ($computer -eq ".") {$computer = Hostname}  
"Time zone information on computer `"{0}`"" -f $computer  
"Time Zone Description   : {0}" -f $timezone.Description  
"Daylight Name           : {0}" -f $timezone.DaylightName  
"Standard Name           : {0}" -f $timezone.StandardName

"10/02/2000"이 "2000년 2월 10일"이 아닌 2000년 10월 2일로 해석되는지 확인할 수 있나요?

CIM DATETIME 형식으로 날짜를 관리하고 GetVarDate와 같은 SWbemDateTime 메서드를 사용하여 FILETIME 또는 VT_Date 형식으로 변환합니다. DATETIME 형식은 로캘에 독립적이므로, 어떤 컴퓨터에서도 실행되는 스크립트를 작성할 수 있습니다. SWbemDateTime 개체를 사용하여 이러한 날짜 및 시간을 일반 날짜 및 시간으로 변환합니다. 날짜 및 시간 변환에 대한 자세한 내용은 날짜 및 시간 형식을 참조하세요.

WMI datetime을 .NET DateTime 값으로 변환할 수 있나요?

문자열을 수동으로 구문 분석한 다음 검색된 값을 DateTime 개체에 넣습니다.

PowerShell 
function WMIDateStringToDateTime( [String] $strWmiDate ) 
{ 
    $strWmiDate.Trim() > $null 
    $iYear   = [Int32]::Parse($strWmiDate.SubString( 0, 4)) 
    $iMonth  = [Int32]::Parse($strWmiDate.SubString( 4, 2)) 
    $iDay    = [Int32]::Parse($strWmiDate.SubString( 6, 2)) 
    $iHour   = [Int32]::Parse($strWmiDate.SubString( 8, 2)) 
    $iMinute = [Int32]::Parse($strWmiDate.SubString(10, 2)) 
    $iSecond = [Int32]::Parse($strWmiDate.SubString(12, 2)) 
<# decimal point is at $strWmiDate.Substring(14, 1) #> 
    $iMicroseconds = [Int32]::Parse($strWmiDate.Substring(15, 6)) 
    $iMilliseconds = $iMicroseconds / 1000 
    $iUtcOffsetMinutes = [Int32]::Parse($strWmiDate.Substring(21, 4)) 
    if ( $iUtcOffsetMinutes -ne 0 ) 
    { 
        $dtkind = [DateTimeKind]::Local 
    } 
    else 
    { 
        $dtkind = [DateTimeKind]::Utc 
    } 
    return New-Object -TypeName DateTime ` 
                      -ArgumentList $iYear, $iMonth, $iDay, ` 
                                    $iHour, $iMinute, $iSecond, ` 
                                    $iMilliseconds, $dtkind 
}

스크립트 및 애플리케이션에 대한 WMI 작업

WMI C++ 애플리케이션 예제

날짜 및 시간 형식

TechNet ScriptCenter

`