Tutorial: Unir dados de várias tabelas

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A junção de dados de várias tabelas permite uma análise mais abrangente, combinando informações de diferentes fontes e criando novas relações entre os pontos de dados. Na KQL (Linguagem de Consulta Kusto), os operadores de junção e pesquisa são usados para combinar dados entre tabelas.

Neste tutorial, você aprenderá como:

Pré-requisitos

Para executar as consultas a seguir, você precisa de um ambiente de consulta com acesso aos dados de exemplo. Você pode usar um dos itens a seguir:

Usar o operador de junção

Há duas tabelas no banco de dados Samples relacionadas a eventos de tempestade. Um é chamado StormEvents e o outro é chamado PopulationDatade . Nesta seção, você unirá as tabelas para realizar análises de dados que não seriam possíveis com uma tabela sozinha.

Entender os dados

Use o operador take para ver quais dados cada tabela contém.

StormEvents 
| take 5

A tabela a seguir mostra apenas 6 das 22 colunas retornadas.

PopulationData 
| take 5

Saída

Ambas as tabelas contêm uma State coluna. A StormEvents tabela tem muito mais colunas e tem PopulationData apenas uma outra coluna que contém a população do estado especificado.

Junte-se às tabelas

Junte-se à PopulationData tabela na StormEvents coluna comum State para encontrar o total de danos materiais causados por tempestades per capita por estado.

StormEvents
| summarize PropertyDamage = sum(DamageProperty) by State
| join kind=innerunique PopulationData on State
| project State, PropertyDamagePerCapita = PropertyDamage / Population
| sort by PropertyDamagePerCapita

Adicione | render columnchart à consulta para visualizar o resultado.

Usar o operador de pesquisa

O operador de pesquisa otimiza o desempenho de consultas em que uma tabela de fatos é enriquecida com dados de uma tabela de dimensões. Ele estende a tabela de fatos com valores pesquisados em uma tabela de dimensões. Para obter o melhor desempenho, o sistema, por padrão, pressupõe que a tabela à esquerda é a tabela de fatos maior e a tabela à direita é a tabela de dimensão menor. Isso é exatamente oposto à suposição usada pelo operador join.

No cluster de ajuda, há outro banco de dados chamado ContosoSales que contém dados de vendas. A consulta a seguir usa lookup para mesclar as SalesFact tabelas e Products desse banco de dados para obter o total de vendas por categoria de produto.

SalesFact
| lookup Products on ProductKey
| summarize TotalSales = count() by ProductCategoryName
| order by TotalSales desc

Saída

Unir tabelas geradas por consulta

As junções também podem ser feitas com base nos resultados da consulta da mesma tabela.

Digamos que você queira criar uma lista de estados em que ocorreram eventos de raios e avalanches. Use o operador de junção para mesclar as linhas de duas tabelas, uma contendo dados sobre eventos de relâmpagos e a outra contendo dados sobre eventos de avalanche, com base na State coluna.

StormEvents
| where EventType == "Lightning"
| distinct State
| join kind=inner (
    StormEvents 
    | where EventType == "Avalanche"
    | distinct State
    )
    on State
| project State

Saída

Conteúdo relacionado

• Saiba mais sobre os diferentes tipos de operador de junção
• Saiba como realizar consultas entre bancos de dados e entre clusters
• Siga o tutorial de criação de visualizações geoespaciais