Compartilhar via

ipv6_compare()

  • Artigo

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Compara duas cadeias de caracteres de endereço de rede IPv6 ou IPv4. As duas cadeias de caracteres IPv6 são analisadas e comparadas ao considerar a máscara de prefixo IP combinada calculada a partir de prefixos de argumento e o argumento opcional prefix .

Observação

A função pode aceitar e comparar argumentos que representam endereços de rede IPv6 e IPv4. No entanto, se o chamador souber que os argumentos estão no formato IPv4, use a função ipv4_is_compare(). Essa função resultará em melhor desempenho de tempo de execução.

Sintaxe

ipv6_compare(Prefixo IP1,IP2[ ,])

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Nome Digitar Obrigatória Descrição
IP1, IP2 string ✔️ Uma expressão que representa um endereço IPv6 ou IPv4. As strings IPv6 e IPv4 podem ser mascaradas usando a notação de prefixo IP.
prefixo int Um número inteiro de 0 a 128 que representa o número de bits mais significativos que são levados em consideração.

Notação de prefixo IP

A notação de prefixo IP (também conhecida como notação CIDR) é uma maneira concisa de representar um endereço IP e sua máscara de rede associada. O formato é <base IP>/<prefix length>, onde o comprimento do prefixo é o número de bits 1 à esquerda na máscara de rede. O comprimento do prefixo determina o intervalo de endereços IP que pertencem à rede.

Para IPv4, o comprimento do prefixo é um número entre 0 e 32. Portanto, a notação 192.168.2.0/24 representa o endereço IP 192.168.2.0 com uma máscara de rede de 255.255.255.0. Essa máscara de rede tem 24 bits 1 à esquerda ou um comprimento de prefixo de 24.

Para IPv6, o comprimento do prefixo é um número entre 0 e 128. Portanto, a notação fe80::85d:e82c:9446:7994/120 representa o endereço IP fe80::85d:e82c:9446:7994 com uma máscara de rede de ffff:ffff:ffff:ffff:ffff:ffff:ffff:ff00. Essa máscara de rede tem 120 bits 1 à esquerda ou um comprimento de prefixo de 120.

Devoluções

  • 0: Se a representação longa do primeiro argumento de cadeia de caracteres IPv6 for igual ao segundo argumento de cadeia de caracteres IPv6.
  • 1: Se a representação longa do primeiro argumento de cadeia de caracteres IPv6 for maior que o segundo argumento de cadeia de caracteres IPv6.
  • -1: Se a representação longa do primeiro argumento de cadeia de caracteres IPv6 for menor que o segundo argumento de cadeia de caracteres IPv6.
  • null: Se a conversão de uma das duas cadeias de caracteres IPv6 não for bem-sucedida.

Exemplos: casos de igualdade de comparação IPv6/IPv4

Compare IPs usando a notação de prefixo IP especificada dentro das strings IPv6/IPv4

datatable(ip1_string:string, ip2_string:string)
[
 // IPv4 are compared as IPv6 addresses
 '192.168.1.1',    '192.168.1.1',       // Equal IPs
 '192.168.1.1/24', '192.168.1.255',     // 24 bit IP4-prefix is used for comparison
 '192.168.1.1',    '192.168.1.255/24',  // 24 bit IP4-prefix is used for comparison
 '192.168.1.1/30', '192.168.1.255/24',  // 24 bit IP4-prefix is used for comparison
  // IPv6 cases
 'fe80::85d:e82c:9446:7994', 'fe80::85d:e82c:9446:7994',         // Equal IPs
 'fe80::85d:e82c:9446:7994/120', 'fe80::85d:e82c:9446:7998',     // 120 bit IP6-prefix is used for comparison
 'fe80::85d:e82c:9446:7994', 'fe80::85d:e82c:9446:7998/120',     // 120 bit IP6-prefix is used for comparison
 'fe80::85d:e82c:9446:7994/120', 'fe80::85d:e82c:9446:7998/120', // 120 bit IP6-prefix is used for comparison
 // Mixed case of IPv4 and IPv6
 '192.168.1.1',      '::ffff:c0a8:0101', // Equal IPs
 '192.168.1.1/24',   '::ffff:c0a8:01ff', // 24 bit IP-prefix is used for comparison
 '::ffff:c0a8:0101', '192.168.1.255/24', // 24 bit IP-prefix is used for comparison
 '::192.168.1.1/30', '192.168.1.255/24', // 24 bit IP-prefix is used for comparison
]
| extend result = ipv6_compare(ip1_string, ip2_string)

Saída

ip1_string ip2_string result
192.168.1.1 192.168.1.1 0
192.168.1.1/24 192.168.1.255 0
192.168.1.1 192.168.1.255/24 0
192.168.1.1/30 192.168.1.255/24 0
fe80::85d:e82c:9446:7994 fe80::85d:e82c:9446:7994 0
fe80::85d:e82c:9446:7994/120 fe80::85d:e82c:9446:7998 0
fe80::85d:e82c:9446:7994 fe80::85d:e82c:9446:7998/120 0
fe80::85d:e82c:9446:7994/120 fe80::85d:e82c:9446:7998/120 0
192.168.1.1 ::ffff:c0a8:0101 0
192.168.1.1/24 ::ffff:c0a8:01ff 0
::ffff:c0a8:0101 192.168.1.255/24 0
::192.168.1.1/30 192.168.1.255/24 0

Compare IPs usando a notação de prefixo IP especificada dentro das strings IPv6/IPv4 e como argumento adicional da ipv6_compare() função

datatable(ip1_string:string, ip2_string:string, prefix:long)
[
 // IPv4 are compared as IPv6 addresses 
 '192.168.1.1',    '192.168.1.0',   31, // 31 bit IP4-prefix is used for comparison
 '192.168.1.1/24', '192.168.1.255', 31, // 24 bit IP4-prefix is used for comparison
 '192.168.1.1',    '192.168.1.255', 24, // 24 bit IP4-prefix is used for comparison
   // IPv6 cases
 'fe80::85d:e82c:9446:7994', 'fe80::85d:e82c:9446:7995',     127, // 127 bit IP6-prefix is used for comparison
 'fe80::85d:e82c:9446:7994/127', 'fe80::85d:e82c:9446:7998', 120, // 120 bit IP6-prefix is used for comparison
 'fe80::85d:e82c:9446:7994/120', 'fe80::85d:e82c:9446:7998', 127, // 120 bit IP6-prefix is used for comparison
 // Mixed case of IPv4 and IPv6
 '192.168.1.1/24',   '::ffff:c0a8:01ff', 127, // 127 bit IP6-prefix is used for comparison
 '::ffff:c0a8:0101', '192.168.1.255',    120, // 120 bit IP6-prefix is used for comparison
 '::192.168.1.1/30', '192.168.1.255/24', 127, // 120 bit IP6-prefix is used for comparison
]
| extend result = ipv6_compare(ip1_string, ip2_string, prefix)

Saída

ip1_string ip2_string prefixo result
192.168.1.1 192.168.1.0 31 0
192.168.1.1/24 192.168.1.255 31 0
192.168.1.1 192.168.1.255 24 0
fe80::85d:e82c:9446:7994 fe80::85d:e82c:9446:7995 127 0
FE80::85D:E82C:9446:7994/127 fe80::85d:e82c:9446:7998 120 0
fe80::85d:e82c:9446:7994/120 fe80::85d:e82c:9446:7998 127 0
192.168.1.1/24 ::ffff:c0a8:01ff 127 0
::ffff:c0a8:0101 192.168.1.255 120 0
::192.168.1.1/30 192.168.1.255/24 127 0

Conteúdo relacionado