Configurar pontos de extremidade do fluxo de dados MQTT

Os pontos de extremidade do fluxo de dados MQTT são usados para origens e destinos MQTT. Você pode definir as configurações do ponto de extremidade, o protocolo TLS, a autenticação e outras configurações.

Pré-requisitos

• Uma instância das Operações do Azure IoT

Corretor MQTT local de operações do Azure IoT

O Azure IoT Operations fornece um broker MQTT local integrado que você pode usar com fluxos de dados. Você pode usar o broker MQTT como uma origem para receber mensagens de outros sistemas ou como um destino para enviar mensagens para outros sistemas.

Ponto de extremidade padrão

Quando você implanta as Operações do Azure IoT, um ponto de extremidade do fluxo de dados chamado "padrão" do Agente MQTT é criado com configurações padrão. Você pode usar esse ponto de extremidade como uma origem ou destino para fluxos de dados.

O ponto de extremidade padrão usa as seguintes configurações:

• Host: aio-broker:18883 por meio do ouvinte do Agente MQTT padrão
• Autenticação: token da conta de serviço (SAT) por meio do recurso padrão BrokerAuthentication
• TLS: habilitado
• Certificado de Autoridade de Certificação confiável: o certificado de Autoridade de Certificação padrão azure-iot-operations-aio-ca-trust-bundle da Autoridade de certificação raiz padrão

Para exibir ou editar as configurações de ponto de extremidade do Agente MQTT padrão:

param aioInstanceName string = '<AIO_INSTANCE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'

resource aioInstance 'Microsoft.IoTOperations/instances@2024-11-01' existing = {
  name: aioInstanceName
}
resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}
resource defaultMqttBrokerDataflowEndpoint 'Microsoft.IoTOperations/instances/dataflowEndpoints@2024-11-01' = {
  parent: aioInstance
  name: 'default'
  extendedLocation: {
    name: customLocation.id
    type: 'CustomLocation'
  }
  properties: {
    endpointType: 'Mqtt'
    mqttSettings: {
      host: 'aio-broker:18883'
      authentication: {
        method: 'ServiceAccountToken'
        serviceAccountTokenSettings: {
          audience: 'aio-internal'
        }
      }
      tls: {
        mode: 'Enabled'
        trustedCaCertificateConfigMapRef: 'azure-iot-operations-aio-ca-trust-bundle'
      }
    }
  }
}

az deployment group create --resource-group <RESOURCE_GROUP> --template-file <FILE>.bicep

kubectl get dataflowendpoint default -n azure-iot-operations -o yaml

Criar um novo ponto de extremidade

Você também pode criar novos pontos de extremidade do Agente MQTT local com configurações personalizadas. Por exemplo, você pode criar um novo ponto de extremidade do broker MQTT usando uma porta, autenticação ou configurações de autorização diferentes. No entanto, você ainda deve sempre usar o ponto de extremidade padrão como origem ou destino em cada fluxo de dados, mesmo se criar novos pontos de extremidade.

param aioInstanceName string = '<AIO_INSTANCE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'
param endpointName string = '<ENDPOINT_NAME>'
param mqttBrokerHostname string = '<HOSTNAME>:<PORT>'
param trustedCA string = '<TRUST_BUNDLE>'
param serviceAccountAudience string = '<SA_AUDIENCE>'

resource aioInstance 'Microsoft.IoTOperations/instances@2024-11-01' existing = {
  name: aioInstanceName
}
resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}
resource MqttBrokerDataflowEndpoint 'Microsoft.IoTOperations/instances/dataflowEndpoints@2024-11-01' = {
  parent: aioInstance
  name: endpointName
  extendedLocation: {
    name: customLocation.id
    type: 'CustomLocation'
  }
  properties: {
    endpointType: 'Mqtt'
    mqttSettings: {
      host: mqttBrokerHostname
      authentication: {
        method: 'ServiceAccountToken'
        serviceAccountTokenSettings: {
          audience: serviceAccountAudience
        }
      }
      tls: {
        mode: 'Enabled'
        trustedCaCertificateConfigMapRef: trustedCA
      }
    }
  }
}

apiVersion: connectivity.iotoperations.azure.com/v1
kind: DataflowEndpoint
metadata:
  name: <ENDPOINT_NAME>
  namespace: azure-iot-operations
spec:
  endpointType: Mqtt
  mqttSettings:
    host: "<HOSTNAME>:<PORT>"
    tls:
      mode: Enabled
      trustedCaCertificateConfigMapRef: <TRUST_BUNDLE>
    authentication:
      method: ServiceAccountToken
      serviceAccountTokenSettings:
        audience: <SA_AUDIENCE>

Grade de Eventos do Azure

A Grade de Eventos do Azure fornece um Agente MQTT totalmente gerenciado que funciona com fluxos de dados de Operações do Azure IoT. Para configurar um ponto de extremidade do Agente MQTT da Grade de Eventos do Azure, recomendamos que você use a identidade gerenciada para autenticação.

Configurar o namespace da Grade de Eventos

Se você ainda não fez isso, crie o namespace da Grade de Eventos primeiro.

Habilitar o MQTT

Depois de ter um namespace da Grade de Eventos, vá para Configuração e verifique:

• Habilitar MQTT: marque a caixa de seleção.
• Máximo de sessões de cliente por nome de autenticação: defina como 3 ou mais.

A opção de sessões máximas de cliente é importante para que os fluxos de dados possam escalar verticalmente e ainda possam se conectar. Para saber mais, consulte suporte a várias sessões MQTT da Grade de Eventos.

Criar um espaço de tópico

Para que os fluxos de dados enviem ou recebam mensagens para o Agente MQTT da Grade de Eventos, você precisa criar pelo menos um espaço de tópico no namespace da Grade de Eventos. Você pode criar um espaço de tópico no namespace da Grade de Eventos selecionando Espaços de tópico >Novo espaço de tópico.

Para começar rapidamente e testar, você pode criar um espaço de tópico com o tópico curinga # como o modelo de tópico.

Atribuir permissão à identidade gerenciada

Para configurar um ponto de extremidade de fluxo de dados para o Agente MQTT da Grade de Eventos, recomendamos usar uma identidade gerenciada atribuída pelo usuário ou atribuída pelo sistema. Essa abordagem é segura e elimina a necessidade de gerenciar credenciais manualmente.

Depois que o espaço de tópico for criado, você precisará atribuir uma função à identidade gerenciada das Operações do Azure IoT que concede permissão para enviar ou receber mensagens no Agente MQTT da Grade de Eventos.

Se estiver usando a identidade gerenciada atribuída pelo sistema, no portal do Azure, vá para a instância das Operações do Azure IoT e selecione Visão geral. Copie o nome da extensão listada após Extensão do Azure IoT Operations Arc. Por exemplo, azure-iot-operations-xxxx7. Sua identidade gerenciada atribuída pelo sistema pode ser encontrada usando o mesmo nome da extensão do Arc das Operações do Azure IoT.

Em seguida, vá para o namespace da Grade de Eventos >Controle de acesso (IAM)>Adicionar atribuição de função.

1. Na guia Função, selecione uma função apropriada como EventGrid TopicSpaces Publisher ou EventGrid TopicSpaces Subscriber. Isso fornece à identidade gerenciada as permissões necessárias para enviar ou receber mensagens para todos os espaços de tópico no namespace. Para saber mais, confira Autenticação JWT do Microsoft Entra e autorização do RBAC do Azure para publicar ou assinar mensagens MQTT.
2. Na guia Membros:
   1. Se estiver usando a identidade gerenciada atribuída pelo sistema, para Atribuir acesso a, selecione a opção usuário, grupo ou entidade de serviço, selecione + Selecionar membros e pesquise o nome da extensão Arc do serviço Operações do Azure IoT.
   2. Se estiver usando a identidade gerenciada atribuída pelo usuário, para atribuir acesso a, selecione a opção Identidade Gerenciada e selecione + Selecionar membros e procure a identidade gerenciada atribuída pelo usuário configurada para conexões de nuvem.

Como alternativa, você pode atribuir a função no nível do espaço de tópico. Vá para o espaço de tópico >Controle de acesso (IAM)>Adicionar atribuição de função. Atribua a identidade gerenciada com uma função apropriada como EventGrid TopicSpaces Publisher ou EventGrid TopicSpaces Subscriber. Isso fornece à identidade gerenciada as permissões necessárias para enviar ou receber mensagens para o espaço de tópico específico.

Criar um ponto de extremidade de fluxo de dados para o Agente MQTT da Grade de Eventos

Depois que o namespace da Grade de Eventos for configurado, você poderá criar um ponto de extremidade de fluxo de dados para o Agente MQTT da Grade de Eventos.

param aioInstanceName string = '<AIO_INSTANCE_NAME>'
param customLocationName string = '<CUSTOM_LOCATION_NAME>'
param endpointName string = '<ENDPOINT_NAME>'
param eventGridHostName string = '<NAMESPACE>.<REGION>-1.ts.eventgrid.azure.net:8883'

resource aioInstance 'Microsoft.IoTOperations/instances@2024-11-01' existing = {
  name: aioInstanceName
}
resource customLocation 'Microsoft.ExtendedLocation/customLocations@2021-08-31-preview' existing = {
  name: customLocationName
}
resource remoteMqttBrokerDataflowEndpoint 'Microsoft.IoTOperations/instances/dataflowEndpoints@2024-11-01' = {
  parent: aioInstance
  name: endpointName
  extendedLocation: {
    name: customLocation.id
    type: 'CustomLocation'
  }
  properties: {
    endpointType: 'Mqtt'
    mqttSettings: {
      host: eventGridHostName
      authentication: {
        // See available authentication methods section for method types
        // method: <METHOD_TYPE>
      }
      tls: {
        mode: 'Enabled'
      }
    }
  }
}

az deployment group create --resource-group <RESOURCE_GROUP> --template-file <FILE>.bicep

apiVersion: connectivity.iotoperations.azure.com/v1
kind: DataflowEndpoint
metadata:
  name: <ENDPOINT_NAME>
  namespace: azure-iot-operations
spec:
  endpointType: Mqtt
  mqttSettings:
    host: <NAMESPACE>.<REGION>-1.ts.eventgrid.azure.net:8883
    authentication:
      # See available authentication methods section for method types
      # method: <METHOD_TYPE>
    tls:
      mode: Enabled

kubectl apply -f <FILE>.yaml

Depois que o ponto de extremidade for criado, você poderá usá-lo em um fluxo de dados para se conectar ao Agente MQTT da Grade de Eventos como uma origem ou destino. Os tópicos do MQTT são configurados no fluxo de dados.

Use a autenticação de certificado X.509 com a Grade de Eventos

Quando você usar autenticação X.509 com um Agente MQTT da Grade de Eventos, vá para o namespace da Grade de Eventos em >Configuração e verifique as seguintes configurações:

• Habilitar MQTT: marque a caixa de seleção.
• Habilitar fontes alternativas de nome de autenticação de cliente: marque a caixa de seleção.
• Nome da Entidade do Certificado: selecione essa opção na lista suspensa.
• Máximo de sessões de cliente por nome de autenticação: defina como 3 ou mais.

As opções alternativas de autenticação de cliente e sessões máximas do cliente permitem que os fluxos de dados usem o nome da entidade do certificado do cliente para autenticação em vez de MQTT CONNECT Username. Essa funcionalidade é importante para que os fluxos de dados possam gerar várias instâncias e ainda conseguir se conectar. Para saber mais, consulte Autenticação do certificado do cliente MQTT do Grade de Eventos e Suporte para várias sessões.

Em seguida, siga as etapas em certificado X.509 para definir o ponto de extremidade com as configurações de certificado X.509.

Limitação de assinatura compartilhada da Grade de Eventos

O broker MQTT do Grade de Eventos do Azure não oferece suporte a assinaturas compartilhadas, o que significa que você não pode definir instanceCount como mais de 1 no perfil de fluxo de dados se o Event Grid for usado como uma origem (onde o fluxo de dados assina mensagens) para um fluxo de dados. Nesse caso, se você definir instanceCount como maior que 1, o fluxo de dados não será iniciado.

Agentes MQTT personalizados

Para outros Agentes do MQTT, você pode configurar o ponto de extremidade, o TLS, a autenticação e outras configurações conforme necessário.

mqttSettings: {
  authentication: {
    // See available authentication methods section for method types
    // method: <METHOD_TYPE>
  }
  host: '<HOST>:<PORT>'
  tls: {
    mode: 'Enabled' // or 'Disabled'
    trustedCaCertificateConfigMapRef: '<TRUSTED_CA_CERT_CONFIGMAP>'
  }
}

spec:
  endpointType: Mqtt
  mqttSettings:
    host: <HOST>:<PORT>
    authentication:
      # See available authentication methods section for method types
      # method: <METHOD_TYPE>
    tls:
      mode: Enabled # or Disabled
      trustedCaCertificateConfigMapRef: <TRUSTED_CA_CERT_CONFIGMAP>

Para personalizar as configurações do ponto de extremidade MQTT, consulte as seções a seguir para obter mais informações.

Métodos de autenticação disponíveis

Os métodos de autenticação a seguir estão disponíveis para pontos de extremidade do fluxo de dados do Agente MQTT.

Identidade gerenciada atribuída pelo sistema

Antes de configurar o ponto de extremidade de fluxo de dados, atribua uma função à identidade gerenciada das Operações do Azure IoT que concede permissão para se conectar ao Agente MQTT:

1. No portal do Azure, acesse sua instância do Azure IoT Operations e selecione Visão geral.
2. Copie o nome da extensão listada após Extensão do Azure IoT Operations Arc. Por exemplo, azure-iot-operations-xxxx7.
3. Vá para o recurso de nuvem que você precisa para conceder permissões. Por exemplo, acesse o namespace da Grade de Eventos >Controle de acesso (IAM)>Adicionar atribuição de função.
4. Na guia Função, selecione uma função apropriada.
5. Na guia Membros, para Atribuir acesso a, selecione Usuário, grupo ou opção de entidade de serviço e selecione + Selecionar membros e pesquise a identidade gerenciada do serviço Operações do Azure IoT. Por exemplo, azure-iot-operations-xxxx7.

Em seguida, defina o ponto de extremidade de fluxo de dados com as configurações de identidade gerenciada atribuídas pelo sistema.

mqttSettings: {
  authentication: {
    method: 'SystemAssignedManagedIdentity'
    systemAssignedManagedIdentitySettings: {}
  }
}

mqttSettings:
  authentication:
    method: SystemAssignedManagedIdentity
    systemAssignedManagedIdentitySettings:
      {}

Na maioria dos casos, ao usar isso com a Grade de Eventos, você pode deixar as configurações vazias, conforme mostrado. Isso define o público-alvo da identidade gerenciada para o público-alvo comum da Grade de Eventos https://eventgrid.azure.net. Se você precisar definir um público-alvo diferente, poderá especificá-lo nas configurações.

mqttSettings: {
  authentication: {
    method: 'SystemAssignedManagedIdentity'
    systemAssignedManagedIdentitySettings: {
      audience: 'https://<AUDIENCE>'
    }
  }
}

mqttSettings:
  authentication:
    method: SystemAssignedManagedIdentity
    systemAssignedManagedIdentitySettings:
      audience: https://<AUDIENCE>

Identidade gerenciada atribuída pelo usuário

Para usar a identidade gerenciada atribuída pelo usuário para autenticação, primeiro você precisa implantar as Operações do Azure IoT com as configurações seguras habilitadas. Em seguida, você precisa configurar uma identidade gerenciada atribuída pelo usuário para conexões de nuvem. Para saber mais, confira Habilitar configurações seguras na implantação das Operações do Azure IoT.

Antes de configurar o ponto de extremidade de fluxo de dados, atribua uma função à identidade gerenciada atribuída pelo usuário que concede permissão para se conectar ao Agente MQTT:

1. No portal do Azure, vá para o recurso de nuvem que você precisa para conceder permissões. Por exemplo, acesse o namespace da Grade de Eventos >Controle de acesso (IAM)>Adicionar atribuição de função.
2. Na guia Função, selecione uma função apropriada.
3. Na guia Membros, para Atribuir acesso a, selecione a opção Identidade Gerenciada e selecione + Selecionar membros e pesquise sua identidade gerenciada atribuída pelo usuário.

Em seguida, defina o ponto de extremidade de fluxo de dados com as configurações de identidade gerenciada atribuídas pelo usuário.

mqttSettings: {
  authentication: {
    method: 'UserAssignedManagedIdentity'
    userAssignedManagedIdentitySettings: {
      clientId: '<ID>'
      tenantId: '<ID>'
      // Optional, defaults to 'https://eventgrid.azure.net/.default'
      // scope: 'https://<SCOPE_URL>' 
    }
  }
}

mqttSettings:
  authentication:
    method: UserAssignedManagedIdentity
    userAssignedManagedIdentitySettings:
      clientId: <ID>
      tenantId: <ID>
      # Optional, defaults to 'https://eventgrid.azure.net/.default'
      # scope: https://<SCOPE_URL>

Aqui, o escopo é opcional e usa como padrão https://eventgrid.azure.net/.default que funciona para todos os namespaces da Grade de Eventos do Azure. Se você precisar definir um escopo diferente, poderá especificá-lo nas configurações por meio do Bicep ou do Kubernetes.

Token da conta de serviço do Kubernetes (SAT)

Para usar o token da conta de serviço do Kubernetes (SAT) para autenticação, você não precisa criar um segredo. O SAT é usado para autenticar com o Agente MQTT ao corresponder o público-alvo.

mqttSettings: {
  authentication: {
    method: 'ServiceAccountToken'
    serviceAccountTokenSettings: {
      audience: '<YOUR_SERVICE_ACCOUNT_AUDIENCE>'
    }
  }
}

mqttSettings:
  authentication:
    method: ServiceAccountToken
    serviceAccountTokenSettings:
      audience: <YOUR_SERVICE_ACCOUNT_AUDIENCE>

Certificado X.509

Muitos agentes MQTT, como a Grade de Eventos, dão suporte à autenticação X.509. Os fluxos de dados podem apresentar um certificado X.509 do cliente e negociar a comunicação TLS.

O certificado e a chave privada precisam estar no formato PEM e não protegidos por senha.

Antes de configurar o ponto de extremidade do fluxo de dados, crie um segredo com o certificado e a chave privada.

• Se você usar o portal de operações, o segredo será automaticamente formatado e sincronizado com o cluster do Kubernetes.

• Se você usar o Bicep ou o Kubernetes, crie manualmente o segredo com o certificado e a chave privada no mesmo namespace do ponto de extremidade do fluxo de dados do MQTT.

  kubectl create secret generic <X509_SECRET_NAME> -n azure-iot-operations --from-file=client_cert.pem=<CLIENT_CERT_FILE>.pem --from-file=client_key.pem=<PRIVATE_KEY_FILE>.pem --from-file=client_intermediate_certs.pem=<INTERMEDIATE_CERT_FILE>.pem
  

  Aqui, o segredo precisa ter client_cert.pem e client_key.pem como os nomes de chaves para o certificado e a chave privada. Opcionalmente, o segredo também pode ter client_intermediate_certs.pem como o nome da chave para os certificados intermediários.

mqttSettings: {
  authentication: {
    method: 'X509Certificate'
      x509CertificateSettings:
        secretRef: '<X509_SECRET_NAME>'
  }
}

mqttSettings:
  authentication:
    method: X509Certificate
    x509CertificateSettings:
      secretRef: <X509_SECRET_NAME>

Anônimo

Para usar a autenticação anônima, defina o método de autenticação como Anonymous.

mqttSettings: {
  authentication: {
    method: 'Anonymous'
  }
}

mqttSettings:
  authentication:
    method: Anonymous
    anonymousSettings:
      {}

Configurações avançadas

Você pode definir configurações avançadas para o ponto de extremidade do fluxo de dados do Agente MQTT, como TLS, certificado de Autoridade de Certificação confiável, configurações de mensagens do MQTT e CloudEvents. Você pode definir essas configurações na guia do portal Avançado no ponto de extremidade do fluxo de dados, dentro do recurso personalizado do ponto de extremidade de fluxo de dados.

// See sections below for explanation of each setting
mqttSettings: {
  qos: 1
  retain: 'Keep'
  sessionExpirySeconds: 3600
  keepAliveSeconds: 60
  maxInflightMessages: 100
  protocol: WebSockets
  clientIdPrefix: 'dataflow'
  cloudEventAttributes : 'Propagate' // or 'CreateOrRemap'
}

# See sections below for explanation of each setting
mqttSettings:
  qos: 1
  retain: Keep
  sessionExpirySeconds: 3600
  keepAliveSeconds: 60
  maxInflightMessages: 100
  protocol: WebSockets
  clientIdPrefix: dataflow
  cloudEventAttributes : Propagate # or CreateOrRemap

Configurações de protocolo TLS

Modo TLS

Para habilitar ou desabilitar o TLS para o ponto de extremidade do MQTT, atualize a configuração mode nas configurações do TLS.

mqttSettings: {
  tls: {
    mode: 'Enabled' // or 'Disabled'
  }
}

mqttSettings:
  tls:
    mode: Enabled # or Disabled

O modo TLS pode ser definido como Enabled ou Disabled. Se o modo estiver definido como Enabled, o fluxo de dados usará uma conexão segura com o Agente MQTT. Se o modo estiver definido como Disabled, o fluxo de dados usará uma conexão não segura com o Agente MQTT.

Certificado de Autoridade de Certificação confiável

Configure o Certificado de Autoridade de Certificação Confiável para o ponto de extremidade MQTT para estabelecer uma conexão segura com o Agente MQTT. Essa configuração é importante se o Agente MQTT usar um certificado autoassinado ou um certificado assinado por uma AC personalizada que não é confiável por padrão.

mqttSettings: {
  tls: {
    trustedCaCertificateConfigMapRef: '<YOUR_CA_CERTIFICATE>'
  }
}

mqttSettings:
  tls:
    trustedCaCertificateConfigMapRef: <YOUR_CA_CERTIFICATE>

Esse ConfigMap deve conter o Certificado de Autoridade de Certificação no formato PEM. O ConfigMap deve estar no mesmo namespace que o recurso de fluxo de dados do MQTT. Por exemplo:

kubectl create configmap client-ca-configmap --from-file root_ca.crt -n azure-iot-operations

Prefixo da ID do cliente

Você pode definir um prefixo da ID do cliente para o cliente MQTT. A ID do cliente é gerada acrescentando o nome da instância do fluxo de dados ao prefixo.

mqttSettings: {
  clientIdPrefix: '<YOUR_PREFIX>'
}

mqttSettings:
  clientIdPrefix: <YOUR_PREFIX>

QoS

Você pode definir o nível de QoS para as mensagens MQTT como 1 ou 0. O padrão é 1.

mqttSettings: {
  qos: 1 // Or 0
}

mqttSettings:
  qos: 1 # Or 0

Manter

Use a configuração retain para especificar se o fluxo de dados devem manter o sinalizador retain em mensagens MQTT. O padrão é Keep.

Definir esse campo como Keep é útil para garantir que o agente remoto tenha as mesmas mensagens retidas que o agente local, o que pode ser importante para cenários de UNS (Unified Namespace).

Se definido como Never, o sinalizador retain será removido das mensagens MQTT. Isso pode ser útil quando você não quiser que o agente remoto retenha mensagens ou se o agente remoto não der suporte à retenção.

Para definir as configurações de retenção:

mqttSettings: {
  retain: Keep // or Never
}

mqttSettings:
  retain: Keep # or Never

A configuração retain só entrará em vigor se o fluxo de dados usar o ponto de extremidade MQTT como origem e destino. Por exemplo, em um cenário de ponte MQTT.

Expiração da sessão

Você pode definir o intervalo de expiração da sessão para o cliente MQTT do fluxo de dados. O intervalo de expiração da sessão é o tempo máximo que uma sessão MQTT é mantida se o cliente do fluxo de dados se desconectar. O padrão é 600 segundos. Para configurar o intervalo de expiração da sessão:

mqttSettings: {
  sessionExpirySeconds: 600
}

mqttSettings:
  sessionExpirySeconds: 600

Protocolo WebSockets ou MQTT

Por padrão, WebSockets não está habilitado. Para usar o MQTT em vez de WebSockets, defina o campo protocol como WebSockets.

mqttSettings: {
  protocol: 'WebSockets'
}

mqttSettings:
  protocol: WebSockets

Máximo de mensagens em andamento

Você pode definir o número máximo de mensagens em andamento que o cliente MQTT do fluxo de dados pode ter. O padrão é 100.

mqttSettings: {
  maxInflightMessages: 100
}

mqttSettings:
  maxInflightMessages: 100

Para assinar quando o ponto de extremidade MQTT é usado como uma origem, esse é o máximo de recebimento. Para publicar quando o ponto de extremidade MQTT for usado como destino, esse é o número máximo de mensagens a serem enviadas antes de aguardar uma confirmação.

Keep alive

Você pode definir o intervalo keep alive para o cliente MQTT do fluxo de dados. O intervalo keep alive é o tempo máximo que o cliente do fluxo de dados pode ficar ocioso antes de enviar uma mensagem PINGREQ ao agente. O padrão é 60 segundos.

mqttSettings: {
  keepAliveSeconds: 60
}

mqttSettings:
  keepAliveSeconds: 60

CloudEvents

CloudEvents são uma maneira de descrever dados de evento de maneira comum. As configurações de CloudEvents são usadas para enviar ou receber mensagens no formato CloudEvents. Você pode usar CloudEvents para arquiteturas orientadas por eventos em que diferentes serviços precisam se comunicar entre si nos mesmos provedores de nuvem ou em provedores de nuvem diferentes.

As opções de cloudEventAttributes são Propagate ou CreateOrRemap. Para definir as configurações do CloudEvents:

mqttSettings: {
  cloudEventAttributes : 'Propagate' // or 'CreateOrRemap'
}

mqttSettings:
  cloudEventAttributes : Propagate # or CreateOrRemap

As seções a seguir fornecem mais informações sobre as configurações do CloudEvents.

Configuração Propagar

As propriedades do CloudEvent são passadas para mensagens que contêm as propriedades necessárias. Se a mensagem não contiver as propriedades necessárias, a mensagem será passada como está.

Configuração CreateOrRemap

As propriedades do CloudEvent são passadas para mensagens que contêm as propriedades necessárias. Se a mensagem não contiver as propriedades necessárias, as propriedades serão geradas.

Próximas etapas

Para saber mais sobre fluxos de dados, confira Criar um fluxo de dados.