Guia de início rápido: criar um repositório da Configuração de Aplicativos do Azure usando o Bicep

Este guia de início rápido descreve como usar o Bicep para:

• Implantar um repositório da Configuração de Aplicativos.
• Criar pares chave-valor em um repositório da Configuração de Aplicativos.
• Ler pares chave-valor em um repositório da Configuração de Aplicativos.

O Bicep é um DSL (linguagem específica de domínio) que usa sintaxe declarativa para implantar recursos do Azure. Ele fornece sintaxe concisa, segurança de tipos confiável e suporte para reutilização de código. O Bicep oferece a melhor experiência de criação para suas soluções de infraestrutura como código no Azure.

Pré-requisitos

Se você não tiver uma assinatura do Azure, crie uma conta gratuita antes de começar.

Autorização

É preciso ter uma função como Colaborador ou Proprietário do Azure Resource Manager para gerenciar um recurso da Configuração de Aplicativos do Azure com o arquivo Bicep. O acesso aos dados da Configuração de Aplicativos do Azure (valores-chave, instantâneos) requer uma função do Azure Resource Manager e uma função de plano de dados adicional da Configuração de Aplicativos do Azure quando o modo de autenticação do ARM do armazenamento de configuração está definido para o modo de autenticação do ARM de Passagem.

Examinar o arquivo Bicep

O arquivo Bicep usado neste guia de início rápido vem dos Modelos de início rápido do Azure.

@description('Specifies the name of the App Configuration store.')
param configStoreName string = 'appconfig${uniqueString(resourceGroup().id)}'

@description('Specifies the Azure location where the app configuration store should be created.')
param location string = resourceGroup().location

@description('Specifies the names of the key-value resources. The name is a combination of key and label with $ as delimiter. The label is optional.')
param keyValueNames array = [
  'myKey'
  'myKey$myLabel'
]

@description('Specifies the values of the key-value resources. It\'s optional')
param keyValueValues array = [
  'Key-value without label'
  'Key-value with label'
]

@description('Specifies the content type of the key-value resources. For feature flag, the value should be application/vnd.microsoft.appconfig.ff+json;charset=utf-8. For Key Value reference, the value should be application/vnd.microsoft.appconfig.keyvaultref+json;charset=utf-8. Otherwise, it\'s optional.')
param contentType string = 'the-content-type'

@description('Adds tags for the key-value resources. It\'s optional')
param tags object = {
  tag1: 'tag-value-1'
  tag2: 'tag-value-2'
}

resource configStore 'Microsoft.AppConfiguration/configurationStores@2024-05-01' = {
  name: configStoreName
  location: location
  sku: {
    name: 'standard'
  }
}

resource configStoreKeyValue 'Microsoft.AppConfiguration/configurationStores/keyValues@2024-05-01' = [for (item, i) in keyValueNames: {
  parent: configStore
  name: item
  properties: {
    value: keyValueValues[i]
    contentType: contentType
    tags: tags
  }
}]

output reference_key_value_value string = configStoreKeyValue[0].properties.value
output reference_key_value_object object = {
  name: configStoreKeyValue[1].name
  properties: configStoreKeyValue[1].properties
}

Há dois recursos do Azure definidos no arquivo Bicep:

• Microsoft.AppConfiguration/configurationStores: cria um repositório de Configuração de Aplicativos.
• Microsoft.AppConfiguration/configurationStores/keyValues: crie um par chave/valor dentro do repositório de Configuração de Aplicativos.

Com esse arquivo Bicep, criamos uma chave com dois valores diferentes. Um desses valores tem um rótulo exclusivo.

Implante o arquivo Bicep

1. Salve o arquivo Bicep como main.bicep em seu computador local.

2. Para implantar o arquivo Bicep, use a CLI do Azure ou o Azure PowerShell.

   • CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters configStoreName=<store-name>
   

   Observação

   Substitua <store-name> pelo nome do repositório da Configuração de Aplicativos.

   Quando a implantação for concluída, você deverá ver uma mensagem indicando que ela foi bem-sucedida.

Examinar os recursos implantados

Use a CLI do Azure ou o Azure PowerShell para listar os recursos implantados no grupo de recursos.

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

Você também pode usar o portal do Azure para listar os recursos:

1. Entre no portal do Azure.
2. Na caixa de pesquisa, insira Configuração de Aplicativos e selecione Configuração de Aplicativos na lista.
3. Selecione o recurso de Configuração de Aplicativos recém-criado.
4. Em Operações, clique em Gerenciador de configurações.
5. Verifique se há dois pares chave/valor.

Limpar os recursos

Quando não for mais necessário, use a CLI do Azure ou o Azure PowerShell para excluir o grupo de recursos e seus recursos.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Você também pode usar o portal do Azure para excluir um grupo de recursos:

1. Navegue até o grupo de recursos.
2. Selecione Excluir grupo de recursos.
3. Uma guia será exibida. Insira o nome do grupo de recursos e selecione Excluir.

Próximas etapas

Para saber como adicionar um sinalizador de recurso e uma referência ao Key Vault a um repositório da Configuração de Aplicativos, confira os exemplos de modelo do ARM.

• app-configuration-store-ff
• app-configuration-store-keyvaultref