Wizualizacje geoprzestrzenne

Dotyczy: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Dane geoprzestrzenne można wizualizować przy użyciu operatora renderowania w Eksploratorze usługi Kusto Desktop. Aby pobrać Eksploratora aplikacji Kusto Desktop, zobacz Instalowanie i interfejs użytkownika kusto.Explorer.

Aby uzyskać więcej informacji na temat klastrowania geoprzestrzennych, zobacz Geoprzestrzenne klastrowanie.

Wizualizowanie punktów na mapie

Punkty można wizualizować przy użyciu kolumn [Długość geograficzna, Szerokość geograficzna] lub GeoJSON. Użycie kolumny serii jest opcjonalne. Para [Długość geograficzna, Szerokość geograficzna] definiuje każdy punkt w tej kolejności.

Przykład: wizualizowanie punktów na mapie

Poniższy przykład umożliwia znalezienie zdarzeń storm i wizualizowanie 100 na mapie.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

Przykład: Wizualizowanie wielu serii punktów na mapie

Poniższy przykład wizualizuje wiele serii punktów, w których para [Długość geograficzna, Szerokość geograficzna] definiuje każdy punkt, a trzecia kolumna definiuje serię. W tym przykładzie seria to EventType.

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

Przykład: wizualizowanie serii punktów na danych z wieloma kolumnami

Poniższy przykład wizualizuje serię punktów na mapie. Jeśli w wyniku istnieje wiele kolumn, musisz określić kolumny, które mają być używane dla kolumn (długości geograficznej), kolumny (szerokość geograficzna) i serii.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

Przykład: wizualizowanie punktów na mapie zdefiniowanej przez wartości dynamiczne GeoJSON

Poniższy przykład wizualizuje punkty na mapie przy użyciu wartości dynamicznych GeoJSON w celu zdefiniowania punktów.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

Wizualizacja ciast lub bąbelków na mapie

Możesz wizualizować ciasta lub bąbelki przy użyciu kolumn [Długość geograficzna, Szerokość geograficzna] lub Kolumna GeoJSON. Te wizualizacje można tworzyć z osiami kolorów lub liczbowymi.

Przykład: Wizualizowanie wykresów kołowych według lokalizacji

W poniższym przykładzie pokazano zdarzenia burzy zagregowane przez komórkę S2. Wykres agreguje zdarzenia na wykresach kołowych według lokalizacji.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map) // pie map rendering available only in Kusto Explorer desktop

Przykład: wizualizowanie bąbelków przy użyciu osi kolorów

W poniższym przykładzie pokazano zdarzenia burzy zagregowane przez komórkę S2. Wykres agreguje zdarzenia w bąbelku według lokalizacji. Ponieważ oś kolorów ("count") jest taka sama dla wszystkich zdarzeń, render operator generuje bąbelki.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map) // pie map rendering available only in Kusto Explorer desktop

Powiązana zawartość

• Klastrowanie geoprzestrzenne
• Operator renderowania
• Analiza danych dla flot testów samochodowych (przypadek użycia klastrów geoprzestrzennych)
• Dowiedz się więcej o architekturze platformy Azure na potrzeby przetwarzania i analizy danych geoprzestrzennych