Compartilhar via

Propriedade Document.Saved (Visio)

  • Artigo

Determina se um documento contém alterações não salvas. Leitura/gravação.

Sintaxe

expressão. Salvou

Expressão Uma variável que representa um objeto Document .

Valor de retorno

Booliano

Comentários

Cuidado ao definir a propriedade Saved de um documento como True. Se você definir a propriedade Saved como True e um usuário ou outro programa fizer alterações no documento antes que ele seja fechado, essas alterações serão perdidas — o Microsoft Visio não fornece um aviso para salvar o documento.

Um documento que contém objetos OLE incorporados ou vinculados pode se declarar como não salvo, mesmo se a propriedade Saved do documento estiver definida como True.

Exemplo

Esta macro do Microsoft Visual Basic for Applications (VBA) mostra como usar a propriedade Saved para determinar se um documento possui alterações não salvas. Ela também mostra como definir a propriedade Saved. Antes de executar essa macro, altere path para o local onde você deseja salvar o desenho e altere filename para o nome que você gostaria de atribuir ao arquivo.

 
Public Sub Saved_Example() 
 
 Dim vsoDocument1 As Visio.Document 
 Dim vsoDocument2 As Visio.Document 
 Dim vsoPage As Visio.Page 
 Dim vsoShape As Visio.Shape 
 
 Set vsoPage = ThisDocument.Pages(1) 
 Set vsoShape = vsoPage.DrawOval(2.5, 7, 3.5, 9) 
 
 'Use the SaveAs method to save the document for the first time. 
 ThisDocument.SaveAs "path\filename .vsd" 
 
 'Use the Saved property to verify that the document was saved. 
 'Saved returns True (-1). 
 Debug.Print ThisDocument.Saved 
 
 'Force a change to the document by adding a shape. 
 Set vsoShape = vsoPage.DrawOval(4, 7, 5, 9) 
 
 'Use the Saved property to verify that the document changed 
 'since the last time is was saved. 
 'Saved returns False (0) 
 Debug.Print ThisDocument.Saved 
 
 'Use the Save method to save any new changes. 
 ThisDocument.Save 
 
 'Use the Saved property again to verify that 
 'the document was saved. Saved returns True (-1). 
 Debug.Print ThisDocument.Saved 
 
 'The Saved property can also be set. For example, change 
 'the document again so that the Saved property becomes False. 
 Set vsoShape = vsoPage.DrawRectangle(1, 1, 7, 7) 
 
 'Set the Saved property to True. 
 'Setting the Saved property to True does not save the document. 
 ThisDocument.Saved = True 
 
 'Close the document and then reopen it. Note that 
 'the rectangle was not saved. 
 Set vsoDocument1 = ThisDocument 
 vsoDocument1.Close 
 Set vsoDocument1 = Documents.Open("path\filename .vsd") 
 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.