Como: Leitura de arquivos de texto delimitado por vírgula no Visual Basic

O objeto TextFieldParser fornece uma maneira para facilmente e com eficiência analisar arquivos texto estruturados, como logs.A propriedade TextFieldType define se ele é um arquivo delimitado ou um arquivo com campos de texto de largura fixa .

Para analisar um arquivo de texto separado por vírgulas

1. Crie um novo TextFieldParser.O código a seguir cria o TextFieldParser chamado MyReader e abre o arquivo test.txt.

   Using MyReader As New _
   Microsoft.VisualBasic.FileIO.TextFieldParser _
   ("C:\TestFolder\test.txt")
   

2. Defina o tipo e delimitador do TextField .O código a seguir define a propriedade TextFieldType como Delimited e o delimitador como ",".

   MyReader.TextFieldType = FileIO.FieldType.Delimited
   MyReader.SetDelimiters(",")
   

3. Faça um loop através dos campos no arquivo.Se alguma linha estiver corrompida, relate um erro e continue a análise.O código a seguir faz um loop no arquivo, exibindo cada campo por vez e relatando quaisquer campos que estejam formatados incorretamente.

   Dim currentRow As String()
      While Not MyReader.EndOfData
         Try
            currentRow = MyReader.ReadFields()
            Dim currentField As String
            For Each currentField In currentRow
               MsgBox(currentField)
            Next
            Catch ex As _
            Microsoft.VisualBasic.FileIO.MalformedLineException
            MsgBox("Line " & ex.Message & _
            "is not valid and will be skipped.")
        End Try
   

4. Feche os blocos While e Using com End While e End Using.

      End While
   End Using
   

Exemplo

Este exemplo lê a partir do arquivo test.txt.

Using MyReader As New _
Microsoft.VisualBasic.FileIO.TextFieldParser("C:\testfile.txt")
   MyReader.TextFieldType = FileIO.FieldType.Delimited
   MyReader.SetDelimiters(",")
   Dim currentRow As String()
   While Not MyReader.EndOfData
      Try
         currentRow = MyReader.ReadFields()
         Dim currentField As String
         For Each currentField In currentRow
            MsgBox(currentField)
         Next
      Catch ex As Microsoft.VisualBasic.FileIO.MalformedLineException
      MsgBox("Line " & ex.Message & _
      "is not valid and will be skipped.")
      End Try
   End While
End Using

Programação robusta

As seguintes condições podem causar uma exceção:

• Uma linha não pode ser analisado usando o formato especificado (MalformedLineException).A mensagem de exceção especifica a linha causando a exceção, enquanto o Propriedade TextFieldParser.ErrorLine é atribuído ao texto contido na linha.

• O arquivo especificado não existe (FileNotFoundException).

• Uma situação de confiança parcial (partial-trust) na qual o usuário não tem permissões suficientes para acessar o arquivo.(SecurityException).

• O caminho é muito longo (PathTooLongException).

• O usuário não tem permissões suficientes para acessar o arquivo (UnauthorizedAccessException).

Consulte também

Tarefas

Como: Leitura de arquivos de texto de largura fixa no Visual Basic

Como: Ler From Texto Files with Multiple formatos no Visual Basic

Demonstra Passo a passo: Manipulação de arquivos e pastas no Visual Basic

Solução de problemas: Leitura e gravação em arquivos de texto

Solucionando problemas de exceções: Microsoft.VisualBasic.FileIO.TextFieldParser.MalformedLineException

Conceitos

Analisar Arquivos de Texto com o Objeto TextFieldParser

Referência

TextFieldParser Objeto