Operações de projeção (Visual Basic)

Projeção refere-se à operação de transformar um objeto em um novo formulário que geralmente consiste apenas nas propriedades que serão usadas posteriormente. Usando a projeção, você pode construir um novo tipo que é criado de cada objeto. É possível projetar uma propriedade e executar uma função matemática nela. Também é possível projetar o objeto original sem alterá-lo.

Os métodos de operador de consulta padrão que realizam a projeção estão listados na seção a seguir.

Métodos

Exemplos de sintaxe de expressão de consulta

Selecionar

O exemplo a seguir usa a cláusula Select para projetar a primeira letra de cada cadeia de caracteres em uma lista de cadeias de caracteres.

Dim words = New List(Of String) From {"an", "apple", "a", "day"}

Dim query = From word In words
            Select word.Substring(0, 1)

Dim sb As New System.Text.StringBuilder()
For Each letter As String In query
    sb.AppendLine(letter)
Next

' Display the output.
MsgBox(sb.ToString())

' This code produces the following output:

' a
' a
' a
' d

SelectMany

O exemplo a seguir usa várias cláusulas From para projetar cada palavra de cada cadeia de caracteres em uma lista de cadeias de caracteres.

Dim phrases = New List(Of String) From {"an apple a day", "the quick brown fox"}

Dim query = From phrase In phrases
            From word In phrase.Split(" "c)
            Select word

Dim sb As New System.Text.StringBuilder()
For Each str As String In query
    sb.AppendLine(str)
Next

' Display the output.
MsgBox(sb.ToString())

' This code produces the following output:

' an
' apple
' a
' day
' the
' quick
' brown
' fox

Select versus SelectMany

O trabalho de Select() e SelectMany() é produzir um valor (ou valores) de resultado dos valores de origem. Select() produz um valor de resultado para cada valor de origem. O resultado geral, portanto, é uma coleção que tem o mesmo número de elementos que a coleção de origem. Por outro lado, SelectMany() produz um único resultado geral que contém subcoleções concatenadas de cada valor de origem. A função de transformação passada como um argumento para SelectMany() deve retornar uma sequência enumerável de valores para cada valor de origem. Essas sequências enumeráveis, então, são concatenadas por SelectMany() para criar uma sequência grande.

As duas ilustrações a seguir mostram a diferença conceitual entre as ações desses dois métodos. Em cada caso, presuma que a função de seletor (transformação) seleciona a matriz de flores de cada valor de origem.

A ilustração mostra como Select() retorna uma coleção que tem o mesmo número de elementos que a coleção de origem.

Esta ilustração mostra como SelectMany() concatena a sequência intermediária de matrizes em um valor de resultado final que contém cada valor de cada matriz intermediária.

Exemplo de código

O exemplo a seguir compara o comportamento de Select() e de SelectMany(). O código cria um "buquê" de flores usando os itens de cada lista de nomes de flor na coleção de fonte. Neste exemplo, o "valor único" que a função de transformação Select<TSource,TResult>(IEnumerable<TSource>, Func<TSource,TResult>) usa é uma coleção de valores. Isso requer o loop For Each extra para enumerar cada cadeia de caracteres em cada subsequência.

Class Bouquet
    Public Flowers As List(Of String)
End Class

Sub SelectVsSelectMany()
    Dim bouquets = New List(Of Bouquet) From {
        New Bouquet With {.Flowers = New List(Of String)(New String() {"sunflower", "daisy", "daffodil", "larkspur"})},
        New Bouquet With {.Flowers = New List(Of String)(New String() {"tulip", "rose", "orchid"})},
        New Bouquet With {.Flowers = New List(Of String)(New String() {"gladiolis", "lily", "snapdragon", "aster", "protea"})},
        New Bouquet With {.Flowers = New List(Of String)(New String() {"larkspur", "lilac", "iris", "dahlia"})}}

    Dim output As New System.Text.StringBuilder

    ' Select()
    Dim query1 = bouquets.Select(Function(b) b.Flowers)

    output.AppendLine("Using Select():")
    For Each flowerList In query1
        For Each str As String In flowerList
            output.AppendLine(str)
        Next
    Next

    ' SelectMany()
    Dim query2 = bouquets.SelectMany(Function(b) b.Flowers)

    output.AppendLine(vbCrLf & "Using SelectMany():")
    For Each str As String In query2
        output.AppendLine(str)
    Next

    ' Display the output
    MsgBox(output.ToString())

    ' This code produces the following output:
    '
    ' Using Select():
    ' sunflower
    ' daisy
    ' daffodil
    ' larkspur
    ' tulip
    ' rose
    ' orchid
    ' gladiolis
    ' lily
    ' snapdragon
    ' aster
    ' protea
    ' larkspur
    ' lilac
    ' iris
    ' dahlia

    ' Using SelectMany()
    ' sunflower
    ' daisy
    ' daffodil
    ' larkspur
    ' tulip
    ' rose
    ' orchid
    ' gladiolis
    ' lily
    ' snapdragon
    ' aster
    ' protea
    ' larkspur
    ' lilac
    ' iris
    ' dahlia

End Sub

Confira também

• System.Linq
• Visão geral de operadores de consulta padrão (Visual Basic)
• Cláusula Select
• Como combinar dados com junções
• Como preencher coleções de objetos de várias fontes (LINQ) (Visual Basic)
• Como retornar um resultado de consulta LINQ como um tipo específico
• Como dividir um arquivo em vários arquivos usando grupos (LINQ) (Visual Basic)