Obter a análise em sua base de dados de conhecimento

O QnA Maker armazena todos os logs de chat e outros dados telemétricos, se você habilitou o Application Insights durante a criação do serviço do QnA Maker. Execute os exemplos de consultas para obter seus logs de bate-papo do Application Insights.

1. Acesse seu recurso do Application Insights.

   

2. Selecione Log (Analytics) . Uma nova janela será aberta onde você pode consultar os dados de telemetria do QnA Maker.

3. Cole a consulta a seguir e execute-a.

   requests
   | where url endswith "generateAnswer"
   | project timestamp, id, url, resultCode, duration, performanceBucket
   | parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
   | join kind= inner (
   traces | extend id = operation_ParentId
   ) on id
   | where message == "QnAMaker GenerateAnswer"
   | extend question = tostring(customDimensions['Question'])
   | extend answer = tostring(customDimensions['Answer'])
   | extend score = tostring(customDimensions['Score'])
   | project timestamp, resultCode, duration, id, question, answer, score, performanceBucket,KbId
   

   Clique em Executar para executar a consulta.

   

Executar consultas para outras análises em sua base de dados de conhecimento do QnA Maker

Tráfego total de 90 dias

//Total Traffic
requests
| where url endswith "generateAnswer" and name startswith "POST"
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| summarize ChatCount=count() by bin(timestamp, 1d), KbId

Tráfego total de perguntas em um determinado período de tempo

//Total Question Traffic in a given time period
let startDate = todatetime('2019-01-01');
let endDate = todatetime('2020-12-31');
requests
| where timestamp <= endDate and timestamp >=startDate
| where url endswith "generateAnswer" and name startswith "POST"
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| summarize ChatCount=count() by KbId

Tráfego de usuários

//User Traffic
requests
| where url endswith "generateAnswer"
| project timestamp, id, url, resultCode, duration
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| join kind= inner (
traces | extend id = operation_ParentId
) on id
| extend UserId = tostring(customDimensions['UserId'])
| summarize ChatCount=count() by bin(timestamp, 1d), UserId, KbId

Distribuição de latência das perguntas

//Latency distribution of questions
requests
| where url endswith "generateAnswer" and name startswith "POST"
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| project timestamp, id, name, resultCode, performanceBucket, KbId
| summarize count() by performanceBucket, KbId

Perguntas não respondidas

// Unanswered questions
requests
| where url endswith "generateAnswer"
| project timestamp, id, url
| parse kind = regex url with *"(?i)knowledgebases/"KbId"/generateAnswer"
| join kind= inner (
traces | extend id = operation_ParentId
) on id
| extend question = tostring(customDimensions['Question'])
| extend answer = tostring(customDimensions['Answer'])
| extend score = tostring(customDimensions['Score'])
| where  score  == "0" and message == "QnAMaker GenerateAnswer"
| project timestamp, KbId, question, answer, score
| order  by timestamp  desc

OBSERVAÇÃO
Se você não conseguir obter corretamente o log usando o Application Insights, confirme as configurações do Application Insights no recurso Serviço de Aplicativo. Abra o recurso Serviço de Aplicativo e acesse o Application Insights. E, em seguida, verifique se ele está habilitado ou desabilitado. Se estiver desabilitado, habilite-o e aplique-o lá.

Próximas etapas