Consultas para a tabela ACSChatIncomingOperations

Artigo
11/05/2024

Para obter informações sobre como usar essas consultas no portal do Azure, consulte o tutorial do Log Analytics. Para a API REST, consulte Consulta.

Operações de chat

Retorna todas as combinações distintas de operação de chat e pares de versão.

ACSChatIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Calcular percentis de duração da operação de chat

Calcula os percentis 90, 95 e 99 da duração da execução em milissegundos para cada operação de chat. Ele pode ser personalizado para ser executado para uma única operação ou para outros percentis.

ACSChatIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

Os 5 principais endereços IP por operação de bate-papo

Para cada operação de bate-papo, busque os 5 endereços IP que mais chamaram essa operação.

ACSChatIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Erros operacionais do chat

Liste todos os erros de bate-papo ordenados por recência.

ACSChatIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100

Contagens de resultados da operação de chat

Para cada operação de chat, conte os tipos de resultados retornados.

ACSChatIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100

Compartilhar via