Compartilhar via

Consultas para a tabela AzureActivity

  • Artigo

Para obter informações sobre como usar essas consultas no portal do Azure, consulte o tutorial do Log Analytics. Para a API REST, consulte Consulta.

[Clássico] Localizar no AzureActivity

[Clássico] Localizar em AzureActivity para pesquisar um valor específico na tabela AzureActivity./nObserve que essa consulta requer a atualização do <parâmetro SeachValue> para produzir resultados

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
AzureActivity
| where ResourceProvider == "MICROSOFT.KEYVAULT"
| where * contains tostring(SearchValue)
| take 1000

Desligar máquinas virtuais

As Máquinas Virtuais são desligadas com êxito nos últimos 10 minutos.

// To create an alert for this query, click '+ New alert rule'
AzureActivity
| where TimeGenerated > ago(10m)
| where OperationName == "Deallocate Virtual Machine" and ActivityStatus == "Succeeded"

Últimos 50 logs

Mostre os logs de atividades do Azure mais recentes para esse recurso.

AzureActivity 
| top 50 by TimeGenerated desc

Status das operações

Mostre o log de atividades mais recente do Azure para cada operação.

AzureActivity 
| summarize arg_max(TimeGenerated, *) by OperationName

Logs de atividades recentes do Azure

Exiba todos os logs de atividades do Azure da última hora.

AzureActivity 
| where Level == "Error" or Level == "Warning"
| project TimeGenerated, Level, ResourceProvider, ActivityStatus, Caller, Category, Properties, CorrelationId

Operações com falha

Liste todos os relatórios de operações com falha na última hora.

AzureActivity 
| where TimeGenerated > ago(1h)  
| where ActivityStatus == "Failed"

Criação de recursos

Liste os recursos do Azure criados. Pode ser útil para monitoramento e alertas.

AzureActivity
| where OperationNameValue has "Microsoft.Resources/deployments/write"
| where CategoryValue == "Administrative"
| where ActivityStatusValue == "Success"
| project Caller, TimeGenerated, _ResourceId

Localizar no AzureActivity

Localizar em AzureActivity para pesquisar um valor específico na tabela AzureActivity./nObserve que essa consulta requer a atualização do <parâmetro SeachValue> para produzir resultados

// This query requires a parameter to run. Enter value in SearchValue to find in table.
let SearchValue =  "<SearchValue>";//Please update term you would like to find in the table.
AzureActivity
| where ResourceProvider == "Microsoft.ContainerService"
| where * contains tostring(SearchValue)
| take 1000

Mostrar logs da tabela AzureActivity

Lista os logs mais recentes na tabela AzureActivity, classificados por hora (mais recente primeiro).

AzureActivity
| top 10 by TimeGenerated

Mostrar logs da tabela AzureActivity

Lista os logs mais recentes na tabela AzureActivity, classificados por hora (mais recente primeiro).

AzureActivity
| top 10 by TimeGenerated

Exibir os 50 principais eventos do registro de atividades

Exiba os 50 principais eventos do log de atividades.

AzureActivity
| project TimeGenerated, SubscriptionId, ResourceGroup,ResourceProviderValue,OperationNameValue,CategoryValue,CorrelationId,ActivityStatusValue, ActivitySubstatusValue, Properties_d, Caller
| top 50 by TimeGenerated

Exibir registro de atividades Eventos administrativos

Exibe o log de atividades para a categoria Administrativa.

AzureActivity 
| where CategoryValue == "Administrative"
| order by TimeGenerated desc

Criação da VM

Essa consulta exibe os resultados de quando uma VM é criada.

AzureActivity
| where TimeGenerated >= ago(1d)
| where OperationNameValue == "MICROSOFT.COMPUTE/VIRTUALMACHINES/WRITE" and ActivityStatusValue == "Start"
| where Authorization_d.action == "Microsoft.Compute/virtualMachines/write"
| project OperationNameValue, ActivityStatusValue, VM_Name=Properties_d.resource, ResourceGroup, SubscriptionId, Created_By=Caller

Exibir eventos do log de atividades gerados a partir da política

Exiba os 100 principais registros de todas as operações de ação de efeito executadas pelo Azure Policy.

AzureActivity
| project TimeGenerated, SubscriptionId, ResourceProviderValue, OperationNameValue, Caller, CategoryValue, CorrelationId, ActivityStatusValue, Properties_d
| where OperationNameValue has "audit"
| top 100 by TimeGenerated desc

Listar os chamadores e suas ações associadas nas últimas 48 horas

Liste os chamadores e suas ações associadas nas últimas 48 horas.

AzureActivity
| where TimeGenerated > ago(2d)
| project Caller, OperationNameValue, ActivityStatusValue, CategoryValue
| where Caller has "@"

All Azure Activity

A consulta apresenta todos os eventos AzureActivity.

AzureActivity
| project TimeGenerated, Caller, OperationName, ActivityStatus, _ResourceId

Atividade do Azure para usuário

Mostre a atividade do usuário na Atividade do Azure.

// Replace the UPN in the query with the UPN of the user of interest
let v_Users_UPN= "osotnoc@contoso.com";
AzureActivity
| where Caller == v_Users_UPN
| project TimeGenerated, Caller, OperationName, ActivityStatus

Enumeração de chave bem-sucedida

Lista os usuários que executaram a enumeração de chave e sua localização.

AzureActivity
| where OperationName == "List Storage Account Keys"
| where ActivityStatus == "Succeeded"
| project TimeGenerated, Caller, CallerIpAddress, OperationName

Início de Acesso de Rede JIT

Lista o início das permissões de acesso à rede JIT.

AzureActivity
| where OperationName == "Initiate JIT Network Access Policy"
| where ActivityStatus == "Started"

Estatísticas de operação da Atividade do Azure

Estatísticas de operações sobre a Atividade do Azure.

AzureActivity
| summarize Count=count() by OperationName, _ResourceId
| sort by Count desc nulls last