Compartilhar via

Date.FromText

  • Artigo

Sintaxe

Date.FromText(text as nullable text, optional options as any) as nullable date

Sobre

Cria um valor de data a partir de uma representação textual.

  • text: Um valor de texto a ser convertido em uma data.

  • options: Um opcional record que pode ser fornecido para especificar propriedades adicionais. O record pode conter os seguintes campos:

    • Format: um valor text que indica o formato a ser usado. Para obter mais detalhes, acesse Cadeias de caracteres de formato de data e hora padrão e Cadeias de caracteres de formato de data e hora personalizadas. Omitir esse campo ou fornecer null resultados na análise da data usando um melhor esforço.
    • Culture: Quando Format não é nulo, Culture controla alguns especificadores de formato. Por exemplo, em "en-US""MMM" é "Jan", "Feb", "Mar", ..., enquanto em "ru-RU""MMM" é "янв", "фев", "мар", .... Quando Format é null, Culture controla o formato padrão a ser usado. Quando Culture é null ou omitido, Culture.Current é usado.

Para dar suporte a fluxos de trabalho herdados, options também pode ser um valor de texto. Isso tem o mesmo comportamento que options = [Format = null, Culture = options].

Exemplo 1

Converter "2010-12-31" em um valor date.

Usage

Date.FromText("2010-12-31")

Saída

#date(2010, 12, 31)

Exemplo 2

Faça a conversão usando um formato personalizado e a cultura alemã.

Usage

Date.FromText("30 Dez 2010", [Format="dd MMM yyyy", Culture="de-DE"])

Saída

#date(2010, 12, 30)

Exemplo 3

Localize a data no calendário gregoriano que corresponde ao início de 1400 no calendário islâmico.

Usage

Date.FromText("1400", [Format="yyyy", Culture="ar-SA"])

Saída

#date(1979, 11, 20)

Exemplo 4

Converta as datas de texto em italiano com meses abreviados na coluna Data de lançamento em valores de data.

Usage

let
    Source = #table(type table [Account Code = text, Posted Date = text, Sales = number],
    {
        {"US-2004", "20 gen. 2023", 580},
        {"CA-8843", "18 lug. 2024", 280},
        {"PA-1274", "12 gen. 2023", 90},
        {"PA-4323", "14 apr. 2023", 187},
        {"US-1200", "14 dic. 2023", 350},
        {"PTY-507", "4 giu. 2024", 110}
    }),
    #"Converted Date" = Table.TransformColumns(
        Source, 
        {"Posted Date", each Date.FromText(_, [Culture = "it-IT"]), type date}
    )
in
    #"Converted Date"

Saída

#table(type table [Account Code = text, Posted Date = date, Sales = number],
{
    {"US-2004", #date(2023, 1, 20), 580},
    {"CA-8843", #date(2024, 7, 18), 280},
    {"PA-1274", #date(2023, 1, 12), 90},
    {"PA-4323", #date(2023, 4, 14), 187},
    {"US-1200", #date(2023, 12, 14), 350},
    {"PTY-507", #date(2024, 6, 4), 110}
})

Conteúdo relacionado