Visualizações geoespaciais

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Os dados geoespaciais podem ser visualizados usando o operador de renderização no Kusto Desktop Explorer. Para baixar o Kusto Desktop Explorer, consulte Instalação e interface do usuário do Kusto.Explorer.

Para obter mais informações sobre clustering geoespacial, consulte Clustering geoespacial.

Visualizar pontos em um mapa

Você pode visualizar pontos usando colunas [Longitude, Latitude] ou coluna GeoJSON. O uso de uma coluna de série é opcional. O par [Longitude, Latitude] define cada ponto, nessa ordem.

Exemplo: Visualizar pontos em um mapa

O exemplo a seguir localiza eventos de tempestade e visualiza 100 em um mapa.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

Exemplo: Visualizar várias séries de pontos em um mapa

O exemplo a seguir visualiza várias séries de pontos, em que o par [Longitude, Latitude] define cada ponto e uma terceira coluna define a série. Neste exemplo, a série é EventType.

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

Exemplo: Visualizar séries de pontos em dados com várias colunas

O exemplo a seguir visualiza uma série de pontos em um mapa. Se você tiver várias colunas no resultado, deverá especificar as colunas a serem usadas para xcolumn (Longitude), ycolumn (Latitude) e series.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

Exemplo: Visualizar pontos em um mapa definido por valores dinâmicos GeoJSON

O exemplo a seguir visualiza pontos no mapa usando valores dinâmicos GeoJSON para definir os pontos.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

Visualização de tortas ou bolhas em um mapa

Você pode visualizar pizzas ou bolhas usando colunas [Longitude, Latitude] ou coluna GeoJSON. Essas visualizações podem ser criadas com eixos numéricos ou coloridos.

Exemplo: visualizar gráficos de pizza por local

O exemplo a seguir mostra eventos de tempestade agregados por célula S2. O gráfico agrega eventos em gráficos de pizza por local.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map) // pie map rendering available only in Kusto Explorer desktop

Exemplo: Visualize bolhas usando um eixo de cores

O exemplo a seguir mostra eventos de tempestade agregados por célula S2. O gráfico agrega eventos em bolha por local. Como o eixo de cor ("count") é o mesmo para todos os eventos, o render operador gera bolhas.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map) // pie map rendering available only in Kusto Explorer desktop

Conteúdo relacionado

• Clustering geoespacial
• Operador de renderização
• Análise de dados para frotas de teste automotivo (caso de uso de clustering geoespacial)
• Saiba mais sobre a arquitetura do Azure para processamento e análise de dados geoespaciais