Guia de Início Rápido: Criar um perfil do Gerenciador de Tráfego usando o Bicep

Este guia de início rápido descreve como usar o Bicep para criar um perfil do Gerenciador de Tráfego com pontos de extremidade externos usando o método de roteamento de desempenho.

O Bicep é um DSL (linguagem específica de domínio) que usa sintaxe declarativa para implantar recursos do Azure. Ele fornece sintaxe concisa, segurança de tipos confiável e suporte para reutilização de código. O Bicep oferece a melhor experiência de criação para suas soluções de infraestrutura como código no Azure.

Pré-requisitos

Se você não tiver uma assinatura do Azure, crie uma conta gratuita antes de começar.

Examinar o arquivo Bicep

O arquivo Bicep usado neste guia de início rápido vem dos Modelos de início rápido do Azure.

@description('Relative DNS name for the traffic manager profile, must be globally unique.')
param uniqueDnsName string

resource ExternalEndpointExample 'Microsoft.Network/trafficmanagerprofiles@2022-04-01' = {
  name: 'ExternalEndpointExample'
  location: 'global'
  properties: {
    profileStatus: 'Enabled'
    trafficRoutingMethod: 'Performance'
    dnsConfig: {
      relativeName: uniqueDnsName
      ttl: 30
    }
    monitorConfig: {
      protocol: 'HTTPS'
      port: 443
      path: '/'
      expectedStatusCodeRanges: [
        {
          min: 200
          max: 202
        }
        {
          min: 301
          max: 302
        }
      ]
    }
    endpoints: [
      {
        type: 'Microsoft.Network/TrafficManagerProfiles/ExternalEndpoints'
        name: 'endpoint1'
        properties: {
          target: 'www.microsoft.com'
          endpointStatus: 'Enabled'
          endpointLocation: 'northeurope'
        }
      }
      {
        type: 'Microsoft.Network/TrafficManagerProfiles/ExternalEndpoints'
        name: 'endpoint2'
        properties: {
          target: 'docs.microsoft.com'
          endpointStatus: 'Enabled'
          endpointLocation: 'southcentralus'
        }
      }
    ]
  }
}
output name string = ExternalEndpointExample.name
output resourceGroupName string = resourceGroup().name
output resourceId string = ExternalEndpointExample.id

Um recurso do Azure é definido no arquivo Bicep:

• Microsoft.Network/trafficManagerProfiles

Implante o arquivo Bicep

1. Salve o arquivo Bicep como main.bicep em seu computador local.

2. Para implantar o arquivo Bicep, use a CLI do Azure ou o Azure PowerShell.

   • CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters uniqueDnsName=<dns-name>
   

   A implantação de arquivo Bicep cria um perfil com dois pontos de extremidade externos. Endpoint1 usa o ponto de extremidade de destino www.microsoft.com com a localização Norte da Europa. Endpoint2 usa o ponto de extremidade de destino learn.microsoft.com com a localização no Centro-Sul dos EUA.

   Observação

   uniqueDNSname precisa ser um nome globalmente exclusivo para que o arquivo Bicep seja implantado com êxito.

   Quando a implantação for concluída, uma mensagem será exibida indicando que a implantação foi realizada com sucesso.

Validar a implantação

Use a CLI do Azure ou o Azure PowerShell para validar a implantação.

1. Determine o nome DNS do perfil do Gerenciador de Tráfego.

   • CLI
   • PowerShell

   az network traffic-manager profile show --name ExternalEndpointExample --resource-group exampleRG 
   

   Na saída, copie o valor de fqdn. Ele estará no seguinte formato: <relativeDnsName>.trafficmanager.net. Esse valor também é o nome DNS do seu perfil do Gerenciador de Tráfego.

2. Execute o comando a seguir substituindo a variável {relativeDnsName} por <relativeDnsName>.trafficmanager.net.

   • CLI
   • PowerShell

   nslookup -type=cname {relativeDnsName}
   

   Você obterá um nome canônico igual a www.microsoft.com ou learn.microsoft.com, dependendo da região que está mais perto de você.

3. Para verificar se você pode resolver o endereço para o outro ponto de extremidade, desabilite o ponto de extremidade no destino obtido na última etapa. Substitua o {endpointName} por endpoint1 ou endpoint2 para desabilitar o destino para www.microsoft.com ou learn.microsoft.com, respectivamente.

   • CLI
   • PowerShell

   az network traffic-manager endpoint update --name {endpointName} --type externalEndpoints --profile-name ExternalEndpointExample --resource-group exampleRG --endpoint-status "Disabled"
   

4. Execute o comando da Etapa 2 novamente na CLI do Azure ou no Azure PowerShell. Desta vez, você obterá o outro nome canônico/NameHost para o outro ponto de extremidade.

Limpar os recursos

Quando não precisar mais do perfil do Gerenciador de Tráfego, use o portal do Azure, a CLI do Azure ou o Azure PowerShell para excluir o grupo de recursos. Isso removerá o perfil do Gerenciador de Tráfego e todos os recursos relacionados.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Próximas etapas

Neste guia de início rápido, você criou um perfil do Gerenciador de Tráfego usando o Bicep.

Para saber mais sobre o encaminhamento de tráfego, prossiga para os tutoriais do Gerenciador de Tráfego.