Consultas para a tabela ACSCallRecordingSummary

Artigo
11/05/2024

Para obter informações sobre como usar essas consultas no portal do Azure, consulte o tutorial do Log Analytics. Para a API REST, consulte Consulta.

Histograma de duração da gravação de chamadas

Produz um histograma das durações de gravação de chamadas em segundos.

ACSCallRecordingSummary
| distinct RecordingId, RecordingLength
// Count call duration bins (60 second intervals)
| summarize duration_counts=count() by bin(RecordingLength, 6000)
| order by RecordingLength asc
| render columnchart with (xcolumn = RecordingLength, title="Recording duration histogram")

Percentis de duração da Gravação de Chamadas

Calcula a duração média da gravação de chamadas em segundos, bem como os percentis de duração da chamada de 50%, 90% e 99%.

ACSCallRecordingSummary
// Get the distinct combinations of RecordingId, RecordingLength
| distinct RecordingId, RecordingLength
// Calculate average and percentiles (50%, 90%, and 99%) of call durations (in seconds)
| summarize avg(RecordingLength), percentiles(RecordingLength, 50, 90, 99)

Taxa de razão final da Gravação de Chamadas

Produz um gráfico de pizza da proporção do motivo final da gravação de chamadas.

ACSCallRecordingSummary
// Count distinct calls (dcount(CorrelationId)) per call type
| summarize call_types=dcount(RecordingId) by RecordingEndReason
| render piechart title="Recording End Reason Ratio"

Gravações diárias de chamadas

Produz um histograma de gravações feitas por dia na última semana.

ACSCallRecordingSummary
// To filter out recordings made over a week ago, uncomment the next line
// | where TimeGenerated > ago(7d)
// Get the distinct combinations of RecordingId and CallStartTime
| distinct RecordingId, TimeGenerated
// Adds a new column with the call start day
| extend day = floor(TimeGenerated, 1d)
// Count the number of calls per day
| summarize event_count=count() by day
| sort by day asc
| render columnchart title="Number of recordings per day"

Gravações de chamadas de hora em hora

Produz um histograma de gravações feitas por hora no último dia.

    ACSCallRecordingSummary
    // To filter out recordings made over a day ago, uncomment the next line
    | where TimeGenerated > ago(1d)
    // Get the distinct combinations of RecordingId and TimeGenerated
    | distinct RecordingId, TimeGenerated
    // Adds a new column with the call start hour
    | extend hour = floor(TimeGenerated, 1h)
    // Count the number of calls per hour
    | summarize event_count=count() by hour
    | sort by hour asc
    | render columnchart title="Number of recordings per hour in last day"

Proporção do modo de gravação de chamadas

Produz um gráfico de pizza da proporção de modos de gravação (tipos de conteúdo/formato).

ACSCallRecordingSummary
| summarize count() by ContentType, FormatType
| extend ContentFormat = strcat(ContentType, "/", FormatType)
| project ContentFormat, count_
| render piechart title="Recording by mode (content/format types)"

Compartilhar via