Valores nulos

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Todos os tipos de dados escalares no Kusto têm um valor especial que representa um valor ausente. Esse valor é chamado de valor nulo ou nulo.

Literais nulos

O valor nulo de um tipo escalar T é representado na linguagem de consulta pelo literal T(null)nulo .

A consulta a seguir retorna uma única linha cheia de valores nulos:

print bool(null), datetime(null), dynamic(null), guid(null), int(null), long(null), real(null), double(null), timespan(null)

Predicados em valores nulos

A função isnull() escalar pode ser usada para determinar se um valor escalar é o valor nulo. A função isnotnull() correspondente pode ser usada para determinar se um valor escalar não é o valor nulo.

Igualdade e desigualdade de valores nulos

• Igualdade (==): Aplicar o operador de igualdade a dois valores nulos produz bool(null). A aplicação do operador de igualdade a um valor nulo e a um valor não nulo produz bool(false).
• Desigualdade (!=): Aplicar o operador de desigualdade a dois valores nulos produz bool(null). Aplicar o operador de desigualdade a um valor nulo e a um valor não nulo produz bool(true).

Por exemplo:

datatable(val:int)[5, int(null)]
| extend IsBiggerThan3 = val > 3
| extend IsBiggerThan3OrNull = val > 3 or isnull(val)
| extend IsEqualToNull = val == int(null)
| extend IsNotEqualToNull = val != int(null)

Saída

Valores nulos e funções de agregação

Ao aplicar os seguintes operadores a entidades que incluem valores nulos, os valores nulos são ignorados e não são considerados no cálculo:

• count()
• count_distinct()
• countif()
• dcount()
• dcountif()
• make_bag()
• make_bag_if()
• make_list()
• make_list_if()
• make_set()
• make_set_if()
• stdev()
• stdevif()
• sum()
• sumif()
• variance()
• variaçãose()

Valores nulos e o where operador

O operador where usa expressões booleanas para determinar se cada registro de entrada deve ser emitido para a saída. Esse operador trata valores nulos como se fossem bool(false). Os registros para os quais o predicado retorna o valor nulo são descartados e não aparecem na saída.

Por exemplo:

datatable(ival:int, sval:string)[5, "a", int(null), "b"]
| where ival != 5

Saída

Valores nulos e operadores binários

Operadores binários são operadores escalares que aceitam dois valores escalares e produzem um terceiro valor. Por exemplo, maior que (>) e booleano AND (&&) são operadores binários.

Para todos os operadores binários, exceto conforme observado em Exceções a esta regra, a regra é a seguinte:

Se um ou ambos os valores de entrada para o operador binário forem valores nulos, a saída do operador binário também será o valor nulo. Em outras palavras, o valor nulo é "sticky".

Exceções a esta regra

• Para os operadores de igualdade (==) e desigualdade (!=), se um dos valores for nulo e o outro valor não for nulo, o resultado será ou bool(false) bool(true), respectivamente.
• Para o operador lógico AND (&&), se um dos valores for bool(false), o resultado também bool(false)será .
• Para o operador lógico OR (||), se um dos valores for bool(true), o resultado também bool(true)será .

Por exemplo:

datatable(val:int)[5, int(null)]
| extend Add = val + 10
| extend Multiply = val * 10

Saída

Valores nulos e o operador lógico NOT (!)

O operador lógico NOT not() produz o valor bool(null) se o argumento for o valor nulo.

Valores nulos e o in operador

• O operador in se comporta como um OR lógico de comparações de igualdade.
• O !in operador se comporta como uma lógica AND de comparações de desigualdade.

Valores nulos e ingestão de dados

Para a maioria dos tipos de dados, um valor ausente na fonte de dados produz um valor nulo na célula da tabela correspondente. No entanto, colunas de tipo string e formatos de dados CSV (ou CSV) são uma exceção a essa regra, e um valor ausente produz uma cadeia de caracteres vazia.

Por exemplo:

.create table T(a:string, b:int)

.ingest inline into table T
[,]
[ , ]
[a,1]

T
| project a, b, isnull_a=isnull(a), isempty_a=isempty(a), stlen_a=strlen(a), isnull_b=isnull(b)

Saída