Compartilhar via

Propriedade OutlineCode.OnlyCompleteCodes (Project)

  • Artigo

True se apenas os códigos de estrutura de tópicos com valores em todos os níveis da máscara de código pode ser usado. Boolean de leitura/gravação.

Sintaxe

expression. OnlyCompleteCodes

Expressão Uma variável que representa um objeto OutlineCode .

Comentários

Para campos de texto da empresa com uma tabela de pesquisa, OnlyCompleteCodes sempre será False e não gravável.

Exemplo

O exemplo a seguir adiciona um código de estrutura personalizado para armazenar o local dos recursos e configura o código de estrutura de modo que somente o nome completo de um código possa ser associado a um recurso.

Observação

[!OBSERVAçãO] A propriedade OnlyCompleteCodes pode ser definida somente depois que a tabela de pesquisa contém entradas. Se você tentar definir OnlyCompleteCodes antes de criar entradas da tabela de pesquisa, o resultado é o tempo de execução erro 7, "sem memória."

Sub CreateLocationOutlineCode() 
 
 Dim objOutlineCode As OutlineCode 
 
 Set objOutlineCode = ActiveProject.OutlineCodes.Add( _ 
 pjCustomResourceOutlineCode1, "Location") 
 
 DefineLocationCodeMask objOutlineCode.CodeMask 
 EditLocationLookupTable objOutlineCode.LookupTable 
 
 objOutlineCode.OnlyCompleteCodes = True 
 
End Sub 
 
 
Sub DefineLocationCodeMask(objCodeMask As CodeMask) 
 objCodeMask.Add _ 
 Sequence:=pjCustomOutlineCodeUppercaseLetters, _ 
 Length:=2, Separator:="." 
 
 objCodeMask.Add _ 
 Sequence:=pjCustomOutlineCodeUppercaseLetters, _ 
 Separator:="." 
 
 objCodeMask.Add _ 
 Sequence:=pjCustomOutlineCodeUppercaseLetters, _ 
 Length:=3, Separator:="." 
End Sub 
 
 
Sub EditLocationLookupTable(objLookupTable As LookupTable) 
 Dim objStateEntry As LookupTableEntry 
 Dim objCountyEntry As LookupTableEntry 
 Dim objCityEntry As LookupTableEntry 
 
 Set objStateEntry = objLookupTable.AddChild("WA") 
 objStateEntry.Description = "Washington" 
 
 Set objCountyEntry = objLookupTable.AddChild("KING", _ 
 objStateEntry.UniqueID) 
 objCountyEntry.Description = "King County" 
 
 Set objCityEntry = objLookupTable.AddChild("SEA", _ 
 objCountyEntry.UniqueID) 
 objCityEntry.Description = "Seattle" 
 
 Set objCityEntry = objLookupTable.AddChild("RED", _ 
 objCountyEntry.UniqueID) 
 objCityEntry.Description = "Redmond" 
 
 Set objCityEntry = objLookupTable.AddChild("KIR", _ 
 objCountyEntry.UniqueID) 
 objCityEntry.Description = "Kirkland" 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.