Propriedade Connect.ToPart (Visio)

Retorna a parte de uma forma à qual uma conexão é feita. Somente leitura.

Sintaxe

expressão. ToPart

Expressão Uma variável que representa um objeto Connect .

Valor de retorno

Inteiro

Comentários

A propriedade ToPart identifica a parte de uma forma à qual outra forma está colada, como seu ponto inicial ou final, uma de suas bordas ou um ponto de conexão. As seguintes constantes declaradas pela biblioteca de tipos do Visio no membro VisToParts mostra possíveis valores de retorno para a propriedade ToPart.

Exemplo

Esta macro do Microsoft Visual Basic for Applications (VBA) mostra como extrair informações de conexão de um desenho do Microsoft Visio. O exemplo exibe as informações de conexão na janela Imediato.

O exemplo presume que haja um documento ativo contendo pelo menos duas formas conectadas.

 
Public Sub ToPart_Example() 
 
 Dim vsoShapes As Visio.Shapes 
 Dim vsoShape As Visio.Shape 
 Dim vsoConnectTo As Visio.Shape 
 Dim intToData As Integer 
 Dim strTo As String 
 Dim vsoConnects As Visio.Connects 
 Dim vsoConnect As Visio.Connect 
 Dim intCurrentShapeID As Integer 
 Dim intCounter As Integer 
 
 Set vsoShapes = ActivePage.Shapes 
 
 'For each shape on the page, get its connections. 
 For intCurrentShapeID = 1 To vsoShapes.Count 
 
 Set vsoShape = vsoShapes(intCurrentShapeID) 
 Set vsoConnects = vsoShape.Connects 
 
 'For each connection, get the shape it connects to 
 'and the part of the shape it connects to, 
 'and print that information in the Immediate window. 
 For intCounter = 1 To vsoConnects.Count 
 
 Set vsoConnect = vsoConnects(intCounter) 
 Set vsoConnectTo = vsoConnect.ToSheet 
 intToData = vsoConnect.ToPart 
 
 If intToData = visConnectError Then 
 strTo = "error" 
 ElseIf intToData = visNone Then 
 strTo = "none" 
 ElseIf intToData = visGuideX Then 
 strTo = "guideX" 
 ElseIf intToData = visGuideY Then 
 strTo = "guideY" 
 ElseIf intToData = visWholeShape Then 
 strTo = "dynamic glue" 
 ElseIf intToData >= visConnectionPoint Then 
 strTo = "connection point " & _ 
 CStr(intToData - visConnectionPoint + 1) 
 Else 
 strTo = "???" 
 End If 
 
 'Print the name and part of the shape the 
 'Connect object connects to. 
 Debug.Print "To "; vsoConnectTo.Name & " " & strTo & "." 
 
 Next intCounter 
 
 Next intCurrentShapeID 
 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.